parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left e
  22 parser (Right r) = fst $ runParser parseProgram r
  23
  24 parseProgram :: Parser Token AST
  25 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  26
  27 parseFunDecl :: Parser Token FunDecl
  28 parseFunDecl = liftM5 FunDecl
  29         (parseIdent <* satTok BraceOpenToken)
  30         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  31         (optional parseFunType <* satTok CBraceOpenToken)
  32         (many parseVarDecl)
  33         (many parseStmt <* satTok CBraceCloseToken)
  34
  35 parseStmt :: Parser Token Stmt
  36 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  37         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  38         (liftM FunStmt (parseSColon parseFunCall))
  39         where
  40                 parseSColon :: (Parser Token a) -> Parser Token a
  41                 parseSColon p = p <* satTok SColonToken
  42
  43                 parseReturnStmt :: Parser Token Stmt
  44                 parseReturnStmt =
  45                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  46
  47                 parseAssStmt :: Parser Token Stmt
  48                 parseAssStmt =
  49                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  50
  51                 parseIfStmt :: Parser Token Stmt
  52                 parseIfStmt = liftM3 IfStmt
  53             (satTok IfToken *> parseBBraces parseExpr)
  54             (parseBlock <|> parseOneLine)
  55             (liftM (fromMaybe [])
  56                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  57
  58
  59                 parseWhileStmt :: Parser Token Stmt
  60                 parseWhileStmt = satTok WhileToken *>
  61                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  62
  63                 parseBlock :: Parser Token [Stmt]
  64                 parseBlock = parseBCBraces (many parseStmt)
  65
  66                 parseOneLine :: Parser Token [Stmt]
  67                 //first pure makes singleton list from the statement
  68                 parseOneLine = liftM pure parseStmt
  69
  70 parseFunType :: Parser Token FunType
  71 parseFunType = satTok DoubleColonToken *>
  72         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  73         where
  74                 parseInOutType :: Parser Token FunType
  75                 parseInOutType = liftM2 FunType
  76                         (some parseType <* satTok ArrowToken) parseVoidOrType
  77
  78                 parseVoidOrType :: Parser Token (Maybe Type)
  79                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  80                         (liftM Just parseType) <|> pure Nothing
  81
  82 parseVarDecl :: Parser Token VarDecl
  83 parseVarDecl = liftM3 VarDecl
  84         (parseType <|> trans1 VarToken VarType )
  85         (parseIdent <* satTok AssignmentToken)
  86         (parseExpr <* satTok SColonToken)
  87
  88 parseType :: Parser Token Type
  89 parseType =
  90         trans1 IntTypeToken IntType <|>
  91         trans1 CharTypeToken CharType <|>
  92         trans1 BoolTypeToken BoolType <|>
  93         (liftM ListType (parseBSqBraces parseType)) <|>
  94         (liftM TupleType (parseTuple parseType)) <|>
  95         (liftM IdType parseIdent)
  96
  97 parseExpr :: Parser Token Expr
  98 parseExpr = //Operators in order of binding strength
  99         parseOpR (trans1 ColonToken BiCons) $
 100         parseOpR (trans1 PipesToken BiOr) $
 101         parseOpR (trans1 AmpersandsToken BiAnd) $
 102         parseOpR (trans1 EqualsToken BiEquals <|>
 103                         trans1 LesserToken BiLesser <|>
 104                         trans1 BiggerToken BiGreater <|>
 105                         trans1 LesserEqToken BiLesserEq <|>
 106                         trans1 GreaterEqToken BiGreaterEq <|>
 107                         trans1 NotEqualToken BiUnEqual) $
 108         parseOpL (trans1 PlusToken BiPlus <|>
 109                         trans1 DashToken BiMinus) $
 110         parseOpL (trans1 StarToken BiTimes <|>
 111                         trans1 SlashToken BiDivide <|>
 112                         trans1 PercentToken BiMod) $ parseBasicExpr
 113         where
 114                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 115                 parseOpR ops prev = prev >>= \e1->optional (
 116                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 117                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 118
 119                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 120                 parseOpL ops prev = prev >>= \e1->many (
 121                                 ops >>= \op->prev >>= \e->pure (op, e)
 122                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 123
 124                 parseBasicExpr :: Parser Token Expr
 125                 parseBasicExpr =
 126                         (liftM TupleExpr (parseTuple parseExpr)) <|>
 127                         (liftM FunExpr parseFunCall) <|>
 128                         parseBBraces parseExpr <|>
 129                         trans1 EmptyListToken EmptyListExpr <|>
 130                         trans1 TrueToken (BoolExpr True) <|>
 131                         trans1 FalseToken (BoolExpr False) <|>
 132                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 133                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 134                         (liftM2 Op1Expr parseOp1 parseExpr) <|>
 135                         (liftM VarExpr parseVarDef)
 136
 137 parseFunCall :: Parser Token FunCall
 138 parseFunCall = liftM2 FunCall
 139         parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)
 140
 141 parseVarDef :: Parser Token VarDef
 142 parseVarDef = liftM2 VarDef
 143         parseIdent
 144         (many (satTok DotToken *> (
 145                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 146                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 147                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 148                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 149
 150 parseOp1 :: Parser Token Op1
 151 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 152
 153 parseBBraces :: (Parser Token a) -> Parser Token a
 154 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 155
 156 parseBCBraces :: (Parser Token a) -> Parser Token a
 157 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 158
 159 parseBSqBraces :: (Parser Token a) -> Parser Token a
 160 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 161
 162 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 163 parseTuple p = satTok BraceOpenToken *>
 164         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 165         <* satTok BraceCloseToken
 166
 167 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 168 trans2 t f = liftM (\{token}->f token) $ satTok t
 169
 170 trans1 :: TokenValue a -> Parser Token a
 171 trans1 t r = trans2 t $ const r
 172
 173 derive gPrint TokenValue
 174 derive gEq TokenValue
 175 satTok :: TokenValue -> Parser Token Token
 176 satTok t = top >>= \tok=:{line,column,token} -> if (eq t token)
 177         (return tok) (fail <?> PositionalError line column ("ParseError: Unexpected token: " +++ printToString token))
 178         where
 179                 eq (IdentToken _)  (IdentToken _) = True
 180                 eq (NumberToken _) (NumberToken _) = True
 181                 eq (CharToken _)   (CharToken _) = True
 182                 eq x y = gEq {|*|} x y
 183
 184 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 185 parseSepList sep p =
 186         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 187         (liftM pure p) <|> pure empty
 188
 189 parseIdent :: Parser Token String
 190 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 191
 192 instance toString AST where
 193         toString (AST v f) = concat (
 194                 ["\n":printersperse "\n" v] ++
 195                 ["\n":printersperse "\n" f])
 196
 197 class print a :: a -> [String]
 198
 199 printersperse :: String [a] -> [String] | print a
 200 printersperse i j = intercalate [i] (map print j)
 201
 202 instance print FunDecl where
 203         print (FunDecl i as t vs ss) =
 204                 ["\n", i, " (":printersperse "," as] ++
 205                 [")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
 206                 ["{\n\t":printersperse "\n\t" vs] ++
 207                 ["\n":printStatements ss 1] ++ ["}\n"]
 208
 209 printStatements :: [Stmt] Int -> [String]
 210 printStatements [] i = []
 211 printStatements [s:ss] i = (case s of
 212         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 213                 printCodeBlock thens i ++
 214                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 215         (WhileStmt b dos) = indent i ["while (":print b] ++
 216                 [")":printCodeBlock dos i]
 217         (AssStmt vardef val) =
 218                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 219         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 220         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 221         ) ++ printStatements ss i
 222         where
 223                 printCodeBlock :: [Stmt] Int -> [String]
 224                 printCodeBlock [] _ = ["{}\n"]
 225                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 226                 printCodeBlock x i =
 227                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 228
 229                 indent :: Int [String] -> [String]
 230                 indent i rest = replicate i "\t" ++ rest
 231
 232 instance print FunType where
 233         print (FunType at rt) = printersperse " " at ++
 234                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 235
 236 instance print VarDecl where
 237         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 238
 239 instance print Type where
 240         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
 241         print (ListType t) = ["[":print t] ++ ["]"]
 242         print (IdType s) = print s
 243         print IntType = print "Int"
 244         print BoolType = print "Bool"
 245         print CharType = print "Char"
 246         print VarType = print "var"
 247
 248 instance print String where
 249         print s = [s]
 250
 251 instance print FieldSelector where
 252         print FieldHd = print "hd"
 253         print FieldTl = print "tl"
 254         print FieldSnd = print "snd"
 255         print FieldFst = print "fst"
 256
 257 instance print VarDef where
 258         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 259
 260 instance print FunCall where
 261         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 262
 263 instance print Expr where
 264         print (VarExpr vd) = print vd
 265         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 266                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 267                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 268                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 269                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 270                 ," ":print e2] ++ [")"]
 271         print (Op1Expr o e) = ["(",case o of
 272                 UnNegation = "!"; UnMinus = "-"
 273                 :print e] ++ [")"]
 274         print (IntExpr i) = [toString i]
 275         print (CharExpr c) = ["\'", case c of
 276                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 277                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 278                 c = if (c == toChar 7) "\\a" (toString c)
 279                 ,"\'"]
 280         print (BoolExpr b) = [toString b]
 281         print (FunExpr fc) = print fc
 282         print EmptyListExpr = ["[]"]
 283         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]