Devices/mTaskDevice.icl

   1 implementation module Devices.mTaskDevice
   2
   3 from StdFunc import flip
   4 import Generics.gCons
   5 import mTaskInterpret
   6 import iTasks
   7 import iTasksTTY
   8 import TTY
   9 import qualified Data.Map as DM
  10 import Utils.SDS
  11 import Utils.Devices
  12
  13 import GenBimap
  14 import Devices.mTaskSerial
  15 import Devices.mTaskTCP
  16 import iTasks._Framework.Store
  17 import iTasks.UI.Definition, iTasks.UI.Editor, iTasks.UI.Editor.Builtin, iTasks.UI.Editor.Common, iTasks.UI.Layout.Default, iTasks.UI.Layout.Common
  18
  19 from Data.Func import $
  20
  21 derive class iTask MTaskDevice, MTaskResource, MTaskMSGRecv, MTaskMSGSend, BCShare
  22 derive conses MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  23 derive consName MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  24
  25 instance == MTaskDevice where
  26         (==) a b = a.deviceChannels == b.deviceChannels
  27
  28 startupDevices :: Task [MTaskDevice]
  29 startupDevices = upd (map reset) deviceStore
  30         where reset d = {d & deviceTask=Nothing, deviceTasks=[], deviceError=Nothing}
  31
  32 makeDevice :: String MTaskResource -> Task MTaskDevice
  33 makeDevice name res = get randomInt @ \rand->{MTaskDevice
  34                 |deviceChannels=name +++ toString rand
  35                 ,deviceName=name
  36                 ,deviceTasks=[]
  37                 ,deviceTask=Nothing
  38                 ,deviceError=Nothing
  39                 ,deviceData=res
  40                 ,deviceSpec=Nothing}
  41
  42 getSynFun :: MTaskResource -> ((Shared Channels) -> Task ())
  43 getSynFun (TCPDevice t) = synFun t
  44 getSynFun (SerialDevice t) = synFun t
  45
  46 addDevice :: (Shared [MTaskDevice]) (MTaskDevice (Shared Channels) -> Task ()) -> Task String
  47 addDevice devices processFun
  48         =   enterChoice "Device type" [] (map consName{|*|} deviceTypes)
  49         >&^ \sh->whileUnchanged sh $ \mty->case mty of
  50                 Nothing = viewInformation "No type selected yet" [] ""
  51                 Just ty = enterInformation "Name" [] -&&- deviceSettings ty
  52                         >>= \(name, settings)->makeDevice name settings
  53                         >>= \dev->upd (\l->[dev:l]) devices
  54                         >>| connectDevice processFun dev
  55                         @! ""
  56         where
  57                 deviceSettings "SerialDevice" = getmTaskSerialDevice
  58                 deviceSettings "TCPDevice" = getmTaskTCPDevice
  59
  60                 deviceTypes :: [MTaskResource]
  61                 deviceTypes = conses{|*|}
  62
  63 connectDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  64 connectDevice pf d = let ch = channels d in appendTopLevelTask 'DM'.newMap True
  65         (pf d ch -||- catchAll (getSynFun d.deviceData ch) errorHandle)
  66         >>= \tid->withDevices d (\d->{d&deviceTask=Just tid,deviceError=Nothing}) @! ()
  67         where
  68                 errorHandle e = withDevices d (\d->{d&deviceTask=Nothing,deviceError=Just e})
  69
  70 manageDevices :: (MTaskDevice (Shared Channels) -> Task ()) [MTaskDevice] -> Task ()
  71 manageDevices processFun ds = anyTask [
  72                 addDevice deviceStore processFun <<@ Title "Add new device" @! ():
  73                         [viewDevice processFun d
  74                                 <<@ Title d.deviceName\\d<-ds]]
  75         <<@ ArrangeWithTabs @! ()
  76
  77 viewDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  78 viewDevice pf d = forever $ traceValue "viewDevice" >>| anyTask
  79                 [viewInformation "Device settings" [] d @! ()
  80                 ,viewSharedInformation "Channels" [ViewAs dropEmpty] (channels d) @! ()
  81                 ,forever $
  82                         enterChoice "Delete task on device" [ChooseFromGrid id] d.deviceTasks
  83                         >>* [OnAction (Action "Delete") $ ifValue (\t->t.ident <> -1) (deviceTaskDelete d)]
  84                         @! ()
  85                 ] <<@ ArrangeHorizontal
  86                 >>* [OnAction (Action "Delete Device") (always $ deleteDevice d):
  87                                 if (isJust d.deviceTask) []
  88                                 [OnAction (Action "Connect") (always $ connectDevice pf d)]]
  89         where
  90                 dropEmpty (r,s,ss) = (filter ((=!=)MTEmpty) r,s,ss)
  91
  92 deleteDevice :: MTaskDevice -> Task ()
  93 deleteDevice d = upd (\(r,s,ss)->(r,s,True)) (channels d)
  94         >>| maybe (treturn ()) (flip removeTask topLevelTasks) d.deviceTask
  95         >>| upd (filter ((<>)d)) deviceStore
  96         @! ()
  97
  98 sendToDevice :: String (Main (ByteCode () Stmt)) (MTaskDevice, MTaskInterval) -> Task ()
  99 sendToDevice wta mTask (device, timeout) =
 100                 get bcStateStore @ toMessages timeout o toRealByteCode (unMain mTask)
 101         >>= \(msgs, st1)->set st1 bcStateStore
 102         >>| toSDSRecords st1
 103         >>= \sdss->set sdss sdsStore//MTaskShareaddToSDSShare
 104         >>| sendMessages msgs device
 105         >>| makeTask wta -1
 106         >>= withDevices device o addTask
 107         @! ()
 108         where
 109                 sharename i = device.deviceChannels +++ "-" +++ toString i
 110                 toSDSRecords st = sequence "" [makeShare wta sdsi sdsval\\{sdsi,sdspub,sdsval}<-st.sdss]// | sdspub]
 111
 112                 addTask :: MTaskTask MTaskDevice -> MTaskDevice
 113                 addTask task device = {device & deviceTasks=[task:device.deviceTasks]}
 114
 115 sendMessages :: [MTaskMSGSend] -> (MTaskDevice -> Task Channels)
 116 sendMessages msgs = upd (\(r,s,ss)->(r,msgs++s,ss)) o channels
 117
 118 withDevices :: MTaskDevice (MTaskDevice -> MTaskDevice) -> Task ()
 119 withDevices a trans = upd (map \b->if (b == a) (trans b) b) deviceStore @! ()
 120
 121 deviceTaskAcked :: MTaskDevice Int -> Task ()
 122 deviceTaskAcked dev i
 123         = withDevices dev (\d->{d&deviceTasks=ackFirst d.deviceTasks})
 124         where
 125                 ackFirst :: [MTaskTask] -> [MTaskTask]
 126                 ackFirst [] = []
 127                 ackFirst [t:ts] = if (t.ident == -1)
 128                         [{t & ident=i}:ts] [t:ackFirst ts]
 129
 130 deviceTaskDelete :: MTaskDevice MTaskTask -> Task ()
 131 deviceTaskDelete dev task = sendMessages [MTTaskDel task.ident] dev @! ()
 132
 133 deviceTaskDeleteAcked :: MTaskDevice Int -> Task ()
 134 deviceTaskDeleteAcked d i = withDevices d $ deleteTask
 135         where deleteTask d = {d & deviceTasks=[s\\s<-d.deviceTasks | i <> s.ident]}
 136
 137 deviceAddSpec :: MTaskDevice MTaskDeviceSpec -> Task ()
 138 deviceAddSpec d s = withDevices d $ \r->{MTaskDevice | r & deviceSpec=Just s}