mTaskSimulation.icl

   1 implementation module mTaskSimulation
   2
   3 import iTasks
   4 import gdynamic, gCons, GenEq, StdMisc, StdArray
   5 import mTask
   6 //derive class iTask Display
   7
   8 eval :: (Main (Eval t p)) -> [String] | toString t
   9 eval {main=(E f)} = [toString (fst (f Rd zero))]
  10
  11 :: State` =
  12   { tasks :: [(Int, State`->State`)]
  13   , store :: [Dyn]
  14   , dpins :: [(DigitalPin, Bool)]
  15   , apins :: [(AnalogPin, Int)]
  16   , serial:: [String]
  17   , millis:: Int
  18   }
  19
  20 instance zero State` where
  21         zero = {store = [], tasks = [], serial = [], millis = 0, dpins = [] , apins = []}
  22
  23 //:: TaskSim :== (Int, State`->State`)
  24 :: Eval t p = E ((ReadWrite t) State` -> (t, State`))
  25 toS2S :: (Eval t p) -> (State`->State`)
  26 toS2S (E f) = \state.snd (f Rd state)
  27
  28 unEval :: (Eval t p) -> ((ReadWrite t) State` -> (t, State`))
  29 unEval (E f) = f
  30
  31 :: ReadWrite t = Rd | Wrt t | Updt (t->t)
  32
  33 (>>==) infixl 1 :: (Eval a p) (a -> Eval b q) -> Eval b r
  34 //(>>== ) (E f) g = E \r s. let (a, s2) = f Rd s; (E h) = g a in h Rd s2
  35 (>>==) (E f) g = E\r s.let (a,t) = f Rd s in unEval (g a) Rd t
  36
  37 rtrn :: t -> Eval t p
  38 rtrn a = E \r s -> (a, s)
  39
  40 yield :: t (Eval s p) -> Eval t Expr
  41 //yield a (E f) = E (\r s.(\(_,t).(a,t)) (f r s))
  42 yield a (E f) = E \r s.(a,snd (f Rd s))
  43
  44 instance arith Eval where
  45   lit a = rtrn a
  46   (+.) x y = x >>==  \a. y >>==  \b. rtrn (a + b)
  47   (-.) x y = x >>==  \a. y >>==  \b. rtrn (a - b)
  48   (*.) x y = x >>==  \a. y >>==  \b. rtrn (a * b)
  49   (/.) x y = x >>==  \a. y >>==  \b. rtrn (a / b)
  50 instance boolExpr Eval where
  51   (&.) x y = x >>==  \a. if a y (rtrn False) // lazy AND
  52   (|.) x y = x >>==  \a. if a (rtrn True) (y >>==  rtrn)
  53   Not x   = x >>==  \a. rtrn (not a)
  54   (==.) x y = x >>==  \a. y >>==  \b. rtrn (a == b)
  55   (!=.) x y = x >>==  \a. y >>==  \b. rtrn (a <> b)
  56   (<.)  x y = x >>==  \a. y >>==  \b. rtrn (a < b)
  57   (>.)  x y = x >>==  \a. y >>==  \b. rtrn (a > b)
  58   (<=.)  x y = x >>==  \a. y >>==  \b. rtrn (a <= b)
  59   (>=.)  x y = x >>==  \a. y >>==  \b. rtrn (a >= b)
  60 instance If Eval p q Expr where
  61   If  c t e = c >>==  \b.if b (toExpr t) (toExpr e)
  62 instance IF Eval where
  63   IF  c t e = c >>==  \b.if b (yield () t) (yield () e)
  64   (?) c t   = c >>==  \b.if b (yield () t) (rtrn ())
  65 instance var2 Eval where
  66   var2 v f = defEval2 v f
  67   con2 v f = defEval2 v f
  68
  69 defEval2 :: t ((Eval t p)->Main (Eval u q)) -> (Main (Eval u q)) | dyn t
  70 defEval2 v f =
  71   {main = E (\r s.(length s.store
  72           , {s & store = s.store ++ [toDyn v]}))
  73   >>==  \n.unMain (f (E (read` n)))}
  74 instance sds Eval where
  75   sds f = defEval f
  76   con f = defEval f
  77   pub _ = undef
  78
  79 defEval :: ((Eval t p)->In t (Main (Eval u q))) -> (Main (Eval u q)) | dyn t
  80 defEval f =
  81   {main = E \r s.let (v In g) = f (E (read` (length s.store))) in
  82           unEval (unMain g) r {s & store = s.store ++ [toDyn v]}}
  83 instance fun Eval x | arg x where
  84   fun f = e where (g In e) = f (\a.toExpr (g a))
  85 instance mtask Eval x | arg x where
  86  task f = e where
  87   (t In e) = f (\d a.long d >>== \(L i).E\r s.(MTask (length s.tasks),{s&tasks=[(i,toS2S (t a)):s.tasks]}))
  88 instance mtasks Eval x y | arg x & arg y where
  89  tasks f = e where
  90   ((t,u) In e) =
  91    f ((\d a.long d >>== \(L i).E\r s.(MTask (length s.tasks),{s&tasks=[(i,toS2S (t a)):s.tasks]}))
  92    ,(\d b.long d >>== \(L j).E\r s.(MTask (length s.tasks),{s&tasks=[(j,toS2S (u b)):s.tasks]}))
  93    )
  94 instance setDelay Eval where
  95   setDelay d t = d >>==  \(L x). t >>==  \(MTask n).E \r s.(MTask n,{s & tasks = updateAt n (x,snd (s.tasks !! n)) s.tasks})
  96 class toExpr v where toExpr :: (v t p) -> v t Expr
  97 instance toExpr Eval where toExpr (E f) = E f
  98 instance toExpr Code where toExpr (C f) = C f
  99 instance seq Eval where
 100   (>>=.) x f = x >>==   f o rtrn
 101   (:.) x y = x >>==  \_. y
 102 instance assign Eval where
 103   (=.) (E v) e = e >>==  \a. E \r s.v (Wrt a) s
 104 instance output Eval where
 105   output x = x >>==  \a.E \r s.((),{s & serial = s.serial ++ [toCode a]})
 106 instance pinMode Eval where
 107   pinmode p m = rtrn ()
 108 instance digitalIO Eval where
 109   digitalRead  p   = E \rw s=:{dpins, apins}.(readPinD p dpins apins, s)
 110   digitalWrite p b = b >>== \a. E \rw s.(a, writePinD p a s)
 111 instance analogIO Eval where
 112   analogRead  p   = E \rw s=:{apins}. (readPinA p apins, s)
 113   analogWrite p b = b >>== \a. E \rw s.(a, writePinA p a s)
 114 instance noOp Eval where noOp = E \r s.(undef,s)
 115
 116 class arg x :: x -> Int
 117 instance arg () where arg _ = 0
 118 instance arg (Eval t p) | type t where arg _ = 1
 119 instance arg (Eval t p, Eval u q) | type t & type u where arg _ = 2
 120 instance arg (Eval t p, Eval u q, Eval v r) | type t & type u & type v where arg _ = 3
 121 instance arg (Eval t p, Eval u q, Eval v r, Eval w s) | type t & type u & type v where arg _ = 4
 122
 123 instance + String where (+) x y = x +++ y
 124
 125 readPinA :: AnalogPin [(AnalogPin, Int)] -> Int
 126 readPinA p lista
 127   = case [b \\ (q, b) <- lista | p == q] of
 128   []  = 0
 129   [a:x] = a
 130
 131 writePinA :: AnalogPin Int State` -> State`
 132 writePinA p x s
 133   = {s & apins = [(p, x):[(q, y) \\ (q, y) <- s.apins | p <> q]]}
 134
 135 class readPinD p :: p [(DigitalPin,Bool)] [(AnalogPin,Int)] -> Bool
 136 instance readPinD DigitalPin where
 137   readPinD p listd lista
 138   = case [b \\ (q,b) <- listd | p == q] of
 139     [] = False
 140     [a:x] = a
 141 instance readPinD AnalogPin where
 142   readPinD p listd lista
 143   = case [b \\ (q,b) <- lista | p == q] of
 144     [] = False
 145     [a:x] = a <> 0
 146 class writePinD p :: p Bool State` -> State`
 147 instance writePinD DigitalPin where
 148   writePinD p b s=:{dpins} = {s & dpins = [(p, b):[(q, c) \\ (q, c) <- dpins | p <> q]]}
 149 instance writePinD AnalogPin where
 150   writePinD p b s=:{apins} = {s & apins = [(p, if b 1 0):[(q, c) \\ (q, c) <- apins | p <> q]]}
 151
 152
 153 // ----- Interactive Simulation ----- //
 154
 155 derive class iTask DigitalPin, AnalogPin, Dyn, StateInterface, DisplayVar, Pin
 156
 157 simulate :: (Main (Eval a p)) -> Task ()
 158 simulate {main=(E f)} = setup zero where
 159   setup s =
 160           updateInformation "State" [] (toView s) @! ()
 161 //        >>* [ OnAction ActionFinish (always shutDown)
 162 //          , OnAction (Action "setup" []) (hasValue
 163 //            (\si.simloop (snd (f Rd (mergeView s si)))))
 164 //          ]
 165   simloop s =
 166           updateInformation "State" [] (toView s) @!()
 167 //        >>* [ OnAction ActionFinish (always shutDown)
 168 //          , OnAction (Action "clear serial" []) (always (simloop {s & serial = []}))
 169 //          , OnAction ActionNew (always (setup zero))
 170 //          : if (isEmpty s.tasks)
 171 //              []
 172 //              [OnAction (Action "loop" []) (hasValue
 173 //            \si.simloop (step` (mergeView s si)))
 174 //            ]
 175 //          ]
 176
 177 toView :: State` -> StateInterface
 178 toView s =
 179   { serialOut = Display s.serial
 180   , analogPins = s.apins
 181   , digitalPins = s.dpins
 182   , var2iables = map toDisplayVar s.store
 183   , timer = s.millis
 184   , taskCount = Display (length s.tasks)
 185   }
 186
 187 mergeView :: State` StateInterface -> State`
 188 mergeView s si =
 189   { s
 190   & store = [fromDisplayVar new old \\ new <- si.var2iables & old <- s.store]
 191   , dpins = si.digitalPins
 192   , apins = si.analogPins
 193 //  , serial = si.serialOut
 194   , millis = si.timer
 195   }
 196
 197 :: StateInterface =
 198   { serialOut   :: Display [String]
 199   , analogPins  :: [(AnalogPin, Int)]
 200   , digitalPins :: [(DigitalPin, Bool)]
 201   , var2iables   :: [DisplayVar]
 202   , timer     :: Int
 203   , taskCount   :: Display Int
 204   }
 205
 206 toDisplayVar :: Dyn -> DisplayVar
 207 toDisplayVar (Dyn [v])
 208     # i = toInt v
 209     | toString i == v
 210         = INT i
 211         = Variable v
 212 toDisplayVar (Dyn ["L",v]) = LONG (toInt v)
 213 toDisplayVar (Dyn ["Servo",pinKind,pin,pos]) = Servo (fromJust (fromDyn (Dyn [pinKind,pin]))) (toInt pos)
 214 toDisplayVar (Dyn ["LCD",_,_,_,_,_,l1,_,l2,_]) = LCD16x2 l1 l2
 215 toDisplayVar (Dyn l) = DisplayVar l
 216
 217 fromDisplayVar :: DisplayVar Dyn -> Dyn
 218 fromDisplayVar (Variable v)  dyn = Dyn [v]
 219 fromDisplayVar (INT v)     dyn = Dyn [toString v]
 220 fromDisplayVar (LONG v)    dyn = Dyn ["L",toString v]
 221 fromDisplayVar (Servo pin pos) dyn = Dyn (["Servo":let (Dyn p) = toDyn pin in p] ++ [toString pos])
 222 fromDisplayVar (LCD16x2 l1 l2) (Dyn list) = Dyn (updateAt 6 l1 (updateAt 8 l2 list))
 223 fromDisplayVar (DisplayVar l)  dyn = Dyn l
 224
 225 :: DisplayVar
 226     = Variable String
 227     | INT Int
 228     | LONG Int
 229     | Servo Pin Int
 230     | LCD16x2 String String
 231     | DisplayVar [String]
 232
 233
 234 step` :: State` -> State`
 235 step` s =
 236   foldr appTask {s & millis = s.millis + delta, tasks = []}
 237     [(w - delta, f) \\ (w, f) <- s.tasks]
 238 where delta = foldl1 min (map fst s.tasks) // smallest wait
 239
 240 appTask t=:(w,f) s | w <= 0
 241   = f s
 242   = {s & tasks = [t:s.tasks]}
 243
 244 foldl1 op [a:x] = foldl op a x
 245 foldr1 op l :== foldr l
 246   where
 247     foldr [a]     = a
 248     foldr [a:x] = op a (foldr x)
 249
 250 class stringQuotes t | type t :: (Code t p) -> Code t p
 251 instance stringQuotes String where stringQuotes x = c "\"" +.+ x +.+ c "\""
 252 instance stringQuotes t    where stringQuotes x = x
 253
 254
 255 derive   toGenDynamic (), MTask, DigitalPin, AnalogPin, Pin, [], Long//, Servo
 256 derive fromGenDynamic (), MTask, DigitalPin, AnalogPin, Pin, [], Long//, Servo
 257 instance ==   () where (==) _ _ = True
 258
 259
 260