parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = many parseLetDecl >>= \fds1->
  31                 some parseFunDecl >>= \fds2->
  32                 pure $ AST (fds1++fds2)
  33
  34 parseLetDecl :: Parser Token FunDecl
  35 parseLetDecl = peekPos >>= \p->
  36                 satTok LetToken >>|
  37                 parseFunType >>= \mt->
  38                 parseIdent >>= \f->
  39                 satTok AssignmentToken >>|
  40                 parseExpr >>= \e->
  41                 satTok SColonToken >>|
  42                 pure (FunDecl p f [] (Just mt) [] [ReturnStmt $ Just e])
  43
  44 parseFunDecl :: Parser Token FunDecl
  45 parseFunDecl = liftM6 FunDecl
  46     (peekPos)
  47     (parseIdent)
  48         (parseBBraces $ parseSepList CommaToken parseIdent)
  49         (optional (satTok DoubleColonToken *> parseFunType))
  50         (satTok CBraceOpenToken *> many parseVarDecl)
  51         (many parseStmt <* satTok CBraceCloseToken)
  52
  53 parseStmt :: Parser Token Stmt
  54 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  55         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  56         (parseSColon parseFunCall
  57                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs)
  58         where
  59                 parseSColon :: (Parser Token a) -> Parser Token a
  60                 parseSColon p = p <* satTok SColonToken
  61
  62                 parseReturnStmt :: Parser Token Stmt
  63                 parseReturnStmt =
  64                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  65
  66                 parseAssStmt :: Parser Token Stmt
  67                 parseAssStmt =
  68                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  69
  70                 parseIfStmt :: Parser Token Stmt
  71                 parseIfStmt = liftM3 IfStmt
  72             (satTok IfToken *> parseBBraces parseExpr)
  73             (parseBlock <|> parseOneLine)
  74             (liftM (fromMaybe [])
  75                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  76
  77                 parseWhileStmt :: Parser Token Stmt
  78                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  79                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  80
  81                 parseBlock :: Parser Token [Stmt]
  82                 parseBlock = parseBCBraces (many parseStmt)
  83
  84                 parseOneLine :: Parser Token [Stmt]
  85                 parseOneLine = pure <$> parseStmt
  86
  87 parseFunType :: Parser Token Type
  88 parseFunType = parseFT >>= \t -> case t of
  89         t1 ->> t2   = pure t
  90         simpleT     = pure $ FuncType simpleT
  91         where
  92         parseFT :: Parser Token Type
  93                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  94                         parseSF
  95                 parseSF :: Parser Token Type
  96                 parseSF = parseBBraces parseFT <|> parseType
  97
  98 parseVarDecl :: Parser Token VarDecl
  99 parseVarDecl = liftM4 VarDecl
 100     peekPos
 101         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
 102         (parseIdent <* satTok AssignmentToken)
 103         (parseExpr <* satTok SColonToken)
 104
 105 parseType :: Parser Token Type
 106 parseType =
 107         trans1 IntTypeToken IntType <|>
 108         trans1 CharTypeToken CharType <|>
 109         trans1 BoolTypeToken BoolType <|>
 110     trans1 VoidToken VoidType <|>
 111         (ListType <$> (parseBSqBraces parseType)) <|>
 112         (TupleType <$> (parseTuple parseType)) <|>
 113         (IdType <$> parseIdent)
 114
 115 parseExpr :: Parser Token Expr
 116 parseExpr = //Operators in order of binding strength
 117         parseOpR (trans1 ColonToken BiCons) $
 118         parseOpR (trans1 PipesToken BiOr) $
 119         parseOpR (trans1 AmpersandsToken BiAnd) $
 120         parseOpR (trans1 EqualsToken BiEquals <|>
 121                         trans1 LesserToken BiLesser <|>
 122                         trans1 BiggerToken BiGreater <|>
 123                         trans1 LesserEqToken BiLesserEq <|>
 124                         trans1 GreaterEqToken BiGreaterEq <|>
 125                         trans1 NotEqualToken BiUnEqual) $
 126         parseOpL (trans1 PlusToken BiPlus <|>
 127                         trans1 DashToken BiMinus) $
 128         parseOpL (trans1 StarToken BiTimes <|>
 129                         trans1 SlashToken BiDivide <|>
 130                         trans1 PercentToken BiMod) $ parseBasicExpr
 131         where
 132                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 133                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 134                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 135                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 136
 137                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 138                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 139                                 ops >>= \op->prev >>= \e->pure (op, e))
 140                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 141
 142                 parseBasicExpr :: Parser Token Expr
 143                 parseBasicExpr = peekPos >>= \pos ->
 144                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 145                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 146                         parseBBraces parseExpr <|>
 147                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 148                         trans1 TrueToken (BoolExpr pos True) <|>
 149                         trans1 FalseToken (BoolExpr pos False) <|>
 150                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 151                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 152                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 153                         (parseFunCall >>= \(ident, args, fs)->
 154                                 pure $ FunExpr pos ident args fs) <|>
 155                         (VarExpr pos <$> parseVarDef)
 156
 157 makeStrExpr :: Pos [Char] -> Expr
 158 makeStrExpr p [] = EmptyListExpr p
 159 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 160
 161 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 162 parseFunCall = liftM3 (\x y z->(x, y, z))
 163         parseIdent
 164         (parseBBraces $ parseSepList CommaToken parseExpr)
 165         parseFieldSelectors
 166
 167 parseVarDef :: Parser Token VarDef
 168 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 169
 170 parseFieldSelectors :: Parser Token [FieldSelector]
 171 parseFieldSelectors = many (satTok DotToken *>
 172         parseIdent >>= \i->case i of
 173                 "hd" = pure FieldHd
 174                 "tl" = pure FieldTl
 175                 "fst" = pure FieldFst
 176                 "snd" = pure FieldSnd
 177                 _ = empty)
 178
 179 parseOp1 :: Parser Token Op1
 180 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 181
 182 parseBBraces :: (Parser Token a) -> Parser Token a
 183 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 184
 185 parseBCBraces :: (Parser Token a) -> Parser Token a
 186 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 187
 188 parseBSqBraces :: (Parser Token a) -> Parser Token a
 189 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 190
 191 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 192 parseTuple p = satTok BraceOpenToken *>
 193         (liftM2 tuple (p <* satTok CommaToken) p)
 194         <* satTok BraceCloseToken
 195
 196 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 197 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 198
 199 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 200 trans2 t f = snd <$> trans t f
 201
 202 trans1 :: TokenValue a -> Parser Token a
 203 trans1 t r = trans2 t $ const r
 204
 205 peekPos :: Parser Token Pos
 206 peekPos = fst <$> peek
 207
 208 derive gPrint TokenValue
 209 derive gEq TokenValue
 210 satTok :: TokenValue -> Parser Token Token
 211 satTok t = top >>= \tok=:({line,col},token) -> if (tokEq t token)
 212         (pure tok) (fail <?> PositionalError line col
 213                 ("ParseError: Unexpected token: " +++ printToString token
 214             +++ "\nExpected: " +++ printToString t))
 215
 216 tokEq (IdentToken _) (IdentToken _) = True
 217 tokEq (NumberToken _) (NumberToken _) = True
 218 tokEq (CharToken _) (CharToken _) = True
 219 tokEq (StringToken _) (StringToken _) = True
 220 tokEq x y = gEq {|*|} x y
 221
 222 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 223 parseSepList sep p =
 224         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 225         (liftM pure p) <|> pure empty
 226
 227 parseIdent :: Parser Token String
 228 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 229
 230 //liftM only goes to liftM5
 231 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6