AST.icl

   1 implementation module AST
   2
   3 import StdEnv
   4
   5 from Data.List import map, intercalate, replicate, flatten, isEmpty
   6 from Data.Func import $
   7 from Text import class Text(concat), instance Text String
   8 from Data.Maybe import :: Maybe, maybe
   9
  10 instance toString AST where
  11         toString (AST v f) = concat (
  12                 ["\n":printersperse "\n" v] ++
  13                 ["\n":printersperse "\n" f])
  14
  15 class print a :: a -> [String]
  16
  17 printersperse :: String [a] -> [String] | print a
  18 printersperse i j = intercalate [i] (map print j)
  19
  20 instance print FunDecl where
  21         print (FunDecl i as t vs ss) =
  22                 ["\n", i, " (":printersperse "," as] ++
  23                 [")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
  24                 ["{\n\t":printersperse "\n\t" vs] ++
  25                 ["\n":printStatements ss 1] ++ ["}\n"]
  26
  27 printStatements :: [Stmt] Int -> [String]
  28 printStatements [] i = []
  29 printStatements [s:ss] i = (case s of
  30         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
  31                 printCodeBlock thens i ++
  32                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
  33         (WhileStmt b dos) = indent i ["while (":print b] ++
  34                 [")":printCodeBlock dos i]
  35         (AssStmt vardef val) =
  36                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
  37         (FunStmt fc) = indent i $ print fc ++ [";\n"]
  38         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
  39         ) ++ printStatements ss i
  40         where
  41                 printCodeBlock :: [Stmt] Int -> [String]
  42                 printCodeBlock [] _ = ["{}\n"]
  43                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
  44                 printCodeBlock x i =
  45                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
  46
  47                 indent :: Int [String] -> [String]
  48                 indent i rest = replicate i "\t" ++ rest
  49
  50 instance print FunType where
  51         print (FunType at rt) = printersperse " " at ++
  52                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
  53
  54 instance print VarDecl where
  55         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
  56
  57 instance print Type where
  58         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
  59         print (ListType t) = ["[":print t] ++ ["]"]
  60         print (IdType s) = print s
  61         print IntType = print "Int"
  62         print BoolType = print "Bool"
  63         print CharType = print "Char"
  64         print VarType = print "var"
  65
  66 instance print String where
  67         print s = [s]
  68
  69 instance print FieldSelector where
  70         print FieldHd = print "hd"
  71         print FieldTl = print "tl"
  72         print FieldSnd = print "snd"
  73         print FieldFst = print "fst"
  74
  75 instance print VarDef where
  76         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
  77
  78 instance print FunCall where
  79         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
  80
  81 instance print Expr where
  82         print (VarExpr vd) = print vd
  83         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
  84                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
  85                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
  86                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
  87                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
  88                 ," ":print e2] ++ [")"]
  89         print (Op1Expr o e) = ["(",case o of
  90                 UnNegation = "!"; UnMinus = "-"
  91                 :print e] ++ [")"]
  92         print (IntExpr i) = [toString i]
  93         print (CharExpr c) = ["\'", case c of
  94                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
  95                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
  96                 c = if (c == toChar 7) "\\a" (toString c)
  97                 ,"\'"]
  98         print (BoolExpr b) = [toString b]
  99         print (FunExpr fc) = print fc
 100         print EmptyListExpr = ["[]"]
 101         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]