parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = AST <$> some parseFunDecl
  31
  32 parseFunDecl :: Parser Token FunDecl
  33 parseFunDecl = liftM6 FunDecl
  34     (peekPos)
  35     (parseIdent)
  36         (parseBBraces $ parseSepList CommaToken parseIdent)
  37         (optional parseFunType)
  38         (satTok CBraceOpenToken *> many parseVarDecl)
  39         (many parseStmt <* satTok CBraceCloseToken)
  40
  41 parseStmt :: Parser Token Stmt
  42 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  43         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  44         (parseSColon parseFunCall
  45                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs)
  46         where
  47                 parseSColon :: (Parser Token a) -> Parser Token a
  48                 parseSColon p = p <* satTok SColonToken
  49
  50                 parseReturnStmt :: Parser Token Stmt
  51                 parseReturnStmt =
  52                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  53
  54                 parseAssStmt :: Parser Token Stmt
  55                 parseAssStmt =
  56                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  57
  58                 parseIfStmt :: Parser Token Stmt
  59                 parseIfStmt = liftM3 IfStmt
  60             (satTok IfToken *> parseBBraces parseExpr)
  61             (parseBlock <|> parseOneLine)
  62             (liftM (fromMaybe [])
  63                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  64
  65                 parseWhileStmt :: Parser Token Stmt
  66                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  67                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  68
  69                 parseBlock :: Parser Token [Stmt]
  70                 parseBlock = parseBCBraces (many parseStmt)
  71
  72                 parseOneLine :: Parser Token [Stmt]
  73                 parseOneLine = pure <$> parseStmt
  74
  75 parseFunType :: Parser Token Type
  76 parseFunType = satTok DoubleColonToken *> parseFT
  77         where
  78         parseFT :: Parser Token Type
  79                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  80                         parseSF
  81                 parseSF :: Parser Token Type
  82                 parseSF = parseBBraces parseFT <|> parseType
  83
  84 parseVarDecl :: Parser Token VarDecl
  85 parseVarDecl = liftM4 VarDecl
  86     peekPos
  87         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
  88         (parseIdent <* satTok AssignmentToken)
  89         (parseExpr <* satTok SColonToken)
  90
  91 parseType :: Parser Token Type
  92 parseType =
  93         trans1 IntTypeToken IntType <|>
  94         trans1 CharTypeToken CharType <|>
  95         trans1 BoolTypeToken BoolType <|>
  96     trans1 VoidToken VoidType <|>
  97         (ListType <$> (parseBSqBraces parseType)) <|>
  98         (TupleType <$> (parseTuple parseType)) <|>
  99         (IdType <$> parseIdent)
 100
 101 parseExpr :: Parser Token Expr
 102 parseExpr = //Operators in order of binding strength
 103         parseOpR (trans1 ColonToken BiCons) $
 104         parseOpR (trans1 PipesToken BiOr) $
 105         parseOpR (trans1 AmpersandsToken BiAnd) $
 106         parseOpR (trans1 EqualsToken BiEquals <|>
 107                         trans1 LesserToken BiLesser <|>
 108                         trans1 BiggerToken BiGreater <|>
 109                         trans1 LesserEqToken BiLesserEq <|>
 110                         trans1 GreaterEqToken BiGreaterEq <|>
 111                         trans1 NotEqualToken BiUnEqual) $
 112         parseOpL (trans1 PlusToken BiPlus <|>
 113                         trans1 DashToken BiMinus) $
 114         parseOpL (trans1 StarToken BiTimes <|>
 115                         trans1 SlashToken BiDivide <|>
 116                         trans1 PercentToken BiMod) $ parseBasicExpr
 117         where
 118                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 119                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 120                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 121                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 122
 123                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 124                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 125                                 ops >>= \op->prev >>= \e->pure (op, e))
 126                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 127
 128                 parseBasicExpr :: Parser Token Expr
 129                 parseBasicExpr = peekPos >>= \pos ->
 130                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 131                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 132                         parseBBraces parseExpr <|>
 133                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 134                         trans1 TrueToken (BoolExpr pos True) <|>
 135                         trans1 FalseToken (BoolExpr pos False) <|>
 136                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 137                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 138                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 139                         (parseFunCall >>= \(ident, args, fs)->
 140                                 pure $ FunExpr pos ident args fs) <|>
 141                         (VarExpr pos <$> parseVarDef)
 142
 143 makeStrExpr :: Pos [Char] -> Expr
 144 makeStrExpr p [] = EmptyListExpr p
 145 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 146
 147 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 148 parseFunCall = liftM3 (\x y z->(x, y, z))
 149         parseIdent
 150         (parseBBraces $ parseSepList CommaToken parseExpr)
 151         parseFieldSelectors
 152
 153 parseVarDef :: Parser Token VarDef
 154 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 155
 156 parseFieldSelectors :: Parser Token [FieldSelector]
 157 parseFieldSelectors = many (satTok DotToken *>
 158         parseIdent >>= \i->case i of
 159                 "hd" = pure FieldHd
 160                 "tl" = pure FieldTl
 161                 "fst" = pure FieldFst
 162                 "snd" = pure FieldSnd
 163                 _ = empty)
 164
 165 parseOp1 :: Parser Token Op1
 166 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 167
 168 parseBBraces :: (Parser Token a) -> Parser Token a
 169 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 170
 171 parseBCBraces :: (Parser Token a) -> Parser Token a
 172 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 173
 174 parseBSqBraces :: (Parser Token a) -> Parser Token a
 175 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 176
 177 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 178 parseTuple p = satTok BraceOpenToken *>
 179         (liftM2 tuple (p <* satTok CommaToken) p)
 180         <* satTok BraceCloseToken
 181
 182 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 183 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 184
 185 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 186 trans2 t f = snd <$> trans t f
 187
 188 trans1 :: TokenValue a -> Parser Token a
 189 trans1 t r = trans2 t $ const r
 190
 191 peekPos :: Parser Token Pos
 192 peekPos = fst <$> peek
 193
 194 derive gPrint TokenValue
 195 derive gEq TokenValue
 196 satTok :: TokenValue -> Parser Token Token
 197 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 198         (pure tok) (fail <?> PositionalError line col
 199                 ("ParseError: Unexpected token: " +++ printToString token))
 200         where
 201                 eq (IdentToken _) (IdentToken _) = True
 202                 eq (NumberToken _) (NumberToken _) = True
 203                 eq (CharToken _) (CharToken _) = True
 204                 eq (StringToken _) (StringToken _) = True
 205                 eq x y = gEq {|*|} x y
 206
 207 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 208 parseSepList sep p =
 209         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 210         (liftM pure p) <|> pure empty
 211
 212 parseIdent :: Parser Token String
 213 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 214
 215 //liftM only goes to liftM5
 216 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6