parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Control.Monad
  10 import Control.Applicative
  11 import Data.Func
  12 from Data.List import intercalate, replicate, instance Functor []
  13 from Text import class Text(concat), instance Text String
  14 import GenPrint
  15
  16 import yard
  17 import lex
  18
  19 parser :: LexerOutput -> ParserOutput
  20 parser (Left e) = Left e
  21 parser (Right r) = fst $ runParser parseProgram r
  22
  23 parseProgram :: Parser Token AST
  24 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  25
  26 parseFunDecl :: Parser Token FunDecl
  27 parseFunDecl = liftM5 FunDecl
  28         (parseIdent <* satTok BraceOpenToken)
  29         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  30         (optional parseFunType <* satTok CBraceOpenToken)
  31         (many parseVarDecl)
  32         (many parseStmt <* satTok CBraceCloseToken)
  33
  34 parseStmt :: Parser Token Stmt
  35 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  36         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  37         (liftM FunStmt (parseSColon parseFunCall))
  38         where
  39                 parseSColon :: (Parser Token a) -> Parser Token a
  40                 parseSColon p = p <* satTok SColonToken
  41
  42                 parseReturnStmt :: Parser Token Stmt
  43                 parseReturnStmt =
  44                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  45
  46                 parseAssStmt :: Parser Token Stmt
  47                 parseAssStmt =
  48                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  49
  50                 parseIfStmt :: Parser Token Stmt
  51                 parseIfStmt = liftM3 IfStmt
  52             (satTok IfToken *> parseBBraces parseExpr)
  53             (parseBlock <|> parseOneLine)
  54             (liftM (fromMaybe [])
  55                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  56
  57                 parseWhileStmt :: Parser Token Stmt
  58                 parseWhileStmt = satTok WhileToken *>
  59                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  60
  61                 parseBlock :: Parser Token [Stmt]
  62                 parseBlock = parseBCBraces (many parseStmt)
  63
  64                 parseOneLine :: Parser Token [Stmt]
  65                 //first pure makes singleton list from the statement
  66                 parseOneLine = liftM pure parseStmt
  67
  68 parseFunType :: Parser Token FunType
  69 parseFunType = satTok DoubleColonToken *>
  70         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  71         where
  72                 parseInOutType :: Parser Token FunType
  73                 parseInOutType = liftM2 FunType
  74                         (some parseType <* satTok ArrowToken) parseVoidOrType
  75
  76                 parseVoidOrType :: Parser Token (Maybe Type)
  77                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  78                         (liftM Just parseType) <|> pure Nothing
  79
  80 parseVarDecl :: Parser Token VarDecl
  81 parseVarDecl = liftM3 VarDecl
  82         (parseType <|> trans1 VarToken VarType )
  83         (parseIdent <* satTok AssignmentToken)
  84         (parseExpr <* satTok SColonToken)
  85
  86 parseType :: Parser Token Type
  87 parseType =
  88         trans1 IntTypeToken IntType <|>
  89         trans1 CharTypeToken CharType <|>
  90         trans1 BoolTypeToken BoolType <|>
  91         (liftM ListType (parseBSqBraces parseType)) <|>
  92         (liftM TupleType (parseTuple parseType)) <|>
  93         (liftM IdType parseIdent)
  94
  95 parseExpr :: Parser Token Expr
  96 parseExpr = //Operators in order of binding strength
  97         parseOpR (trans1 ColonToken BiCons) $
  98         parseOpR (trans1 PipesToken BiOr) $
  99         parseOpR (trans1 AmpersandsToken BiAnd) $
 100         parseOpR (trans1 EqualsToken BiEquals <|>
 101                         trans1 LesserToken BiLesser <|>
 102                         trans1 BiggerToken BiGreater <|>
 103                         trans1 LesserEqToken BiLesserEq <|>
 104                         trans1 GreaterEqToken BiGreaterEq <|>
 105                         trans1 NotEqualToken BiUnEqual) $
 106         parseOpL (trans1 PlusToken BiPlus <|>
 107                         trans1 DashToken BiMinus) $
 108         parseOpL (trans1 StarToken BiTimes <|>
 109                         trans1 SlashToken BiDivide <|>
 110                         trans1 PercentToken BiMod) $ parseBasicExpr
 111         where
 112                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 113                 parseOpR ops prev = prev >>= \e1->optional (
 114                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 115                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 116
 117                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 118                 parseOpL ops prev = prev >>= \e1->many (
 119                                 ops >>= \op->prev >>= \e->pure (op, e)
 120                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 121
 122                 parseBasicExpr :: Parser Token Expr
 123                 parseBasicExpr =
 124                         (liftM TupleExpr (parseTuple parseExpr)) <|>
 125                         (liftM FunExpr parseFunCall) <|>
 126                         parseBBraces parseExpr <|>
 127                         trans1 EmptyListToken EmptyListExpr <|>
 128                         trans1 TrueToken (BoolExpr True) <|>
 129                         trans1 FalseToken (BoolExpr False) <|>
 130                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 131                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 132                         (liftM2 Op1Expr parseOp1 parseExpr) <|>
 133                         (liftM VarExpr parseVarDef)
 134
 135 parseFunCall :: Parser Token FunCall
 136 parseFunCall = liftM2 FunCall
 137         parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)
 138
 139 parseVarDef :: Parser Token VarDef
 140 parseVarDef = liftM2 VarDef
 141         parseIdent
 142         (many (satTok DotToken *> (
 143                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 144                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 145                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 146                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 147
 148 parseOp1 :: Parser Token Op1
 149 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 150
 151 parseBBraces :: (Parser Token a) -> Parser Token a
 152 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 153
 154 parseBCBraces :: (Parser Token a) -> Parser Token a
 155 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 156
 157 parseBSqBraces :: (Parser Token a) -> Parser Token a
 158 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 159
 160 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 161 parseTuple p = satTok BraceOpenToken *>
 162         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 163         <* satTok BraceCloseToken
 164
 165 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 166 trans2 t f = liftM (\{token}->f token) $ satTok t
 167
 168 trans1 :: TokenValue a -> Parser Token a
 169 trans1 t r = trans2 t $ const r
 170
 171 derive gPrint TokenValue
 172 derive gEq TokenValue
 173 satTok :: TokenValue -> Parser Token Token
 174 satTok t = top >>= \tok=:{line,column,token} -> if (eq t token)
 175         (pure tok) (fail <?> PositionalError line column
 176                 ("ParseError: Unexpected token: " +++ printToString token))
 177         where
 178                 eq (IdentToken _)  (IdentToken _) = True
 179                 eq (NumberToken _) (NumberToken _) = True
 180                 eq (CharToken _)   (CharToken _) = True
 181                 eq x y = gEq {|*|} x y
 182
 183 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 184 parseSepList sep p =
 185         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 186         (liftM pure p) <|> pure empty
 187
 188 parseIdent :: Parser Token String
 189 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 190
 191 instance toString AST where
 192         toString (AST v f) = concat (
 193                 ["\n":printersperse "\n" v] ++
 194                 ["\n":printersperse "\n" f])
 195
 196 class print a :: a -> [String]
 197
 198 printersperse :: String [a] -> [String] | print a
 199 printersperse i j = intercalate [i] (map print j)
 200
 201 instance print FunDecl where
 202         print (FunDecl i as t vs ss) =
 203                 ["\n", i, " (":printersperse "," as] ++
 204                 [")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
 205                 ["{\n\t":printersperse "\n\t" vs] ++
 206                 ["\n":printStatements ss 1] ++ ["}\n"]
 207
 208 printStatements :: [Stmt] Int -> [String]
 209 printStatements [] i = []
 210 printStatements [s:ss] i = (case s of
 211         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 212                 printCodeBlock thens i ++
 213                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 214         (WhileStmt b dos) = indent i ["while (":print b] ++
 215                 [")":printCodeBlock dos i]
 216         (AssStmt vardef val) =
 217                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 218         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 219         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 220         ) ++ printStatements ss i
 221         where
 222                 printCodeBlock :: [Stmt] Int -> [String]
 223                 printCodeBlock [] _ = ["{}\n"]
 224                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 225                 printCodeBlock x i =
 226                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 227
 228                 indent :: Int [String] -> [String]
 229                 indent i rest = replicate i "\t" ++ rest
 230
 231 instance print FunType where
 232         print (FunType at rt) = printersperse " " at ++
 233                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 234
 235 instance print VarDecl where
 236         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 237
 238 instance print Type where
 239         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
 240         print (ListType t) = ["[":print t] ++ ["]"]
 241         print (IdType s) = print s
 242         print IntType = print "Int"
 243         print BoolType = print "Bool"
 244         print CharType = print "Char"
 245         print VarType = print "var"
 246
 247 instance print String where
 248         print s = [s]
 249
 250 instance print FieldSelector where
 251         print FieldHd = print "hd"
 252         print FieldTl = print "tl"
 253         print FieldSnd = print "snd"
 254         print FieldFst = print "fst"
 255
 256 instance print VarDef where
 257         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 258
 259 instance print FunCall where
 260         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 261
 262 instance print Expr where
 263         print (VarExpr vd) = print vd
 264         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 265                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 266                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 267                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 268                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 269                 ," ":print e2] ++ [")"]
 270         print (Op1Expr o e) = ["(",case o of
 271                 UnNegation = "!"; UnMinus = "-"
 272                 :print e] ++ [")"]
 273         print (IntExpr i) = [toString i]
 274         print (CharExpr c) = ["\'", case c of
 275                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 276                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 277                 c = if (c == toChar 7) "\\a" (toString c)
 278                 ,"\'"]
 279         print (BoolExpr b) = [toString b]
 280         print (FunExpr fc) = print fc
 281         print EmptyListExpr = ["[]"]
 282         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]