lex.icl

   1 implementation module lex
   2
   3 import Control.Monad
   4 import Data.Either
   5 import Data.Maybe
   6 import Data.Map
   7 import StdString
   8 import StdBool
   9 import StdList
  10 import StdChar
  11 import qualified Text
  12
  13 SingleCharTokens :: Map Char Token
  14 SingleCharTokens = fromList [
  15         ('(', BraceOpenToken), (')', BraceCloseToken), ('{', CBraceOpenToken),
  16         ('}', CBraceCloseToken), ('[', SquareOpenToken), (']', SquareCloseToken),
  17         (',', CommaToken), (':', ColonToken), (';', SColonToken),
  18         ('.', DotToken), ('+', PlusToken), ('-', DashToken), ('*', StarToken),
  19         ('/', SlashToken), ('%', PercentToken), ('=', AssignmentToken),
  20         ('<', LesserToken), ('>', BiggerToken), ('!', ExclamationToken)]
  21
  22 EscapeMap :: Map Char Char
  23 EscapeMap = fromList [
  24         ('a', toChar 7), ('b', '\b'), ('f', '\f'), ('n', '\n'), ('r', '\r'),
  25         ('t', '\t'), ('v', '\v')]
  26
  27 lexer :: [Char] -> LexerOutput
  28 lexer [] = Right []
  29 lexer x = case lex x of
  30         (Right t, rest) = lexer rest >>= \ts.Right [t:ts]
  31         (Left e, _) = Left e
  32
  33 lex :: [Char] -> (Either String Token, [Char])
  34 lex [] = (Right EndOfFileToken, [])
  35 lex ['/':'/':x:rest] = if (x == '\n') (lex rest) (lex ['/':'/':rest])
  36 lex ['/':'*':x1:x2:rest] = if (x1 == '*' && x2 == '/')
  37         (lex rest) (lex ['/':'*':rest])
  38 lex ['v':'a':'r':rest] = (Right VarToken, rest)
  39 lex ['V':'o':'i':'d':rest] = (Right VoidToken, rest)
  40 lex ['r':'e':'t':'u':'r':'n':rest] = (Right ReturnToken, rest)
  41 lex ['i':'f':rest] = (Right IfToken, rest)
  42 lex ['e':'l':'s':'e':rest] = (Right ElseToken, rest)
  43 lex ['w':'h':'i':'l':'e':rest] = (Right WhileToken, rest)
  44 lex ['T':'r':'u':'e':rest] = (Right TrueToken, rest)
  45 lex ['F':'a':'l':'s':'e':rest] = (Right FalseToken, rest)
  46 lex ['I':'n':'t':rest] = (Right IntTypeToken, rest)
  47 lex ['C':'h':'a':'r':rest] = (Right CharTypeToken, rest)
  48 lex ['B':'o':'o':'l':rest] = (Right BoolTypeToken, rest)
  49 lex [':':':':rest] = (Right DoubleColonToken, rest)
  50 lex ['!':'=':rest] = (Right NotEqualToken, rest)
  51 lex ['<':'=':rest] = (Right LesserEqToken, rest)
  52 lex ['>':'=':rest] = (Right GreaterEqToken, rest)
  53 lex ['=':'=':rest] = (Right EqualsToken, rest)
  54 lex ['&':'&':rest] = (Right AmpersandsToken, rest)
  55 lex ['|':'|':rest] = (Right PipesToken, rest)
  56 lex ['-':'>':rest] = (Right ArrowToken, rest)
  57 lex ['\'':x:'\'':rest] = (Right (CharToken x), rest)
  58 lex ['\'':'\\':x:'\'':rest] = case get x EscapeMap of
  59         Just t = (Right (CharToken t), rest)
  60         _ = (Left ("Unknown escape: \\" +++ toString x), [])
  61 lex [x:rest]
  62 # t = get x SingleCharTokens
  63 | isJust t = (Right (fromJust t), rest)
  64 | isSpace x = lex rest
  65 | isDigit x = let (is, rest`) = span isDigit rest in
  66         (Right (NumberToken [x:is]), rest`)
  67 | isAlpha x = let (is, rest`) = span (\c.isAlphanum c || c == '_') rest in
  68         (Right (IdentToken [x:is]), rest`)
  69 | otherwise = (Left ("Unexpected character: " +++ toString x), [])