Devices/mTaskDevice.icl

   1 implementation module Devices.mTaskDevice
   2
   3 from StdFunc import flip
   4 import Generics.gCons
   5 import mTaskInterpret
   6 import iTasks
   7 import iTasksTTY
   8 import TTY
   9 import qualified Data.Map as DM
  10 import qualified Data.List as DL
  11 import Utils.SDS
  12 import Utils.Devices
  13
  14 import GenBimap
  15 import Devices.mTaskSerial
  16 import Devices.mTaskTCP
  17 import iTasks._Framework.Store
  18 import iTasks.UI.Definition, iTasks.UI.Editor, iTasks.UI.Editor.Builtin, iTasks.UI.Editor.Common, iTasks.UI.Layout.Default, iTasks.UI.Layout.Common
  19
  20 from Data.Func import $
  21
  22 derive class iTask MTaskDevice, MTaskResource, MTaskMSGRecv, MTaskMSGSend, BCShare
  23 derive conses MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  24 derive consName MTaskResource, TTYSettings, BaudRate, Parity, ByteSize, TCPSettings
  25
  26 instance == MTaskDevice where
  27         (==) a b = a.deviceChannels == b.deviceChannels
  28
  29 startupDevices :: Task [MTaskDevice]
  30 startupDevices = upd (map reset) deviceStore
  31         where reset d = {d & deviceTask=Nothing, deviceTasks=[], deviceError=Nothing}
  32
  33 withDevice :: (MTaskDevice -> Task a) String -> Task a | iTask a
  34 withDevice f s = get deviceStore
  35         >>= \ds->case 'DL'.find (\d->d.deviceName == s) ds of
  36                 Nothing = throw "Device not available"
  37                 Just d = f d
  38
  39 makeDevice :: String MTaskResource -> Task MTaskDevice
  40 makeDevice name res = get randomInt @ \rand->{MTaskDevice
  41                 |deviceChannels=name +++ toString rand
  42                 ,deviceName=name
  43                 ,deviceTasks=[]
  44                 ,deviceTask=Nothing
  45                 ,deviceError=Nothing
  46                 ,deviceData=res
  47                 ,deviceSpec=Nothing}
  48
  49 getSynFun :: MTaskResource -> ((Shared Channels) -> Task ())
  50 getSynFun (TCPDevice t) = synFun t
  51 getSynFun (SerialDevice t) = synFun t
  52
  53 addDevice :: (Shared [MTaskDevice]) (MTaskDevice (Shared Channels) -> Task ()) -> Task String
  54 addDevice devices processFun
  55         =   enterChoice "Device type" [] (map consName{|*|} deviceTypes)
  56         >&^ \sh->whileUnchanged sh $ \mty->case mty of
  57                 Nothing = viewInformation "No type selected yet" [] ""
  58                 Just ty = enterInformation "Name" [] -&&- deviceSettings ty
  59                         >>= \(name, settings)->makeDevice name settings
  60                         >>= \dev->upd (\l->[dev:l]) devices
  61                         >>| connectDevice processFun dev
  62                         @! ""
  63         where
  64                 deviceSettings "SerialDevice" = getmTaskSerialDevice
  65                 deviceSettings "TCPDevice" = getmTaskTCPDevice
  66
  67                 deviceTypes :: [MTaskResource]
  68                 deviceTypes = conses{|*|}
  69
  70 connectDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  71 connectDevice pf d = let ch = channels d in appendTopLevelTask 'DM'.newMap True
  72         (pf d ch -||- catchAll (getSynFun d.deviceData ch) errorHandle)
  73         >>= \tid->withDevices d (\d->{d&deviceTask=Just tid,deviceError=Nothing})
  74         >>| upd (\(r,s,ss)->(r,s++[MTSpec],ss)) ch
  75         @! ()
  76         where
  77                 errorHandle e = withDevices d (\d->{d&deviceTask=Nothing,deviceError=Just e})
  78
  79 manageDevices :: (MTaskDevice (Shared Channels) -> Task ()) [MTaskDevice] -> Task ()
  80 manageDevices processFun ds = anyTask [
  81                 addDevice deviceStore processFun <<@ Title "Add new device" @! ():
  82                         [viewDevice processFun d
  83                                 <<@ Title d.deviceName\\d<-ds]]
  84         <<@ ArrangeWithTabs @! ()
  85
  86 viewDevice :: (MTaskDevice (Shared Channels) -> Task ()) MTaskDevice -> Task ()
  87 viewDevice pf d = forever $ traceValue "viewDevice" >>| anyTask
  88                 [viewInformation "Device settings" [] d @! ()
  89                 ,viewSharedInformation "Channels" [ViewAs dropEmpty] (channels d) @! ()
  90                 ,forever $
  91                         enterChoice "Delete task on device" [ChooseFromGrid id] d.deviceTasks
  92                         >>* [OnAction (Action "Delete") $ ifValue (\t->t.ident <> -1) (deviceTaskDelete d)]
  93                         @! ()
  94                 ] <<@ ArrangeHorizontal
  95                 >>* [OnAction (Action "Delete Device") (always $ deleteDevice d):
  96                                 if (isJust d.deviceTask) []
  97                                 [OnAction (Action "Connect") (always $ connectDevice pf d)]]
  98         where
  99                 dropEmpty (r,s,ss) = (filter ((=!=)MTEmpty) r,s,ss)
 100
 101 deleteDevice :: MTaskDevice -> Task ()
 102 deleteDevice d = upd (\(r,s,ss)->(r,s,True)) (channels d)
 103         >>| maybe (treturn ()) (flip removeTask topLevelTasks) d.deviceTask
 104         >>| upd (filter ((<>)d)) deviceStore
 105         >>| cleanSharesDevice d.deviceName
 106         @! ()
 107
 108 sendMessages :: [MTaskMSGSend] -> (MTaskDevice -> Task Channels)
 109 sendMessages msgs = upd (\(r,s,ss)->(r,msgs++s,ss)) o channels
 110
 111 withDevices :: MTaskDevice (MTaskDevice -> MTaskDevice) -> Task ()
 112 withDevices a trans = upd (map \b->if (b == a) (trans b) b) deviceStore @! ()
 113
 114 deviceTaskAcked :: MTaskDevice Int Int -> Task ()
 115 deviceTaskAcked dev i mem
 116         = withDevices dev (\d->{d
 117                         &deviceTasks=ackFirst d.deviceTasks
 118                         ,deviceSpec=Just {fromJust d.deviceSpec & bytesMemory=mem}})
 119         where
 120                 ackFirst :: [MTaskTask] -> [MTaskTask]
 121                 ackFirst [] = []
 122                 ackFirst [t:ts] = if (t.ident == -1)
 123                         [{t & ident=i}:ts] [t:ackFirst ts]
 124
 125 deviceTaskDelete :: MTaskDevice MTaskTask -> Task ()
 126 deviceTaskDelete dev task = sendMessages [MTTaskDel task.ident] dev @! ()
 127
 128 deviceTaskDeleteAcked :: MTaskDevice Int -> Task ()
 129 deviceTaskDeleteAcked d i = cleanSharesTask i d
 130         >>| withDevices d deleteTask
 131         where deleteTask d = {d & deviceTasks=[s\\s<-d.deviceTasks | i <> s.ident]}
 132
 133 deviceAddSpec :: MTaskDevice MTaskDeviceSpec -> Task ()
 134 deviceAddSpec d s = withDevices d $ \r->{MTaskDevice | r & deviceSpec=Just s}