parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Data.Tuple
  11 import Control.Monad
  12 import Control.Applicative
  13 import Data.Func
  14 import StdMisc
  15 from Data.List import intercalate, replicate, instance Functor []
  16 from Text import class Text(concat), instance Text String
  17 import GenPrint
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = AST <$> some parseFunDecl
  31
  32 parseFunDecl :: Parser Token FunDecl
  33 parseFunDecl = liftM6 FunDecl
  34     (peekPos)
  35     (parseIdent)
  36         (parseBBraces $ parseSepList CommaToken parseIdent)
  37         (optional parseFunType)
  38         (satTok CBraceOpenToken *> many parseVarDecl)
  39         (many parseStmt <* satTok CBraceCloseToken)
  40
  41 parseStmt :: Parser Token Stmt
  42 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  43         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  44         (parseSColon parseFunCall >>= \(ident, args)->pure $ FunStmt ident args)
  45         where
  46                 parseSColon :: (Parser Token a) -> Parser Token a
  47                 parseSColon p = p <* satTok SColonToken
  48
  49                 parseReturnStmt :: Parser Token Stmt
  50                 parseReturnStmt =
  51                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  52
  53                 parseAssStmt :: Parser Token Stmt
  54                 parseAssStmt =
  55                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  56
  57                 parseIfStmt :: Parser Token Stmt
  58                 parseIfStmt = liftM3 IfStmt
  59             (satTok IfToken *> parseBBraces parseExpr)
  60             (parseBlock <|> parseOneLine)
  61             (liftM (fromMaybe [])
  62                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  63
  64                 parseWhileStmt :: Parser Token Stmt
  65                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  66                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  67
  68                 parseBlock :: Parser Token [Stmt]
  69                 parseBlock = parseBCBraces (many parseStmt)
  70
  71                 parseOneLine :: Parser Token [Stmt]
  72                 parseOneLine = pure <$> parseStmt
  73
  74 parseFunType :: Parser Token Type
  75 parseFunType = satTok DoubleColonToken *> parseFT
  76         where
  77         parseFT :: Parser Token Type
  78                 parseFT = (liftM2 (->>)
  79                                 ((parseBBraces parseFT <|> parseType) <* satTok ArrowToken)
  80                                 parseFT) <|> parseType
  81
  82 parseVarDecl :: Parser Token VarDecl
  83 parseVarDecl = liftM4 VarDecl
  84     peekPos
  85         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
  86         (parseIdent <* satTok AssignmentToken)
  87         (parseExpr <* satTok SColonToken)
  88
  89 parseType :: Parser Token Type
  90 parseType =
  91         trans1 IntTypeToken IntType <|>
  92         trans1 CharTypeToken CharType <|>
  93         trans1 BoolTypeToken BoolType <|>
  94     trans1 VoidToken VoidType <|>
  95         (ListType <$> (parseBSqBraces parseType)) <|>
  96         (TupleType <$> (parseTuple parseType)) <|>
  97         (IdType <$> parseIdent)
  98
  99 parseExpr :: Parser Token Expr
 100 parseExpr = //Operators in order of binding strength
 101         parseOpR (trans1 ColonToken BiCons) $
 102         parseOpR (trans1 PipesToken BiOr) $
 103         parseOpR (trans1 AmpersandsToken BiAnd) $
 104         parseOpR (trans1 EqualsToken BiEquals <|>
 105                         trans1 LesserToken BiLesser <|>
 106                         trans1 BiggerToken BiGreater <|>
 107                         trans1 LesserEqToken BiLesserEq <|>
 108                         trans1 GreaterEqToken BiGreaterEq <|>
 109                         trans1 NotEqualToken BiUnEqual) $
 110         parseOpL (trans1 PlusToken BiPlus <|>
 111                         trans1 DashToken BiMinus) $
 112         parseOpL (trans1 StarToken BiTimes <|>
 113                         trans1 SlashToken BiDivide <|>
 114                         trans1 PercentToken BiMod) $ parseBasicExpr
 115         where
 116                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 117                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 118                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 119                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 120
 121                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 122                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 123                                 ops >>= \op->prev >>= \e->pure (op, e))
 124                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 125
 126                 parseBasicExpr :: Parser Token Expr
 127                 parseBasicExpr = peekPos >>= \pos ->
 128                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 129                         (parseFunCall >>= \(ident, args)->parseFieldSelectors >>= \fs->
 130                                 pure $ FunExpr pos ident args fs) <|>
 131                         parseBBraces parseExpr <|>
 132                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 133                         trans1 TrueToken (BoolExpr pos True) <|>
 134                         trans1 FalseToken (BoolExpr pos False) <|>
 135                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 136                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 137                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 138                         (VarExpr pos <$> parseVarDef)
 139
 140 parseFunCall :: Parser Token (String, [Expr])
 141 parseFunCall = tuple <$> parseIdent <*> (
 142         (parseBBraces $ parseSepList CommaToken parseExpr) <|> pure [])
 143
 144 parseVarDef :: Parser Token VarDef
 145 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 146
 147 parseFieldSelectors :: Parser Token [FieldSelector]
 148 parseFieldSelectors = many (satTok DotToken *> (
 149         (parseIdent >>= \i.if (i == "hd") (pure FieldHd) empty) <|>
 150         (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 151         (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 152         (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty)))
 153
 154 parseOp1 :: Parser Token Op1
 155 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 156
 157 parseBBraces :: (Parser Token a) -> Parser Token a
 158 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 159
 160 parseBCBraces :: (Parser Token a) -> Parser Token a
 161 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 162
 163 parseBSqBraces :: (Parser Token a) -> Parser Token a
 164 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 165
 166 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 167 parseTuple p = satTok BraceOpenToken *>
 168         (liftM2 tuple (p <* satTok CommaToken) p)
 169         <* satTok BraceCloseToken
 170
 171 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 172 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 173
 174 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 175 trans2 t f = snd <$> trans t f
 176
 177 trans1 :: TokenValue a -> Parser Token a
 178 trans1 t r = trans2 t $ const r
 179
 180 peekPos :: Parser Token Pos
 181 peekPos = fst <$> peek
 182
 183 derive gPrint TokenValue
 184 derive gEq TokenValue
 185 satTok :: TokenValue -> Parser Token Token
 186 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 187         (pure tok) (fail <?> PositionalError line col
 188                 ("ParseError: Unexpected token: " +++ printToString token))
 189         where
 190                 eq (IdentToken _)  (IdentToken _) = True
 191                 eq (NumberToken _) (NumberToken _) = True
 192                 eq (CharToken _)   (CharToken _) = True
 193                 eq x y = gEq {|*|} x y
 194
 195 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 196 parseSepList sep p =
 197         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 198         (liftM pure p) <|> pure empty
 199
 200 parseIdent :: Parser Token String
 201 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 202
 203 //liftM only goes to liftM5
 204 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6