lex.icl

   1 implementation module lex
   2
   3 import Control.Monad
   4 import Data.Either
   5 import Data.Maybe
   6 import Data.Map
   7 import Data.Func
   8 import StdString
   9 import StdTuple
  10 import StdBool
  11 import StdList
  12 import StdChar
  13 import qualified Text
  14
  15 SingleCharTokens :: Map Char Token
  16 SingleCharTokens = fromList [
  17         ('(', BraceOpenToken), (')', BraceCloseToken), ('{', CBraceOpenToken),
  18         ('}', CBraceCloseToken), ('[', SquareOpenToken), (']', SquareCloseToken),
  19         (',', CommaToken), (':', ColonToken), (';', SColonToken),
  20         ('.', DotToken), ('+', PlusToken), ('*', StarToken), ('/', SlashToken),
  21         ('%', PercentToken), ('=', AssignmentToken), ('<', LesserToken),
  22         ('>', BiggerToken), ('!', ExclamationToken)]
  23
  24 EscapeMap :: Map Char Char
  25 EscapeMap = fromList [('a', toChar 7), ('b', '\b'), ('f', '\f'), ('n', '\n'),
  26         ('r', '\r'), ('t', '\t'), ('v', '\v')]
  27
  28 lexer :: [Char] -> LexerOutput
  29 lexer [] = Right []
  30 lexer x = case lex x of
  31         (Right t, rest) = lexer rest >>= \ts.Right [t:ts]
  32         (Left e, _) = Left e
  33
  34 lex :: [Char] -> (Either String Token, [Char])
  35 lex [] = (Right EndOfFileToken, [])
  36 lex ['/':'/':xs] = lex $ dropWhile ((<>) '\n') xs
  37 lex ['/':'*':xs] =
  38         lex $ tl $ map snd $ dropWhile ((<>) ('*', '/')) $ zip2 [zero:xs] xs
  39 lex ['v':'a':'r':xs] = (Right VarToken, xs)
  40 lex ['V':'o':'i':'d':xs] = (Right VoidToken, xs)
  41 lex ['r':'e':'t':'u':'r':'n':xs] = (Right ReturnToken, xs)
  42 lex ['i':'f':xs] = (Right IfToken, xs)
  43 lex ['e':'l':'s':'e':xs] = (Right ElseToken, xs)
  44 lex ['w':'h':'i':'l':'e':xs] = (Right WhileToken, xs)
  45 lex ['T':'r':'u':'e':xs] = (Right TrueToken, xs)
  46 lex ['F':'a':'l':'s':'e':xs] = (Right FalseToken, xs)
  47 lex ['I':'n':'t':xs] = (Right IntTypeToken, xs)
  48 lex ['C':'h':'a':'r':xs] = (Right CharTypeToken, xs)
  49 lex ['B':'o':'o':'l':xs] = (Right BoolTypeToken, xs)
  50 lex [':':':':xs] = (Right DoubleColonToken, xs)
  51 lex ['!':'=':xs] = (Right NotEqualToken, xs)
  52 lex ['<':'=':xs] = (Right LesserEqToken, xs)
  53 lex ['>':'=':xs] = (Right GreaterEqToken, xs)
  54 lex ['=':'=':xs] = (Right EqualsToken, xs)
  55 lex ['&':'&':xs] = (Right AmpersandsToken, xs)
  56 lex ['|':'|':xs] = (Right PipesToken, xs)
  57 lex ['-':'>':xs] = (Right ArrowToken, xs)
  58 lex ['\'':x:'\'':xs] = (Right (CharToken x), xs)
  59 lex ['\'':'\\':x:'\'':xs] = case get x EscapeMap of
  60         Just t = (Right (CharToken t), xs)
  61         _ = (Left ("Unknown escape: \\" +++ toString x), [])
  62 lex ['-':t=:[x:xs]]
  63 | isDigit x = let (i, r) = span isDigit t in (Right (NumberToken ['-':i]), r)
  64 | otherwise = (Right DashToken, xs)
  65 lex t=:[x:xs] = case get x SingleCharTokens of
  66         (Just tok) = (Right tok, xs)
  67         Nothing
  68         | isSpace x = lex xs
  69         | isDigit x = let (i, r) = span isDigit t in (Right (NumberToken i), r)
  70         | isAlpha x = let (i, r) = span isIdent t in (Right (IdentToken i), r)
  71                 with isIdent c = isAlphanum c || c == '_'
  72         | otherwise = (Left ("Unexpected character: " +++ toString x), [])