Devices/mTaskDevice.icl

   1 implementation module Devices.mTaskDevice
   2
   3 from StdFunc import flip
   4 import Generics.gCons
   5 import mTaskInterpret
   6 import iTasks
   7 import iTasksTTY
   8 import TTY
   9 import qualified Data.Map as DM
  10 import qualified Data.List as DL
  11 import Utils.SDS
  12 import Utils.Devices
  13
  14 import GenBimap
  15 import Devices.mTaskSerial
  16 import Devices.mTaskTCP
  17 import iTasks._Framework.Store
  18 import iTasks.UI.Definition, iTasks.UI.Editor, iTasks.UI.Editor.Builtin, iTasks.UI.Editor.Common, iTasks.UI.Layout.Default, iTasks.UI.Layout.Common
  19
  20 from Data.Func import $
  21
  22 derive class iTask MTaskDevice, MTaskResource, MTaskMSGRecv, MTaskMSGSend, BCShare
  23 derive conses MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  24 derive consName MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  25
  26 instance == MTaskDevice where
  27         (==) a b = a.deviceChannels == b.deviceChannels
  28
  29 startupDevices :: Task [MTaskDevice]
  30 startupDevices = upd (map reset) deviceStore
  31         where reset d = {d & deviceTask=Nothing, deviceTasks=[], deviceError=Nothing}
  32
  33 withDevice :: (MTaskDevice -> Task a) String -> Task a | iTask a
  34 withDevice f s = get deviceStore
  35         >>= \ds->case 'DL'.find (\d->d.deviceName == s) ds of
  36                 Nothing = throw "Device not available"
  37                 Just d = f d
  38
  39 makeDevice :: String MTaskResource -> Task MTaskDevice
  40 makeDevice name res = get randomInt @ \rand->{MTaskDevice
  41                 |deviceChannels=name +++ toString rand
  42                 ,deviceName=name
  43                 ,deviceTasks=[]
  44                 ,deviceTask=Nothing
  45                 ,deviceError=Nothing
  46                 ,deviceData=res
  47                 ,deviceSpec=Nothing
  48                 ,deviceShares=[]}
  49
  50 getSynFun :: MTaskResource -> ((Shared Channels) -> Task ())
  51 getSynFun (TCPDevice t) = synFun t
  52 getSynFun (SerialDevice t) = synFun t
  53
  54 addDevice :: (Shared [MTaskDevice]) (MTaskDevice (Shared Channels) -> Task ()) -> Task String
  55 addDevice devices processFun
  56         =   enterChoice "Device type" [] (map consName{|*|} deviceTypes)
  57         >&^ \sh->whileUnchanged sh $ \mty->case mty of
  58                 Nothing = viewInformation "No type selected yet" [] ""
  59                 Just ty = enterInformation "Name" [] -&&- deviceSettings ty
  60                         >>= \(name, settings)->makeDevice name settings
  61                         >>= \dev->upd (\l->[dev:l]) devices
  62                         >>| connectDevice processFun dev
  63                         @! ""
  64         where
  65                 deviceSettings "SerialDevice" = getmTaskSerialDevice
  66                 deviceSettings "TCPDevice" = getmTaskTCPDevice
  67
  68                 deviceTypes :: [MTaskResource]
  69                 deviceTypes = conses{|*|}
  70
  71 connectDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  72 connectDevice pf d = let ch = channels d in appendTopLevelTask 'DM'.newMap True
  73         (pf d ch -||- catchAll (getSynFun d.deviceData ch) errorHandle)
  74         >>= \tid->withDevices d (\d->{d&deviceTask=Just tid,deviceError=Nothing})
  75         >>| upd (\(r,s,ss)->(r,s++[MTSpec],ss)) ch
  76         @! ()
  77         where
  78                 errorHandle e = withDevices d (\d->{d&deviceTask=Nothing,deviceError=Just e})
  79
  80 manageDevices :: (MTaskDevice (Shared Channels) -> Task ()) [MTaskDevice] -> Task ()
  81 manageDevices processFun ds = anyTask [
  82                 addDevice deviceStore processFun <<@ Title "Add new device" @! ():
  83                         [viewDevice processFun d
  84                                 <<@ Title d.deviceName\\d<-ds]]
  85         <<@ ArrangeWithTabs @! ()
  86
  87 viewDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  88 viewDevice pf d = forever $ traceValue "viewDevice" >>| anyTask
  89                 [viewInformation "Device settings" [] d @! ()
  90                 ,viewSharedInformation "Channels" [ViewAs dropEmpty] (channels d) @! ()
  91                 ,forever $
  92                         enterChoice "Delete task on device" [ChooseFromGrid id] d.deviceTasks
  93                         >>* [OnAction (Action "Delete") $ ifValue (\t->t.ident <> -1) (deviceTaskDelete d)]
  94                         @! ()
  95                 ] <<@ ArrangeHorizontal
  96                 >>* [OnAction (Action "Delete Device") (always $ deleteDevice d):
  97                                 if (isJust d.deviceTask) []
  98                                 [OnAction (Action "Connect") (always $ connectDevice pf d)]]
  99         where
 100                 dropEmpty (r,s,ss) = (filter ((=!=)MTEmpty) r,s,ss)
 101
 102 deleteDevice :: MTaskDevice -> Task ()
 103 deleteDevice d = sendMessages [MTShutdown] d
 104         >>| wait "Waiting for the channels to empty" (\(r,s,ss)->isEmpty s) (channels d)
 105         >>| upd (\(r,s,ss)->(r,s,True)) (channels d)
 106         >>| maybe (treturn ()) (flip removeTask topLevelTasks) d.deviceTask
 107         >>| upd (filter ((<>)d)) deviceStore
 108 //      >>| cleanSharesDevice d.deviceName
 109         @! ()
 110
 111 sendMessages :: [MTaskMSGSend] -> (MTaskDevice -> Task Channels)
 112 sendMessages msgs = upd (\(r,s,ss)->(r,msgs++s,ss)) o channels
 113
 114 withDevices :: MTaskDevice (MTaskDevice -> MTaskDevice) -> Task ()
 115 withDevices a trans = upd (map \b->if (b == a) (trans b) b) deviceStore @! ()
 116
 117 deviceTaskAcked :: MTaskDevice Int Int -> Task ()
 118 deviceTaskAcked dev i mem
 119         = withDevices dev (\d->{d
 120                         &deviceTasks=ackFirst d.deviceTasks
 121                         ,deviceSpec=Just {fromJust d.deviceSpec & bytesMemory=mem}})
 122         where
 123                 ackFirst :: [MTaskTask] -> [MTaskTask]
 124                 ackFirst [] = []
 125                 ackFirst [t:ts] = if (t.ident == -1)
 126                         [{t & ident=i}:ts] [t:ackFirst ts]
 127
 128 deviceTaskDelete :: MTaskDevice MTaskTask -> Task ()
 129 deviceTaskDelete dev task = sendMessages [MTTaskDel task.ident] dev @! ()
 130
 131 deviceTaskDeleteAcked :: MTaskDevice Int -> Task ()
 132 deviceTaskDeleteAcked d i = cleanSharesTask i d
 133         >>| withDevices d deleteTask
 134         where deleteTask d = {d & deviceTasks=[s\\s<-d.deviceTasks | i <> s.ident]}
 135
 136 deviceAddSpec :: MTaskDevice MTaskDeviceSpec -> Task ()
 137 deviceAddSpec d s = withDevices d $ \r->{MTaskDevice | r & deviceSpec=Just s}