mTaskSimulation.icl

   1 implementation module mTaskSimulation
   2
   3 import iTasks
   4 import gdynamic, gCons, GenEq, StdMisc, StdArray
   5 import mTask
   6 derive class iTask Display
   7
   8 eval :: (Main (Eval t p)) -> [String] | toString t
   9 eval {main=(E f)} = [toString (fst (f Rd zero))]
  10
  11 :: State` =
  12   { tasks :: [(Int, State`->State`)]
  13   , store :: [Dyn]
  14   , dpins :: [(DigitalPin, Bool)]
  15   , apins :: [(AnalogPin, Int)]
  16   , serial:: [String]
  17   , millis:: Int
  18   }
  19
  20 instance zero State` where
  21         zero = {store = [], tasks = [], serial = [], millis = 0, dpins = [] , apins = []}
  22
  23 //:: TaskSim :== (Int, State`->State`)
  24 :: Eval t p = E ((ReadWrite t) State` -> (t, State`))
  25 toS2S :: (Eval t p) -> (State`->State`)
  26 toS2S (E f) = \state.snd (f Rd state)
  27
  28 unEval :: (Eval t p) -> ((ReadWrite t) State` -> (t, State`))
  29 unEval (E f) = f
  30
  31 :: ReadWrite t = Rd | Wrt t | Updt (t->t)
  32
  33 (>>==) infixl 1 :: (Eval a p) (a -> Eval b q) -> Eval b r
  34 //(>>== ) (E f) g = E \r s. let (a, s2) = f Rd s; (E h) = g a in h Rd s2
  35 (>>==) (E f) g = E\r s.let (a,t) = f Rd s in unEval (g a) Rd t
  36
  37 rtrn :: t -> Eval t p
  38 rtrn a = E \r s -> (a, s)
  39
  40 yield :: t (Eval s p) -> Eval t Expr
  41 //yield a (E f) = E (\r s.(\(_,t).(a,t)) (f r s))
  42 yield a (E f) = E \r s.(a,snd (f Rd s))
  43
  44 instance arith Eval where
  45   lit a = rtrn a
  46   (+.) x y = x >>==  \a. y >>==  \b. rtrn (a + b)
  47   (-.) x y = x >>==  \a. y >>==  \b. rtrn (a - b)
  48   (*.) x y = x >>==  \a. y >>==  \b. rtrn (a * b)
  49   (/.) x y = x >>==  \a. y >>==  \b. rtrn (a / b)
  50 instance boolExpr Eval where
  51   (&.) x y = x >>==  \a. if a y (rtrn False) // lazy AND
  52   (|.) x y = x >>==  \a. if a (rtrn True) (y >>==  rtrn)
  53   Not x   = x >>==  \a. rtrn (not a)
  54   (==.) x y = x >>==  \a. y >>==  \b. rtrn (a == b)
  55   (!=.) x y = x >>==  \a. y >>==  \b. rtrn (a <> b)
  56   (<.)  x y = x >>==  \a. y >>==  \b. rtrn (a < b)
  57   (>.)  x y = x >>==  \a. y >>==  \b. rtrn (a > b)
  58   (<=.)  x y = x >>==  \a. y >>==  \b. rtrn (a <= b)
  59   (>=.)  x y = x >>==  \a. y >>==  \b. rtrn (a >= b)
  60 instance If Eval p q Expr where
  61   If  c t e = c >>==  \b.if b (toExpr t) (toExpr e)
  62 instance IF Eval where
  63   IF  c t e = c >>==  \b.if b (yield () t) (yield () e)
  64   (?) c t   = c >>==  \b.if b (yield () t) (rtrn ())
  65 instance var2 Eval where
  66   var2 v f = defEval2 v f
  67   con2 v f = defEval2 v f
  68
  69 defEval2 :: t ((Eval t p)->Main (Eval u q)) -> (Main (Eval u q)) | dyn t
  70 defEval2 v f =
  71   {main = E (\r s.(length s.store
  72           , {s & store = s.store ++ [toDyn v]}))
  73   >>==  \n.unMain (f (E (read` n)))}
  74 instance sds Eval where
  75   sds f = defEval f
  76   con f = defEval f
  77
  78 defEval :: ((Eval t p)->In t (Main (Eval u q))) -> (Main (Eval u q)) | dyn t
  79 defEval f =
  80   {main = E \r s.let (v In g) = f (E (read` (length s.store))) in
  81           unEval (unMain g) r {s & store = s.store ++ [toDyn v]}}
  82 instance fun Eval x | arg x where
  83   fun f = e where (g In e) = f (\a.toExpr (g a))
  84 instance mtask Eval x | arg x where
  85  task f = e where
  86   (t In e) = f (\d a.long d >>== \(L i).E\r s.(MTask (length s.tasks),{s&tasks=[(i,toS2S (t a)):s.tasks]}))
  87 instance mtasks Eval x y | arg x & arg y where
  88  tasks f = e where
  89   ((t,u) In e) =
  90    f ((\d a.long d >>== \(L i).E\r s.(MTask (length s.tasks),{s&tasks=[(i,toS2S (t a)):s.tasks]}))
  91    ,(\d b.long d >>== \(L j).E\r s.(MTask (length s.tasks),{s&tasks=[(j,toS2S (u b)):s.tasks]}))
  92    )
  93 instance setDelay Eval where
  94   setDelay d t = d >>==  \(L x). t >>==  \(MTask n).E \r s.(MTask n,{s & tasks = updateAt n (x,snd (s.tasks !! n)) s.tasks})
  95 class toExpr v where toExpr :: (v t p) -> v t Expr
  96 instance toExpr Eval where toExpr (E f) = E f
  97 instance toExpr Code where toExpr (C f) = C f
  98 instance seq Eval where
  99   (>>=.) x f = x >>==   f o rtrn
 100   (:.) x y = x >>==  \_. y
 101 instance assign Eval where
 102   (=.) (E v) e = e >>==  \a. E \r s.v (Wrt a) s
 103 instance output Eval where
 104   output x = x >>==  \a.E \r s.((),{s & serial = s.serial ++ [toCode a]})
 105 instance pinMode Eval where
 106   pinmode p m = rtrn ()
 107 instance digitalIO Eval where
 108   digitalRead  p   = E \rw s=:{dpins, apins}.(readPinD p dpins apins, s)
 109   digitalWrite p b = b >>== \a. E \rw s.(a, writePinD p a s)
 110 instance analogIO Eval where
 111   analogRead  p   = E \rw s=:{apins}. (readPinA p apins, s)
 112   analogWrite p b = b >>== \a. E \rw s.(a, writePinA p a s)
 113 instance noOp Eval where noOp = E \r s.(undef,s)
 114
 115 class arg x :: x -> Int
 116 instance arg () where arg _ = 0
 117 instance arg (Eval t p) | type t where arg _ = 1
 118 instance arg (Eval t p, Eval u q) | type t & type u where arg _ = 2
 119 instance arg (Eval t p, Eval u q, Eval v r) | type t & type u & type v where arg _ = 3
 120 instance arg (Eval t p, Eval u q, Eval v r, Eval w s) | type t & type u & type v where arg _ = 4
 121
 122 instance + String where (+) x y = x +++ y
 123
 124 readPinA :: AnalogPin [(AnalogPin, Int)] -> Int
 125 readPinA p lista
 126   = case [b \\ (q, b) <- lista | p == q] of
 127   []  = 0
 128   [a:x] = a
 129
 130 writePinA :: AnalogPin Int State` -> State`
 131 writePinA p x s
 132   = {s & apins = [(p, x):[(q, y) \\ (q, y) <- s.apins | p <> q]]}
 133
 134 class readPinD p :: p [(DigitalPin,Bool)] [(AnalogPin,Int)] -> Bool
 135 instance readPinD DigitalPin where
 136   readPinD p listd lista
 137   = case [b \\ (q,b) <- listd | p == q] of
 138     [] = False
 139     [a:x] = a
 140 instance readPinD AnalogPin where
 141   readPinD p listd lista
 142   = case [b \\ (q,b) <- lista | p == q] of
 143     [] = False
 144     [a:x] = a <> 0
 145 class writePinD p :: p Bool State` -> State`
 146 instance writePinD DigitalPin where
 147   writePinD p b s=:{dpins} = {s & dpins = [(p, b):[(q, c) \\ (q, c) <- dpins | p <> q]]}
 148 instance writePinD AnalogPin where
 149   writePinD p b s=:{apins} = {s & apins = [(p, if b 1 0):[(q, c) \\ (q, c) <- apins | p <> q]]}
 150
 151
 152 // ----- Interactive Simulation ----- //
 153
 154 derive class iTask DigitalPin, AnalogPin, Dyn, StateInterface, DisplayVar, Pin
 155
 156 simulate :: (Main (Eval a p)) -> Task ()
 157 simulate {main=(E f)} = setup zero where
 158   setup s =
 159           updateInformation "State" [] (toView s) @! ()
 160 //        >>* [ OnAction ActionFinish (always shutDown)
 161 //          , OnAction (Action "setup" []) (hasValue
 162 //            (\si.simloop (snd (f Rd (mergeView s si)))))
 163 //          ]
 164   simloop s =
 165           updateInformation "State" [] (toView s) @!()
 166 //        >>* [ OnAction ActionFinish (always shutDown)
 167 //          , OnAction (Action "clear serial" []) (always (simloop {s & serial = []}))
 168 //          , OnAction ActionNew (always (setup zero))
 169 //          : if (isEmpty s.tasks)
 170 //              []
 171 //              [OnAction (Action "loop" []) (hasValue
 172 //            \si.simloop (step` (mergeView s si)))
 173 //            ]
 174 //          ]
 175
 176 toView :: State` -> StateInterface
 177 toView s =
 178   { serialOut = Display s.serial
 179   , analogPins = s.apins
 180   , digitalPins = s.dpins
 181   , var2iables = map toDisplayVar s.store
 182   , timer = s.millis
 183   , taskCount = Display (length s.tasks)
 184   }
 185
 186 mergeView :: State` StateInterface -> State`
 187 mergeView s si =
 188   { s
 189   & store = [fromDisplayVar new old \\ new <- si.var2iables & old <- s.store]
 190   , dpins = si.digitalPins
 191   , apins = si.analogPins
 192 //  , serial = si.serialOut
 193   , millis = si.timer
 194   }
 195
 196 :: StateInterface =
 197   { serialOut   :: Display [String]
 198   , analogPins  :: [(AnalogPin, Int)]
 199   , digitalPins :: [(DigitalPin, Bool)]
 200   , var2iables   :: [DisplayVar]
 201   , timer     :: Int
 202   , taskCount   :: Display Int
 203   }
 204
 205 toDisplayVar :: Dyn -> DisplayVar
 206 toDisplayVar (Dyn [v])
 207     # i = toInt v
 208     | toString i == v
 209         = INT i
 210         = Variable v
 211 toDisplayVar (Dyn ["L",v]) = LONG (toInt v)
 212 toDisplayVar (Dyn ["Servo",pinKind,pin,pos]) = Servo (fromJust (fromDyn (Dyn [pinKind,pin]))) (toInt pos)
 213 toDisplayVar (Dyn ["LCD",_,_,_,_,_,l1,_,l2,_]) = LCD16x2 l1 l2
 214 toDisplayVar (Dyn l) = DisplayVar l
 215
 216 fromDisplayVar :: DisplayVar Dyn -> Dyn
 217 fromDisplayVar (Variable v)  dyn = Dyn [v]
 218 fromDisplayVar (INT v)     dyn = Dyn [toString v]
 219 fromDisplayVar (LONG v)    dyn = Dyn ["L",toString v]
 220 fromDisplayVar (Servo pin pos) dyn = Dyn (["Servo":let (Dyn p) = toDyn pin in p] ++ [toString pos])
 221 fromDisplayVar (LCD16x2 l1 l2) (Dyn list) = Dyn (updateAt 6 l1 (updateAt 8 l2 list))
 222 fromDisplayVar (DisplayVar l)  dyn = Dyn l
 223
 224 :: DisplayVar
 225     = Variable String
 226     | INT Int
 227     | LONG Int
 228     | Servo Pin Int
 229     | LCD16x2 String String
 230     | DisplayVar [String]
 231
 232
 233 step` :: State` -> State`
 234 step` s =
 235   foldr appTask {s & millis = s.millis + delta, tasks = []}
 236     [(w - delta, f) \\ (w, f) <- s.tasks]
 237 where delta = foldl1 min (map fst s.tasks) // smallest wait
 238
 239 appTask t=:(w,f) s | w <= 0
 240   = f s
 241   = {s & tasks = [t:s.tasks]}
 242
 243 foldl1 op [a:x] = foldl op a x
 244 foldr1 op l :== foldr l
 245   where
 246     foldr [a]     = a
 247     foldr [a:x] = op a (foldr x)
 248
 249 class stringQuotes t | type t :: (Code t p) -> Code t p
 250 instance stringQuotes String where stringQuotes x = c "\"" +.+ x +.+ c "\""
 251 instance stringQuotes t    where stringQuotes x = x
 252
 253
 254 derive   toGenDynamic (), MTask, DigitalPin, AnalogPin, Pin, [], Long//, Servo
 255 derive fromGenDynamic (), MTask, DigitalPin, AnalogPin, Pin, [], Long//, Servo
 256 instance ==   () where (==) _ _ = True
 257
 258
 259