parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = many parseLetDecl >>= \fds1->
  31                 some parseFunDecl >>= \fds2->
  32                 pure $ AST (fds1++fds2)
  33
  34 parseLetDecl :: Parser Token FunDecl
  35 parseLetDecl = peekPos >>= \p->
  36                 satTok LetToken >>|
  37                 parseFunType >>= \mt->
  38                 parseIdent >>= \f->
  39                 satTok AssignmentToken >>|
  40                 parseExpr >>= \e->
  41                 satTok SColonToken >>|
  42                 pure (FunDecl p f [] (Just mt) [] [ReturnStmt $ Just e])
  43
  44 parseFunDecl :: Parser Token FunDecl
  45 parseFunDecl = liftM6 FunDecl
  46     (peekPos)
  47     (parseIdent)
  48         (parseBBraces $ parseSepList CommaToken parseIdent)
  49         (optional (satTok DoubleColonToken *> parseFunType))
  50         (satTok CBraceOpenToken *> many parseVarDecl)
  51         (many parseStmt <* satTok CBraceCloseToken)
  52
  53 parseStmt :: Parser Token Stmt
  54 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  55         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  56         (parseSColon parseFunCall
  57                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs)
  58         where
  59                 parseSColon :: (Parser Token a) -> Parser Token a
  60                 parseSColon p = p <* satTok SColonToken
  61
  62                 parseReturnStmt :: Parser Token Stmt
  63                 parseReturnStmt =
  64                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  65
  66                 parseAssStmt :: Parser Token Stmt
  67                 parseAssStmt =
  68                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  69
  70                 parseIfStmt :: Parser Token Stmt
  71                 parseIfStmt = liftM3 IfStmt
  72             (satTok IfToken *> parseBBraces parseExpr)
  73             (parseBlock <|> parseOneLine)
  74             (liftM (fromMaybe [])
  75                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  76
  77                 parseWhileStmt :: Parser Token Stmt
  78                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  79                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  80
  81                 parseBlock :: Parser Token [Stmt]
  82                 parseBlock = parseBCBraces (many parseStmt)
  83
  84                 parseOneLine :: Parser Token [Stmt]
  85                 parseOneLine = pure <$> parseStmt
  86
  87 parseFunType :: Parser Token Type
  88 parseFunType = parseFT >>= \t -> case t of
  89         t1 ->> t2   = pure t
  90         simpleT     = pure $ FuncType simpleT
  91         where
  92         parseFT :: Parser Token Type
  93                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  94                         parseSF
  95                 parseSF :: Parser Token Type
  96                 parseSF = parseBBraces parseFT <|> parseType
  97
  98 parseVarDecl :: Parser Token VarDecl
  99 parseVarDecl = liftM4 VarDecl
 100     peekPos
 101         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
 102         (parseIdent <* satTok AssignmentToken)
 103         (parseExpr <* satTok SColonToken)
 104
 105 parseType :: Parser Token Type
 106 parseType =
 107         trans1 IntTypeToken IntType <|>
 108         trans1 CharTypeToken CharType <|>
 109         trans1 BoolTypeToken BoolType <|>
 110     trans1 VoidToken VoidType <|>
 111         (ListType <$> (parseBSqBraces parseType)) <|>
 112         (TupleType <$> (parseTuple parseType)) <|>
 113         (IdType <$> parseIdent)
 114
 115 parseExpr :: Parser Token Expr
 116 parseExpr = parseValueExpr <|> parseLambda
 117 parseValueExpr :: Parser Token Expr
 118 parseValueExpr = //Operators in order of binding strength
 119         parseOpR (trans1 ColonToken BiCons) $
 120         parseOpR (trans1 PipesToken BiOr) $
 121         parseOpR (trans1 AmpersandsToken BiAnd) $
 122         parseOpR (trans1 EqualsToken BiEquals <|>
 123                         trans1 LesserToken BiLesser <|>
 124                         trans1 BiggerToken BiGreater <|>
 125                         trans1 LesserEqToken BiLesserEq <|>
 126                         trans1 GreaterEqToken BiGreaterEq <|>
 127                         trans1 NotEqualToken BiUnEqual) $
 128         parseOpL (trans1 PlusToken BiPlus <|>
 129                         trans1 DashToken BiMinus) $
 130         parseOpL (trans1 StarToken BiTimes <|>
 131                         trans1 SlashToken BiDivide <|>
 132                         trans1 PercentToken BiMod) $ parseBasicExpr
 133         where
 134                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 135                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 136                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 137                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 138
 139                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 140                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 141                                 ops >>= \op->prev >>= \e->pure (op, e))
 142                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 143
 144                 parseBasicExpr :: Parser Token Expr
 145                 parseBasicExpr = peekPos >>= \pos ->
 146                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 147                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 148                         parseBBraces parseExpr <|>
 149                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 150                         trans1 TrueToken (BoolExpr pos True) <|>
 151                         trans1 FalseToken (BoolExpr pos False) <|>
 152                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 153                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 154                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 155                         (parseFunCall >>= \(ident, args, fs)->
 156                                 pure $ FunExpr pos ident args fs) <|>
 157                         (VarExpr pos <$> parseVarDef)
 158
 159 parseLambda :: Parser Token Expr
 160 parseLambda = LambdaExpr <$> peekPos
 161                         <*> (satTok BackslashToken *> some parseIdent)
 162                         <*> (satTok ArrowToken *> parseExpr)
 163
 164 makeStrExpr :: Pos [Char] -> Expr
 165 makeStrExpr p [] = EmptyListExpr p
 166 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 167
 168 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 169 parseFunCall = liftM3 (\x y z->(x, y, z))
 170         parseIdent
 171         (parseBBraces $ parseSepList CommaToken parseExpr)
 172         parseFieldSelectors
 173
 174 parseVarDef :: Parser Token VarDef
 175 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 176
 177 parseFieldSelectors :: Parser Token [FieldSelector]
 178 parseFieldSelectors = many (satTok DotToken *>
 179         parseIdent >>= \i->case i of
 180                 "hd" = pure FieldHd
 181                 "tl" = pure FieldTl
 182                 "fst" = pure FieldFst
 183                 "snd" = pure FieldSnd
 184                 _ = empty)
 185
 186 parseOp1 :: Parser Token Op1
 187 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 188
 189 parseBBraces :: (Parser Token a) -> Parser Token a
 190 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 191
 192 parseBCBraces :: (Parser Token a) -> Parser Token a
 193 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 194
 195 parseBSqBraces :: (Parser Token a) -> Parser Token a
 196 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 197
 198 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 199 parseTuple p = satTok BraceOpenToken *>
 200         (liftM2 tuple (p <* satTok CommaToken) p)
 201         <* satTok BraceCloseToken
 202
 203 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 204 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 205
 206 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 207 trans2 t f = snd <$> trans t f
 208
 209 trans1 :: TokenValue a -> Parser Token a
 210 trans1 t r = trans2 t $ const r
 211
 212 peekPos :: Parser Token Pos
 213 peekPos = fst <$> peek
 214
 215 derive gPrint TokenValue
 216 derive gEq TokenValue
 217 satTok :: TokenValue -> Parser Token Token
 218 satTok t = top >>= \tok=:({line,col},token) -> if (tokEq t token)
 219         (pure tok) (fail <?> PositionalError line col
 220                 ("ParseError: Unexpected token: " +++ printToString token
 221             +++ "\nExpected: " +++ printToString t))
 222
 223 tokEq (IdentToken _) (IdentToken _) = True
 224 tokEq (NumberToken _) (NumberToken _) = True
 225 tokEq (CharToken _) (CharToken _) = True
 226 tokEq (StringToken _) (StringToken _) = True
 227 tokEq x y = gEq {|*|} x y
 228
 229 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 230 parseSepList sep p =
 231         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 232         (liftM pure p) <|> pure empty
 233
 234 parseIdent :: Parser Token String
 235 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 236
 237 //liftM only goes to liftM5
 238 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6