parse.icl

   1 implementation module parse
   2
   3 import Control.Applicative
   4 import Control.Monad
   5 import Control.Monad.State
   6 import Control.Monad.Trans
   7 import Data.Either
   8 import Data.GenEq
   9 import Data.Functor
  10 import Data.Func
  11 import Data.List
  12 import Text.GenPrint
  13 import StdEnv
  14
  15 import ast
  16
  17 (<:>) infixl 0 :: a (m [a]) -> m [a] | Functor m
  18 (<:>) l r = (\xs->[l:xs]) <$> r
  19
  20 :: Token = TTEq | TTSemiColon | TTLambda | TTDot | TTBrackOpen | TTBrackClose | TTBool Bool | TTInt Int | TTOp [Char] | TTIdent [Char]
  21 derive gEq Token
  22 instance toString Token where toString t = printToString t
  23 derive gPrint Token
  24 lex :: [Char] -> Either [String] [Token]
  25 lex [] = pure []
  26 lex [';':ts] = TTSemiColon <:> lex ts
  27 lex [')':ts] = TTBrackClose <:> lex ts
  28 lex ['(':ts] = TTBrackOpen <:> lex ts
  29 lex ['True':ts] = TTBool True <:> lex ts
  30 lex ['False':ts] = TTBool False <:> lex ts
  31 lex ['-',t:ts]
  32         | isDigit t = lex [t:ts] >>= \v->case v of
  33                 [TTInt i:rest] = Right [TTInt (~i):rest]
  34                 x = pure x
  35 lex [t:ts]
  36         | isSpace t = lex ts
  37         | isDigit t
  38                 # (i, ts) = span isDigit [t:ts]
  39                 = TTInt (toInt (toString i)) <:> lex ts
  40         | isAlpha t
  41                 # (i, ts) = span isAlpha [t:ts]
  42                 = TTIdent i <:> lex ts
  43         | isOp t
  44                 # (i, ts) = span isOp [t:ts]
  45                 | i =: ['='] = TTEq <:> lex ts
  46                 | i =: ['.'] = TTDot <:> lex ts
  47                 | i =: ['\\'] = TTLambda <:> lex ts
  48                 = TTOp i <:> lex ts
  49         = Left ["Unexpected: " +++ toString t +++ " ord: " +++ toString (toInt t)]
  50 where
  51         isOp c = isMember c ['!@#$%^&*=+/?-_|\\\'",<>.:']
  52
  53 :: Parser a :== StateT ParseState (Either [String]) a
  54 :: ParseState =
  55         { tokens :: [Token]
  56         , ifxs   :: [((Parser Expression) -> Parser Expression, Int)]
  57         }
  58
  59 pTop :: Parser Token
  60 pTop = getState >>= \s->case s.tokens of
  61         [t:ts] = put {s & tokens=ts} >>| pure t
  62         [] = liftT (Left ["Fully consumed input"])
  63
  64 pEof :: Parser ()
  65 pEof = getState >>= \s->case s.tokens of
  66         [] = pure ()
  67         [t:ts] = liftT (Left ["Expected EOF"])
  68
  69 (?) infixl 9 :: (Parser a) (a -> Bool) -> Parser a
  70 (?) p f = p >>= \v->if (f v) (pure v) empty
  71
  72 pToken :: (Token -> Parser Token)
  73 pToken = (?) pTop o (===)
  74
  75 pChainl :: (Parser (a a -> a)) (Parser a) -> Parser a
  76 pChainl op p = foldl (flip ($)) <$> p <*> many (flip <$> op <*> p)
  77
  78 pChainr :: (Parser (a a -> a)) (Parser a) -> Parser a
  79 pChainr op p = flip ($) <$> p <*> (flip <$> op <*> pChainr op p) <|> p
  80
  81 parse :: [Token] -> Either [String] [Function]
  82 parse ts = fst <$> runStateT (pAST <* pEof) {tokens=ts, ifxs=[]}
  83 where
  84         pAST :: Parser [Function]
  85         pAST = many pFunction >>= mapM \(id, args, body)->Function id args <$
  86                 modify (\t->{t & tokens=body}) <*> pExpression <* pEof
  87
  88         pId = (\(TTIdent i)->i) <$> pTop ? (\t->t=:(TTIdent _))
  89         pOp = (\(TTOp i)->i) <$> pTop ? (\t->t=:(TTOp _))
  90
  91         pFunction :: Parser ([Char], [[Char]], [Token])
  92         pFunction
  93                 =   (\x y z->(x, y, z))
  94                 <$> (pFunId <|> pId)
  95                 <*> many pId
  96                 <*  pToken TTEq
  97                 <*> many (pTop ? ((=!=)TTSemiColon))
  98                 <*  pToken TTSemiColon
  99
 100         pFunId :: Parser [Char]
 101         pFunId = pOp
 102                 >>= \i->pChainr <$ pId ? ((==) ['ifxr']) <|> pChainl <$ pId ? ((==)['ifxl'])
 103                 >>= \p->(\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
 104                 >>= \s->modify (\t->{t & ifxs=[(p (App o App (Var i) <$ pOp ? ((==)i)), s):t.ifxs]})
 105                 >>| pure i
 106
 107         pExpression :: Parser Expression
 108         pExpression = getState >>= \{ifxs}->flip (foldr ($))
 109                         (map fst $ sortBy (on (<) snd) ifxs)
 110                 $   pChainl (pure App)
 111                 $   Lambda <$ pToken TTLambda <*> pId <* pToken TTDot <*> pExpression
 112                 <|> pToken TTBrackOpen *> pExpression <* pToken TTBrackClose
 113                 <|> Lit o Int <$> (\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
 114                 <|> (\(TTBool i)->Lit (Bool i)) <$> pTop ? (\t->t=:(TTBool _))
 115                 <|> Var <$> pId