parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19 import AST
  20
  21 parser :: LexerOutput -> ParserOutput
  22 parser (Left e) = Left e
  23 parser (Right r) = case runParser parseProgram r of
  24         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  25                 "Unable to parse from: " +++ printToString t)
  26         x = fst x
  27
  28 parseProgram :: Parser Token AST
  29 parseProgram = AST <$> (many parseVarDecl) <*> (some parseFunDecl)
  30
  31 parseFunDecl :: Parser Token FunDecl
  32 parseFunDecl = liftM6 FunDecl
  33     (peekPos)
  34     (parseIdent)
  35         (parseBBraces $ parseSepList CommaToken parseIdent)
  36         (optional parseFunType)
  37         (satTok CBraceOpenToken *> many parseVarDecl)
  38         (many parseStmt <* satTok CBraceCloseToken)
  39
  40 parseStmt :: Parser Token Stmt
  41 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  42         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  43         (FunStmt <$> parseSColon parseFunCall)
  44         where
  45                 parseSColon :: (Parser Token a) -> Parser Token a
  46                 parseSColon p = p <* satTok SColonToken
  47
  48                 parseReturnStmt :: Parser Token Stmt
  49                 parseReturnStmt =
  50                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  51
  52                 parseAssStmt :: Parser Token Stmt
  53                 parseAssStmt =
  54                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  55
  56                 parseIfStmt :: Parser Token Stmt
  57                 parseIfStmt = liftM3 IfStmt
  58             (satTok IfToken *> parseBBraces parseExpr)
  59             (parseBlock <|> parseOneLine)
  60             (liftM (fromMaybe [])
  61                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  62
  63                 parseWhileStmt :: Parser Token Stmt
  64                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  65                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  66
  67                 parseBlock :: Parser Token [Stmt]
  68                 parseBlock = parseBCBraces (many parseStmt)
  69
  70                 parseOneLine :: Parser Token [Stmt]
  71                 parseOneLine = pure <$> parseStmt
  72
  73 parseFunType :: Parser Token Type
  74 parseFunType = satTok DoubleColonToken *> parseFT
  75         where
  76         parseFT :: Parser Token Type
  77         parseFT = ((->>) <$> parseType <* satTok ArrowToken <*> parseFT) <|> parseType
  78
  79 parseVarDecl :: Parser Token VarDecl
  80 parseVarDecl = liftM4 VarDecl
  81     peekPos
  82         (parseType <|> trans1 VarToken VarType )
  83         (parseIdent <* satTok AssignmentToken)
  84         (parseExpr <* satTok SColonToken)
  85
  86 parseType :: Parser Token Type
  87 parseType =
  88         trans1 IntTypeToken IntType <|>
  89         trans1 CharTypeToken CharType <|>
  90         trans1 BoolTypeToken BoolType <|>
  91     trans1 VoidToken VoidType <|>
  92         (ListType <$> (parseBSqBraces parseType)) <|>
  93         (TupleType <$> (parseTuple parseType)) <|>
  94         (IdType <$> parseIdent)
  95
  96 parseExpr :: Parser Token Expr
  97 parseExpr = //Operators in order of binding strength
  98         parseOpR (trans1 ColonToken BiCons) $
  99         parseOpR (trans1 PipesToken BiOr) $
 100         parseOpR (trans1 AmpersandsToken BiAnd) $
 101         parseOpR (trans1 EqualsToken BiEquals <|>
 102                         trans1 LesserToken BiLesser <|>
 103                         trans1 BiggerToken BiGreater <|>
 104                         trans1 LesserEqToken BiLesserEq <|>
 105                         trans1 GreaterEqToken BiGreaterEq <|>
 106                         trans1 NotEqualToken BiUnEqual) $
 107         parseOpL (trans1 PlusToken BiPlus <|>
 108                         trans1 DashToken BiMinus) $
 109         parseOpL (trans1 StarToken BiTimes <|>
 110                         trans1 SlashToken BiDivide <|>
 111                         trans1 PercentToken BiMod) $ parseBasicExpr
 112         where
 113                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 114                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 115                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 116                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 117
 118                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 119                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 120                                 ops >>= \op->prev >>= \e->pure (op, e))
 121                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 122
 123                 parseBasicExpr :: Parser Token Expr
 124                 parseBasicExpr = peekPos >>= \pos ->
 125                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 126                         (FunExpr pos <$> parseFunCall) <|>
 127                         parseBBraces parseExpr <|>
 128                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 129                         trans1 TrueToken (BoolExpr pos True) <|>
 130                         trans1 FalseToken (BoolExpr pos False) <|>
 131                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 132                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 133                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 134                         (VarExpr pos <$> parseVarDef)
 135
 136 parseFunCall :: Parser Token FunCall
 137 parseFunCall = FunCall <$> parseIdent <*>
 138         (parseBBraces $ parseSepList CommaToken parseExpr)
 139
 140 parseVarDef :: Parser Token VarDef
 141 parseVarDef = liftM2 VarDef
 142         parseIdent
 143         (many (satTok DotToken *> (
 144                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 145                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 146                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 147                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 148
 149 parseOp1 :: Parser Token Op1
 150 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 151
 152 parseBBraces :: (Parser Token a) -> Parser Token a
 153 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 154
 155 parseBCBraces :: (Parser Token a) -> Parser Token a
 156 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 157
 158 parseBSqBraces :: (Parser Token a) -> Parser Token a
 159 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 160
 161 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 162 parseTuple p = satTok BraceOpenToken *>
 163         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 164         <* satTok BraceCloseToken
 165
 166 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 167 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 168
 169 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 170 trans2 t f = snd <$> trans t f
 171
 172 trans1 :: TokenValue a -> Parser Token a
 173 trans1 t r = trans2 t $ const r
 174
 175 peekPos :: Parser Token Pos
 176 peekPos = fst <$> peek
 177
 178 derive gPrint TokenValue
 179 derive gEq TokenValue
 180 satTok :: TokenValue -> Parser Token Token
 181 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 182         (pure tok) (fail <?> PositionalError line col
 183                 ("ParseError: Unexpected token: " +++ printToString token))
 184         where
 185                 eq (IdentToken _)  (IdentToken _) = True
 186                 eq (NumberToken _) (NumberToken _) = True
 187                 eq (CharToken _)   (CharToken _) = True
 188                 eq x y = gEq {|*|} x y
 189
 190 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 191 parseSepList sep p =
 192         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 193         (liftM pure p) <|> pure empty
 194
 195 parseIdent :: Parser Token String
 196 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 197
 198 //liftM only goes to liftM5
 199 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6