parse.icl

   1 implementation module parse
   2
   3 import Control.Applicative
   4 import Control.Monad
   5 import Control.Monad.State
   6 import Control.Monad.Trans
   7 import Data.Either
   8 import Data.GenEq
   9 import Data.Functor
  10 import Data.Func
  11 import Data.List
  12 import Data.Tuple
  13 import StdEnv
  14
  15 import ast
  16
  17 (<:>) infixl 0 :: a (m [a]) -> m [a] | Functor m
  18 (<:>) l r = (\xs->[l:xs]) <$> r
  19
  20 :: Token = TTEq | TTSemiColon | TTLambda | TTDot | TTBrackOpen | TTBrackClose | TTBool Bool | TTInt Int | TTOp [Char] | TTIdent [Char]
  21 derive gEq Token
  22 lex :: [Char] -> Either [String] [Token]
  23 lex [] = pure []
  24 lex [';':ts] = TTSemiColon <:> lex ts
  25 lex [')':ts] = TTBrackClose <:> lex ts
  26 lex ['(':ts] = TTBrackOpen <:> lex ts
  27 lex ['True':ts] = TTBool True <:> lex ts
  28 lex ['False':ts] = TTBool False <:> lex ts
  29 lex ['-',t:ts]
  30         | isDigit t = lex [t:ts] >>= \v->case v of
  31                 [TTInt i:rest] = Right [TTInt (~i):rest]
  32                 x = pure x
  33 lex [t:ts]
  34         | isSpace t = lex ts
  35         | isDigit t
  36                 # (i, ts) = span isDigit [t:ts]
  37                 = TTInt (toInt (toString i)) <:> lex ts
  38         | isAlpha t
  39                 # (i, ts) = span isAlpha [t:ts]
  40                 = TTIdent i <:> lex ts
  41         | isOp t
  42                 # (i, ts) = span isOp [t:ts]
  43                 | i =: ['='] = TTEq <:> lex ts
  44                 | i =: ['.'] = TTDot <:> lex ts
  45                 | i =: ['\\'] = TTLambda <:> lex ts
  46                 = TTOp i <:> lex ts
  47         = Left ["Unexpected: " +++ toString t +++ " ord: " +++ toString (toInt t)]
  48 where
  49         isOp c = isMember c ['!@#$%^&*=+/?-_|\\\'",<>.:']
  50
  51 :: Parser a :== StateT ParseState (Either [String]) a
  52 :: ParseState =
  53         { tokens :: [Token]
  54         , ifxs   :: [((Parser Expression) -> Parser Expression, Int)]
  55         }
  56
  57 pTop :: Parser Token
  58 pTop = getState >>= \s->case s.tokens of
  59         [t:ts] = put {s & tokens=ts} >>| pure t
  60         [] = liftT (Left ["Fully consumed input"])
  61
  62 pEof :: Parser ()
  63 pEof = getState >>= \s->case s.tokens of
  64         [] = pure ()
  65         [t:ts] = liftT (Left ["Expected EOF"])
  66
  67 (?) infixl 9 :: (Parser a) (a -> Bool) -> Parser a
  68 (?) p f = p >>= \v->if (f v) (pure v) empty
  69
  70 pToken :: (Token -> Parser Token)
  71 pToken = (?) pTop o (===)
  72
  73 pChainl :: (Parser (a a -> a)) (Parser a) -> Parser a
  74 pChainl op p = foldl (flip ($)) <$> p <*> many (flip <$> op <*> p)
  75
  76 pChainr :: (Parser (a a -> a)) (Parser a) -> Parser a
  77 pChainr op p = flip ($) <$> p <*> (flip <$> op <*> pChainr op p) <|> p
  78
  79 parse :: [Token] -> Either [String] [Function]
  80 parse ts = fst <$> runStateT (pAST <* pEof) {tokens=ts, ifxs=[]}
  81 where
  82         pAST :: Parser [Function]
  83         pAST = many pFunction >>= mapM \(id, args, body)->Function id args <$
  84                 modify (\t->{t & tokens=body}) <*> pExpression <* pEof
  85
  86         pId = (\(TTIdent i)->i) <$> pTop ? (\t->t=:(TTIdent _))
  87         pOp = (\(TTOp i)->i) <$> pTop ? (\t->t=:(TTOp _))
  88
  89         pFunction :: Parser ([Char], [[Char]], [Token])
  90         pFunction
  91                 =   tuple3
  92                 <$> (pFunId <|> pId)
  93                 <*> many pId
  94                 <*  pToken TTEq
  95                 <*> many (pTop ? ((=!=)TTSemiColon))
  96                 <*  pToken TTSemiColon
  97
  98         pFunId :: Parser [Char]
  99         pFunId = pOp
 100                 >>= \i->pChainr <$ pId ? ((==) ['ifxr']) <|> pChainl <$ pId ? ((==)['ifxl'])
 101                 >>= \p->(\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
 102                 >>= \s->modify (\t->{t & ifxs=[(p (App o App (Var i) <$ pOp ? ((==)i)), s):t.ifxs]})
 103                 >>| pure i
 104
 105         pExpression :: Parser Expression
 106         pExpression = getState >>= \{ifxs}->flip (foldr ($))
 107                         (map fst $ sortBy (on (<) snd) ifxs)
 108                 $   pChainl (pure App)
 109                 $   Lambda <$ pToken TTLambda <*> pId <* pToken TTDot <*> pExpression
 110                 <|> pToken TTBrackOpen *> pExpression <* pToken TTBrackClose
 111                 <|> Lit o Int <$> (\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
 112                 <|> (\(TTBool i)->Lit (Bool i)) <$> pTop ? (\t->t=:(TTBool _))
 113                 <|> Var <$> pId