fp2/week45/mart/RefactorX.icl

   1 implementation module RefactorX
   2
   3 import StdEnv
   4
   5 //Start = map toString [E1,E2,E3,E4,E5]
   6 //Start = map free [E1,E2,E3,E4,E5]
   7 //Start = map toString (map remove_unused_lets [E1,E2,E3,E4,E5])
   8 Start = map eval [E1,E2,E3,E4,E5]
   9         where
  10                 E1 = OP (LET "x" (OP (NR 42) MIN (NR 3)) (OP (VAR "x") DIV (NR 0))) PLUS (LET "y" (NR 6) (OP (VAR "y") MUL (VAR "y")))
  11                 E2 = LET "x" (NR 42) (OP (VAR "x") PLUS (LET "x" (NR 58) (VAR "x")))
  12                 E3 = LET "x" (NR 1) (LET "y" (NR 2) (LET "x" (NR 3) (NR 4)))
  13                 E4 = LET "x" (NR 1) (OP (VAR "x") PLUS (VAR "y"))
  14                 E5 = OP (LET "x" (NR 1) (VAR "x")) MUL (VAR "x")
  15
  16 (<+) infixl 9 :: String a -> String | toString a
  17 (<+) str a = str +++ toString a
  18
  19 instance toString Operator where
  20         toString PLUS = "+"
  21         toString MIN = "-"
  22         toString MUL = "*"
  23         toString DIV = "/"
  24
  25 instance toString Expr where
  26         toString (NR n) = toString n
  27         toString (VAR v) = v
  28         toString (LET n e1 e2) = "(let " <+ n <+ "=" <+ e1 <+ " in " <+ e2 <+ ")"
  29         toString (OP e1 o e2) = bracket e1 <+ o <+ bracket e2
  30                 where
  31                         bracket :: Expr -> String
  32                         bracket (OP e1 o e2) = "(" <+ (OP e1 o e2) <+ ")"
  33                         bracket e = toString e
  34
  35 free:: Expr -> [Name]
  36 free (NR n) = []
  37 free (VAR v) = [v]
  38 free (OP e1 o e2) = removeDup (free e1 ++ free e2)
  39 free (LET n e1 e2) = removeMember n (free e2)
  40
  41 remove_unused_lets:: Expr -> Expr
  42 remove_unused_lets (LET n e1 e2)
  43 | isMember n (free e2) = (LET n (remove_unused_lets e1) (remove_unused_lets e2))
  44 | otherwise = remove_unused_lets e2
  45 remove_unused_lets (OP e1 o e2) = (OP (remove_unused_lets e1) o (remove_unused_lets e2))
  46 remove_unused_lets e = e
  47
  48 apply:: Operator Val Val -> Val
  49 apply _ Undef _ = Undef
  50 apply _ _ Undef = Undef
  51 apply DIV _ (Result 0) = Undef
  52 apply o (Result e1) (Result e2) = Result (apply` o e1 e2)
  53         where
  54                 apply`:: Operator -> Int Int -> Int
  55                 apply` PLUS = +
  56                 apply` MIN = -
  57                 apply` MUL = *
  58                 apply` DIV = /
  59
  60
  61 eval:: Expr -> Val
  62 eval e = eval` (remove_unused_lets e) []
  63         where
  64                 eval`:: Expr [(Name, Val)] -> Val
  65                 eval` (NR n) _ = Result n
  66                 eval` (VAR v) [] = Undef
  67                 eval` (VAR v) [(n, e):xs]
  68                 | v == n = e
  69                 | otherwise = eval` (VAR v) xs
  70                 eval` (OP e1 o e2) xs = apply o (eval` e1 xs) (eval` e2 xs)
  71                 eval` (LET n e1 e2) xs = eval` e2 [(n, eval` e1 xs):xs]