parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = many parseLetDecl >>= \fds1->
  31                 some parseFunDecl >>= \fds2->
  32                 pure $ AST (fds1++fds2)
  33
  34 parseLetDecl :: Parser Token FunDecl
  35 parseLetDecl = peekPos >>= \p->
  36                 satTok LetToken >>|
  37                 parseFunType >>= \mt->
  38                 parseIdent >>= \f->
  39                 satTok AssignmentToken >>|
  40                 parseExpr >>= \e->
  41                 satTok SColonToken >>|
  42                 pure (FunDecl p f [] (Just mt) [] [ReturnStmt $ Just e])
  43
  44 parseFunDecl :: Parser Token FunDecl
  45 parseFunDecl = liftM6 FunDecl
  46     (peekPos)
  47     (parseIdent)
  48         (parseBBraces $ parseSepList CommaToken parseIdent)
  49         (optional (satTok DoubleColonToken *> parseFunType))
  50         (satTok CBraceOpenToken *> many parseVarDecl)
  51         (many parseStmt <* satTok CBraceCloseToken)
  52
  53 parseStmt :: Parser Token Stmt
  54 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  55         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  56         (parseSColon parseFunCall
  57                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs)
  58         where
  59                 parseSColon :: (Parser Token a) -> Parser Token a
  60                 parseSColon p = p <* satTok SColonToken
  61
  62                 parseReturnStmt :: Parser Token Stmt
  63                 parseReturnStmt =
  64                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  65
  66                 parseAssStmt :: Parser Token Stmt
  67                 parseAssStmt =
  68                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  69
  70                 parseIfStmt :: Parser Token Stmt
  71                 parseIfStmt = liftM3 IfStmt
  72             (satTok IfToken *> parseBBraces parseExpr)
  73             (parseBlock <|> parseOneLine)
  74             (liftM (fromMaybe [])
  75                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  76
  77                 parseWhileStmt :: Parser Token Stmt
  78                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  79                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  80
  81                 parseBlock :: Parser Token [Stmt]
  82                 parseBlock = parseBCBraces (many parseStmt)
  83
  84                 parseOneLine :: Parser Token [Stmt]
  85                 parseOneLine = pure <$> parseStmt
  86
  87 parseFunType :: Parser Token Type
  88 parseFunType = parseFT >>= \t -> case t of
  89         t1 ->> t2   = pure t
  90         simpleT     = pure $ FuncType simpleT
  91         where
  92         parseFT :: Parser Token Type
  93                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  94                         parseSF
  95                 parseSF :: Parser Token Type
  96                 parseSF = parseBBraces parseFT <|> parseType
  97
  98 parseVarDecl :: Parser Token VarDecl
  99 parseVarDecl = liftM4 VarDecl
 100     peekPos
 101         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
 102         (parseIdent <* satTok AssignmentToken)
 103         (parseExpr <* satTok SColonToken)
 104
 105 parseType :: Parser Token Type
 106 parseType =
 107         trans1 IntTypeToken IntType <|>
 108         trans1 CharTypeToken CharType <|>
 109         trans1 BoolTypeToken BoolType <|>
 110     trans1 VoidToken VoidType <|>
 111         (ListType <$> (parseBSqBraces parseType)) <|>
 112         (TupleType <$> (parseTuple parseType)) <|>
 113         (IdType <$> parseIdent)
 114
 115 parseExpr :: Parser Token Expr
 116 parseExpr = parseValueExpr <|> parseLambda
 117
 118 parseValueExpr :: Parser Token Expr
 119 parseValueExpr = //Operators in order of binding strength
 120         parseOpR (trans1 ColonToken BiCons) $
 121         parseOpR (trans1 PipesToken BiOr) $
 122         parseOpR (trans1 AmpersandsToken BiAnd) $
 123         parseOpR (trans1 EqualsToken BiEquals <|>
 124                         trans1 LesserToken BiLesser <|>
 125                         trans1 BiggerToken BiGreater <|>
 126                         trans1 LesserEqToken BiLesserEq <|>
 127                         trans1 GreaterEqToken BiGreaterEq <|>
 128                         trans1 NotEqualToken BiUnEqual) $
 129         parseOpL (trans1 PlusToken BiPlus <|>
 130                         trans1 DashToken BiMinus) $
 131         parseOpL (trans1 StarToken BiTimes <|>
 132                         trans1 SlashToken BiDivide <|>
 133                         trans1 PercentToken BiMod) $ parseBasicExpr
 134         where
 135                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 136                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 137                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 138                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 139
 140                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 141                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 142                                 ops >>= \op->prev >>= \e->pure (op, e))
 143                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 144
 145                 parseBasicExpr :: Parser Token Expr
 146                 parseBasicExpr = peekPos >>= \pos ->
 147                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 148                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 149                         parseBBraces parseExpr <|>
 150                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 151                         trans1 TrueToken (BoolExpr pos True) <|>
 152                         trans1 FalseToken (BoolExpr pos False) <|>
 153                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 154                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 155                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 156                         (parseFunCall >>= \(ident, args, fs)->
 157                                 pure $ FunExpr pos ident args fs) <|>
 158                         (VarExpr pos <$> parseVarDef)
 159
 160 parseLambda :: Parser Token Expr
 161 parseLambda = LambdaExpr <$> peekPos
 162                         <*> (satTok BackslashToken *> many parseIdent)
 163                         <*> (satTok ArrowToken *> parseExpr)
 164
 165 makeStrExpr :: Pos [Char] -> Expr
 166 makeStrExpr p [] = EmptyListExpr p
 167 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 168
 169 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 170 parseFunCall = liftM3 (\x y z->(x, y, z))
 171         parseIdent
 172         (parseBBraces $ parseSepList CommaToken parseExpr)
 173         parseFieldSelectors
 174
 175 parseVarDef :: Parser Token VarDef
 176 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 177
 178 parseFieldSelectors :: Parser Token [FieldSelector]
 179 parseFieldSelectors = many (satTok DotToken *>
 180         parseIdent >>= \i->case i of
 181                 "hd" = pure FieldHd
 182                 "tl" = pure FieldTl
 183                 "fst" = pure FieldFst
 184                 "snd" = pure FieldSnd
 185                 _ = empty)
 186
 187 parseOp1 :: Parser Token Op1
 188 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 189
 190 parseBBraces :: (Parser Token a) -> Parser Token a
 191 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 192
 193 parseBCBraces :: (Parser Token a) -> Parser Token a
 194 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 195
 196 parseBSqBraces :: (Parser Token a) -> Parser Token a
 197 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 198
 199 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 200 parseTuple p = satTok BraceOpenToken *>
 201         (liftM2 tuple (p <* satTok CommaToken) p)
 202         <* satTok BraceCloseToken
 203
 204 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 205 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 206
 207 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 208 trans2 t f = snd <$> trans t f
 209
 210 trans1 :: TokenValue a -> Parser Token a
 211 trans1 t r = trans2 t $ const r
 212
 213 peekPos :: Parser Token Pos
 214 peekPos = fst <$> peek
 215
 216 derive gPrint TokenValue
 217 derive gEq TokenValue
 218 satTok :: TokenValue -> Parser Token Token
 219 satTok t = top >>= \tok=:({line,col},token) -> if (tokEq t token)
 220         (pure tok) (fail <?> PositionalError line col
 221                 ("ParseError: Unexpected token: " +++ printToString token
 222             +++ "\nExpected: " +++ printToString t))
 223
 224 tokEq (IdentToken _) (IdentToken _) = True
 225 tokEq (NumberToken _) (NumberToken _) = True
 226 tokEq (CharToken _) (CharToken _) = True
 227 tokEq (StringToken _) (StringToken _) = True
 228 tokEq x y = gEq {|*|} x y
 229
 230 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 231 parseSepList sep p =
 232         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 233         (liftM pure p) <|> pure empty
 234
 235 parseIdent :: Parser Token String
 236 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 237
 238 //liftM only goes to liftM5
 239 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6