dsl/xtend/src/robots/missions/generator/TaskDSLGenerator.xtend

   1 /*
   2  * generated by Xtext
   3  */
   4 package robots.missions.generator
   5
   6 import org.eclipse.emf.common.util.EList
   7 import org.eclipse.emf.ecore.resource.Resource
   8 import org.eclipse.xtext.generator.IFileSystemAccess
   9 import org.eclipse.xtext.generator.IGenerator
  10 import robots.missions.taskDSL.Behaviour
  11 import robots.missions.taskDSL.Mission
  12 import robots.missions.taskDSL.OperatorE
  13 import robots.missions.taskDSL.Robot
  14 import robots.missions.taskDSL.StoppingExpression
  15
  16 /**
  17  * Generates code from your model files on save.
  18  *
  19  * See https://www.eclipse.org/Xtext/documentation/303_runtime_concepts.html#code-generation
  20  */
  21 class TaskDSLGenerator implements IGenerator {
  22
  23         override void doGenerate(Resource resource, IFileSystemAccess fsa) {
  24                 var root = resource.allContents.head as Robot;
  25                 if(root != null){
  26                         fsa.generateFile("nl/ru/des/Constants.java", makeConstants(root));
  27                         fsa.generateFile("nl/ru/des/Behaviours.java", makeBehaviours(root.behaviour));
  28                         fsa.generateFile("nl/ru/des/Missions.java", makeMissions(root.mission));
  29                 }
  30         }
  31
  32         def CharSequence makeMissions(EList<Mission> list)'''
  33 package nl.ru.des;
  34
  35 import java.util.LinkedList;
  36
  37 import lejos.hardware.motor.EV3LargeRegulatedMotor;
  38 import lejos.robotics.subsumption.Behavior;
  39 import nl.ru.des.Behaviours;
  40
  41 public class Missions{
  42         public static LinkedList<Mission> getMissions(SensorCollector sensors, EV3LargeRegulatedMotor rightMotor,
  43                         EV3LargeRegulatedMotor leftMotor, ColorMemory colors){
  44                 LinkedList<Mission> missions = new LinkedList<Mission>();
  45                 «FOR m : list»
  46                 missions.add(new Mission("«m.name»", new Behavior[]{
  47                         «FOR b : m.behaviours SEPARATOR ","»
  48                         new Behaviours.«b.name»Behaviour(sensors, rightMotor, leftMotor, colors)
  49                         «ENDFOR»,
  50                         new ShutdownBehaviour(sensors, rightMotor, leftMotor, colors, "«m.name»"){
  51                                 @Override public boolean takeControl(){
  52                                         return «printExpression(m.se)»;
  53                                 }
  54                         }}
  55                 «ENDFOR»));
  56                 return missions;
  57         }
  58 }
  59 '''
  60
  61         def CharSequence makeBehaviours(EList<Behaviour> list)'''
  62 package nl.ru.des;
  63
  64 import lejos.hardware.motor.EV3LargeRegulatedMotor;
  65
  66 public class Behaviours{
  67         «FOR b : list»
  68         public static class «b.name»Behaviour extends BasicBehaviour {
  69                 public «b.name»Behaviour(SensorCollector sensors, EV3LargeRegulatedMotor rightMotor,
  70                                 EV3LargeRegulatedMotor leftMotor, ColorMemory colors){
  71                         super(sensors, rightMotor, leftMotor, colors);
  72                 }
  73                 «IF b.tc != null»
  74                 @Override public boolean takeControl(){
  75                         return «printExpression(b.tc)»;
  76                 }
  77                 «ENDIF»
  78
  79                 @Override public void action(){
  80                         super.action();
  81                         «FOR a : b.actions»
  82                                 «IF a.whichMotor != null»
  83                                         «IF a.acc > 0»
  84                                         «a.whichMotor.d.toString()»Motor.setAcceleration(«a.acc»);
  85                                         «a.whichMotor.d.toString()»Motor.setSpeed(«a.spd»);
  86                                         «ENDIF»
  87                                         «a.whichMotor.d.toString()»Motor.«a.dir.d.toString()»();
  88                                 «ELSE»
  89                                 time = System.currentTimeMillis();
  90                                 while(!suppressed«IF a.time.time > 0» && System.currentTimeMillis()-time>«a.time.time»«ENDIF»){
  91                                         «IF !b.clcColor.nullOrEmpty»
  92                                         int currentColor = sensors.color();
  93                                         if (Constants.colorsToFind.contains(currentColor)) {
  94                                                 colors.addColor(currentColor);
  95                                         }
  96                                         «ENDIF»
  97                                         Thread.yield();
  98                                 }
  99                                 «ENDIF»
 100                         «ENDFOR»
 101                         reset();
 102                 }
 103         }
 104         «ENDFOR»
 105 }
 106         '''
 107
 108         def CharSequence printExpression(StoppingExpression e)'''
 109         «IF e.scond != null»
 110                 «IF !e.scond.colors.nullOrEmpty»
 111                 colors.containsAll(Constants.colorsToFind)
 112                 «ELSEIF e.scond.touch != null»
 113                 sensors.«e.scond.touch.d.toString()»Touch()
 114                 «ELSEIF e.scond.op != null»
 115                 sensors.distance() «e.scond.op.d.toString()» «e.scond.dist»
 116                 «ELSEIF e.scond.color != null»
 117                 sensors.color() == «e.scond.color.d.ordinal»
 118                 «ENDIF»
 119         «ELSE»
 120                 «IF e.op.d.equals(OperatorE.AND)»
 121                         «FOR ex : e.s BEFORE "(" SEPARATOR "&&" AFTER ")"»«printExpression(ex)»«ENDFOR»
 122                 «ELSE»
 123                         «FOR ex : e.s BEFORE "(" SEPARATOR "&&" AFTER ")"»«printExpression(ex)»«ENDFOR»
 124                 «ENDIF»
 125         «ENDIF»
 126         '''
 127
 128         def CharSequence makeConstants(Robot robot)'''
 129 package nl.ru.des;
 130
 131 import java.util.Arrays;
 132 import java.util.List;
 133
 134 public class Constants{
 135         public final static int speed = «robot.spd»;
 136         public final static int acceleration = «robot.acc»;
 137         «FOR m : robot.mission»
 138                 «IF !m.se.scond.colors.nullOrEmpty»
 139                         public final static List<Integer> colorsToFind = Arrays.asList(new Integer[] {«FOR c : m.se.scond.colors SEPARATOR ","»«c.d.ordinal»«ENDFOR»});
 140                 «ENDIF»
 141         «ENDFOR»
 142 }'''
 143
 144 }