miTask.icl

   1 module miTask
   2
   3 import StdDebug, StdMisc
   4 from StdFunc import flip
   5
   6 import iTasks
   7 import mTask
   8
   9 from Text import class Text(startsWith,concat,split,join), instance Text String
  10
  11 import Data.Tuple
  12 import System.Directory
  13
  14 import iTasks.UI.Definition
  15
  16 import iTasks._Framework.TaskState
  17 import iTasks._Framework.TaskServer
  18 import iTasks._Framework.IWorld
  19 import iTasks._Framework.Store
  20
  21 import TTY
  22
  23 derive class iTask Queue, TTYSettings, Parity, BaudRate, ByteSize
  24 derive class iTask MTaskMSGRecv, MTaskMSGSend, SerTCP
  25
  26 :: SerTCP = Serial | TCP
  27 :: *Resource | TTYd !*TTY
  28
  29 Start :: *World -> *World
  30 Start world = startEngine mTaskTask world
  31 //Start world = startEngine mTaskTask world
  32
  33 bc :: Main (ByteCode () Stmt)
  34 bc = sds \x=1 In sds \pinnetje=1 In {main =
  35                 IF (digitalRead D3 ==. lit True) (
  36                         x =. x +. lit 1 :.
  37                         pub x
  38                 ) (
  39                         noOp
  40                 ) :.
  41                 IF (pinnetje ==. lit 1) (
  42                         digitalWrite D0 (lit True) :.
  43                         digitalWrite D1 (lit False) :.
  44                         digitalWrite D2 (lit False)
  45                 ) (
  46                         IF (pinnetje ==. lit 2) (
  47                                 digitalWrite D0 (lit False) :.
  48                                 digitalWrite D1 (lit True) :.
  49                                 digitalWrite D2 (lit False)
  50                         ) (
  51                                 digitalWrite D0 (lit False) :.
  52                                 digitalWrite D1 (lit False) :.
  53                                 digitalWrite D2 (lit True)
  54                         )
  55                 )}
  56
  57 deviceSelector :: (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) -> Task ()
  58 deviceSelector ch = enterInformation "Type" []
  59         >>= \ty->case ty of
  60                 TCP = (enterInformation "Host" [] -&&- enterInformation "Port" [])
  61                         >>= \(port,host)->syncNetworkChannel host port ch
  62                 Serial = accWorld getDevices
  63                         >>= \dl->(enterChoice "Device" [] dl -&&- updateInformation "Settings" [] zero)
  64                         >>= \(dev,set)->syncSerialChannel dev set ch
  65         where
  66                 getDevices :: !*World -> *(![String], !*World)
  67                 getDevices w = case readDirectory "/dev" w of
  68                         (Error (errcode, errmsg), w) = abort errmsg
  69                         (Ok entries, w) = (map ((+++) "/dev/") (filter isTTY entries), w)
  70                         where
  71                                 isTTY s = not (isEmpty (filter (flip startsWith s) prefixes))
  72                                 prefixes = ["ttyS", "ttyACM", "ttyUSB", "tty.usbserial"]
  73
  74 mTaskTask :: Task ()
  75 mTaskTask = let (msgs, sdsShares) = makeMsgs 1000 bc in
  76         withShared ([], msgs, False) (\ch->
  77                         deviceSelector ch
  78                 ||- processMessages ch messageShare sdsShares
  79                 ||- viewSharedInformation "channels" [ViewWith lens] ch
  80                 ||- viewSharedInformation "messages" [] messageShare
  81                 ||- viewSh sdsShares ch
  82                 >>* [OnAction ActionFinish (always shutDown)]
  83         )
  84         where
  85                 messageShare :: Shared [String]
  86                 messageShare = sharedStore "mTaskMessagesRecv" []
  87
  88                 processMessages ch msgs sdss = forever (watch ch
  89                         >>* [OnValue (ifValue (not o isEmpty o fst3) (process ch))])
  90                         where
  91                                 process :: (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) ([MTaskMSGRecv],[MTaskMSGSend],Bool) -> Task ()
  92                                 process ch (r,_,_) = upd (appFst3 (const [])) ch >>| process` r
  93                                         where
  94                                                 process` = foldr (\r t->updateSDSs sdss msgs r >>| t) (return ())
  95
  96                 makeMsgs :: Int (Main (ByteCode () Stmt)) -> ([MTaskMSGSend], [(Int, Shared Int)])
  97                 makeMsgs timeout bc
  98                 # (msgs, st) = toMessages timeout (toRealByteCode (unMain bc))
  99                 = (msgs, map f st.sdss)
 100                         where
 101                                 f (i,d) = (i, sharedStore ("mTaskSDS-" +++ toString i) 0)
 102
 103                 updateSDSs :: [(Int, Shared Int)] (Shared [String]) MTaskMSGRecv -> Task ()
 104                 updateSDSs _ m (MTMessage s) = upd (\l->take 20 [s:l]) m @! ()
 105                 updateSDSs _ _ MTEmpty = return ()
 106                 updateSDSs [(id, sh):xs] m n=:(MTPub i d)
 107                 | id == i = set ((toInt d.[0])*265 + toInt d.[1]) sh @! ()
 108                 = updateSDSs xs m n
 109
 110                 lens :: ([MTaskMSGRecv], [MTaskMSGSend],Bool) -> ([String], [String])
 111                 lens (r,s,_) = (map toString r, map toString s)
 112
 113                 viewSh :: [(Int, Shared Int)] (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) -> Task ()
 114                 viewSh [] ch = return ()
 115                 viewSh [(i, sh):xs] ch
 116                 # sharename = "SDS-" +++ toString i
 117                 = (
 118                                 viewSharedInformation ("SDS-" +++ toString i) [] sh ||-
 119                                 forever (
 120                                         enterInformation sharename []
 121                                         >>* [OnAction ActionOk
 122                                                         (ifValue (\j->j>=1 && j <= 3)
 123                                                         (\c->set c sh
 124                                                                 >>= \_->sendMsg (toSDSUpdate i c) ch
 125                                                                 @! ()
 126                                                         )
 127                                                 )]
 128                                 )
 129                         ) ||- viewSh xs ch
 130
 131 sendMsg :: [MTaskMSGSend] (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) -> Task ()
 132 sendMsg m ch = upd (\(r,s,ss)->(r,s ++ m,True)) ch @! ()
 133
 134 syncSerialChannel :: String TTYSettings (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) -> Task ()
 135 syncSerialChannel dev opts rw = Task eval
 136         where
 137                 eval event evalOpts tree=:(TCInit taskId ts) iworld=:{IWorld|world}
 138                 = case TTYopen dev opts world of
 139                         (False, _, world)
 140                         # (err, world) = TTYerror world
 141                         = (ExceptionResult (exception err), {iworld & world=world})
 142                         (True, tty, world)
 143                         # iworld = {iworld & world=world, resources=Just (TTYd tty)}
 144                         = case addBackgroundTask 42 (BackgroundTask (serialDeviceBackgroundTask rw)) iworld of
 145                                 (Error e, iworld) = (ExceptionResult (exception "h"), iworld)
 146                                 (Ok _, iworld) = (ValueResult NoValue {TaskEvalInfo|lastEvent=ts,removedTasks=[],refreshSensitive=True} NoRep (TCBasic taskId ts JSONNull False), iworld)
 147
 148                 eval _ _ tree=:(TCBasic _ ts _ _) iworld
 149                 = (ValueResult NoValue {TaskEvalInfo|lastEvent=ts,removedTasks=[],refreshSensitive=False} NoRep tree, iworld)
 150
 151                 eval event evalOpts tree=:(TCDestroy _) iworld=:{IWorld|resources,world}
 152                 # (TTYd tty) = fromJust resources
 153                 # (ok, world) = TTYclose tty world
 154                 # iworld = {iworld & world=world,resources=Nothing}
 155                 = case removeBackgroundTask 42 iworld of
 156                         (Error e, iworld) = (ExceptionResult (exception "h"), iworld)
 157                         (Ok _, iworld) = (DestroyedResult, iworld)
 158
 159 serialDeviceBackgroundTask :: (Shared ([MTaskMSGRecv],[MTaskMSGSend],Bool)) !*IWorld -> *IWorld
 160 serialDeviceBackgroundTask rw iworld
 161         = case read rw iworld of
 162                 (Error e, iworld) = abort "share couldn't be read"
 163                 (Ok (r,s,ss), iworld)
 164                 # (Just (TTYd tty)) = iworld.resources
 165                 # tty = writet (map encode s) tty
 166                 # (ml, tty) = case TTYavailable tty of
 167                         (False, tty) = ([], tty)
 168                         (_, tty)
 169                         # (l, tty) = TTYreadline tty
 170                         | not (trace_tn ("recv: '" +++ l +++ "'")) = undef
 171                         = ([decode l], tty)
 172                 # iworld = {iworld & resources=Just (TTYd tty)}
 173                 = case write (r++ml,[],False) rw iworld of
 174                         (Error e, iworld) = abort "share couldn't be written"
 175                         (Ok _, iworld) = case notify rw iworld of
 176                                 (Error e, iworld) = abort "share couldn't be notified"
 177                                 (Ok _, iworld) = iworld
 178         where
 179                 writet :: [String] -> (*TTY -> *TTY)
 180                 writet [] = id
 181                 writet [x:xs] = writet xs o TTYwrite x
 182
 183
 184 syncNetworkChannel :: String Int (Shared ([MTaskMSGRecv], [MTaskMSGSend], Bool)) -> Task ()
 185 syncNetworkChannel server port channel
 186         = tcpconnect server port channel {ConnectionHandlers|onConnect=onConnect,whileConnected=whileConnected,onDisconnect=onDisconnect} @! ()
 187         where
 188                 onConnect :: String ([MTaskMSGRecv],[MTaskMSGSend],Bool) -> (MaybeErrorString String, Maybe ([MTaskMSGRecv],[MTaskMSGSend],Bool), [String], Bool)
 189                 onConnect _ (msgs,send,sendStopped)
 190                         = (Ok "", Just (msgs,[],sendStopped), map encode send, False)
 191
 192                 whileConnected :: (Maybe String) String ([MTaskMSGRecv], [MTaskMSGSend],Bool) -> (MaybeErrorString String, Maybe ([MTaskMSGRecv],[MTaskMSGSend],Bool), [String], Bool)
 193                 whileConnected Nothing acc (msgs,send,sendStopped)
 194                 = (Ok acc, Nothing, [], False)
 195 //              = (Ok acc, Just (msgs,[],sendStopped), map encode send, False)
 196
 197                 whileConnected (Just newData) acc (msgs,send,sendStopped)
 198                 | sendStopped = (Ok acc, Just (msgs ++ [decode newData],[],False), map encode send, False)
 199                 = (Ok acc, Just (msgs ++ [decode newData],[],False), [], False)
 200
 201                 onDisconnect :: String ([MTaskMSGRecv],[MTaskMSGSend],Bool) -> (MaybeErrorString String, Maybe ([MTaskMSGRecv],[MTaskMSGSend],Bool))
 202                 onDisconnect l (msgs,send,sendStopped) = (Ok l, Nothing)