parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Data.Tuple
  11 import Control.Monad
  12 import Control.Applicative
  13 import Data.Func
  14 import StdMisc
  15 from Data.List import intercalate, replicate, instance Functor []
  16 from Text import class Text(concat), instance Text String
  17 import GenPrint
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = AST <$> some parseFunDecl
  31
  32 parseFunDecl :: Parser Token FunDecl
  33 parseFunDecl = liftM6 FunDecl
  34     (peekPos)
  35     (parseIdent)
  36         (parseBBraces $ parseSepList CommaToken parseIdent)
  37         (optional parseFunType)
  38         (satTok CBraceOpenToken *> many parseVarDecl)
  39         (many parseStmt <* satTok CBraceCloseToken)
  40
  41 parseStmt :: Parser Token Stmt
  42 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  43         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  44         (parseSColon parseFunCall >>= \(ident, args)->pure $ FunStmt ident args)
  45         where
  46                 parseSColon :: (Parser Token a) -> Parser Token a
  47                 parseSColon p = p <* satTok SColonToken
  48
  49                 parseReturnStmt :: Parser Token Stmt
  50                 parseReturnStmt =
  51                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  52
  53                 parseAssStmt :: Parser Token Stmt
  54                 parseAssStmt =
  55                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  56
  57                 parseIfStmt :: Parser Token Stmt
  58                 parseIfStmt = liftM3 IfStmt
  59             (satTok IfToken *> parseBBraces parseExpr)
  60             (parseBlock <|> parseOneLine)
  61             (liftM (fromMaybe [])
  62                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  63
  64                 parseWhileStmt :: Parser Token Stmt
  65                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  66                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  67
  68                 parseBlock :: Parser Token [Stmt]
  69                 parseBlock = parseBCBraces (many parseStmt)
  70
  71                 parseOneLine :: Parser Token [Stmt]
  72                 parseOneLine = pure <$> parseStmt
  73
  74 parseFunType :: Parser Token Type
  75 parseFunType = satTok DoubleColonToken *> parseFT
  76         where
  77         parseFT :: Parser Token Type
  78                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  79                         parseSF
  80                 parseSF :: Parser Token Type
  81                 parseSF = parseBBraces parseFT <|> parseType
  82
  83 parseVarDecl :: Parser Token VarDecl
  84 parseVarDecl = liftM4 VarDecl
  85     peekPos
  86         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
  87         (parseIdent <* satTok AssignmentToken)
  88         (parseExpr <* satTok SColonToken)
  89
  90 parseType :: Parser Token Type
  91 parseType =
  92         trans1 IntTypeToken IntType <|>
  93         trans1 CharTypeToken CharType <|>
  94         trans1 BoolTypeToken BoolType <|>
  95     trans1 VoidToken VoidType <|>
  96         (ListType <$> (parseBSqBraces parseType)) <|>
  97         (TupleType <$> (parseTuple parseType)) <|>
  98         (IdType <$> parseIdent)
  99
 100 parseExpr :: Parser Token Expr
 101 parseExpr = //Operators in order of binding strength
 102         parseOpR (trans1 ColonToken BiCons) $
 103         parseOpR (trans1 PipesToken BiOr) $
 104         parseOpR (trans1 AmpersandsToken BiAnd) $
 105         parseOpR (trans1 EqualsToken BiEquals <|>
 106                         trans1 LesserToken BiLesser <|>
 107                         trans1 BiggerToken BiGreater <|>
 108                         trans1 LesserEqToken BiLesserEq <|>
 109                         trans1 GreaterEqToken BiGreaterEq <|>
 110                         trans1 NotEqualToken BiUnEqual) $
 111         parseOpL (trans1 PlusToken BiPlus <|>
 112                         trans1 DashToken BiMinus) $
 113         parseOpL (trans1 StarToken BiTimes <|>
 114                         trans1 SlashToken BiDivide <|>
 115                         trans1 PercentToken BiMod) $ parseBasicExpr
 116         where
 117                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 118                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 119                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 120                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 121
 122                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 123                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 124                                 ops >>= \op->prev >>= \e->pure (op, e))
 125                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 126
 127                 parseBasicExpr :: Parser Token Expr
 128                 parseBasicExpr = peekPos >>= \pos ->
 129                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 130                         parseBBraces parseExpr <|>
 131                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 132                         trans1 TrueToken (BoolExpr pos True) <|>
 133                         trans1 FalseToken (BoolExpr pos False) <|>
 134                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 135                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 136                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 137                         (parseFunCall >>= \(ident, args)->parseFieldSelectors >>= \fs->
 138                                 pure $ FunExpr pos ident args fs) <|>
 139                         (VarExpr pos <$> parseVarDef)
 140
 141 parseFunCall :: Parser Token (String, [Expr])
 142 parseFunCall = liftM2 tuple
 143         parseIdent
 144         (parseBBraces $ parseSepList CommaToken parseExpr)
 145
 146 parseVarDef :: Parser Token VarDef
 147 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 148
 149 parseFieldSelectors :: Parser Token [FieldSelector]
 150 parseFieldSelectors = many (satTok DotToken *> (
 151         (parseIdent >>= \i.if (i == "hd") (pure FieldHd) empty) <|>
 152         (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 153         (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 154         (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty)))
 155
 156 parseOp1 :: Parser Token Op1
 157 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 158
 159 parseBBraces :: (Parser Token a) -> Parser Token a
 160 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 161
 162 parseBCBraces :: (Parser Token a) -> Parser Token a
 163 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 164
 165 parseBSqBraces :: (Parser Token a) -> Parser Token a
 166 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 167
 168 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 169 parseTuple p = satTok BraceOpenToken *>
 170         (liftM2 tuple (p <* satTok CommaToken) p)
 171         <* satTok BraceCloseToken
 172
 173 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 174 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 175
 176 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 177 trans2 t f = snd <$> trans t f
 178
 179 trans1 :: TokenValue a -> Parser Token a
 180 trans1 t r = trans2 t $ const r
 181
 182 peekPos :: Parser Token Pos
 183 peekPos = fst <$> peek
 184
 185 derive gPrint TokenValue
 186 derive gEq TokenValue
 187 satTok :: TokenValue -> Parser Token Token
 188 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 189         (pure tok) (fail <?> PositionalError line col
 190                 ("ParseError: Unexpected token: " +++ printToString token))
 191         where
 192                 eq (IdentToken _)  (IdentToken _) = True
 193                 eq (NumberToken _) (NumberToken _) = True
 194                 eq (CharToken _)   (CharToken _) = True
 195                 eq x y = gEq {|*|} x y
 196
 197 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 198 parseSepList sep p =
 199         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 200         (liftM pure p) <|> pure empty
 201
 202 parseIdent :: Parser Token String
 203 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 204
 205 //liftM only goes to liftM5
 206 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6