parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = many parseLetDecl >>= \fds1->
  31                 some parseFunDecl >>= \fds2->
  32                 pure $ AST (fds1++fds2)
  33
  34 parseLetDecl :: Parser Token FunDecl
  35 parseLetDecl = peekPos >>= \p->
  36                 satTok LetToken >>|
  37                 parseFunType >>= \mt->
  38                 parseIdent >>= \f->
  39                 satTok AssignmentToken >>|
  40                 parseExpr >>= \e->
  41                 satTok SColonToken >>|
  42                 pure (FunDecl p f [] (Just mt) [] [ReturnStmt $ Just e])
  43
  44 parseFunDecl :: Parser Token FunDecl
  45 parseFunDecl = liftM6 FunDecl
  46     (peekPos)
  47     (parseIdent)
  48         (parseBBraces $ parseSepList CommaToken parseIdent)
  49         (optional (satTok DoubleColonToken *> parseFunType))
  50         (satTok CBraceOpenToken *> many parseVarDecl)
  51         (flatten <$> (many parseStmt <* satTok CBraceCloseToken))
  52
  53 parseStmt :: Parser Token [Stmt]
  54 parseStmt = (parseIfStmt <|> parseWhileStmt <|>
  55         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  56         (parseSColon parseFunCall
  57                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs))
  58         >>= \stmt->case stmt of
  59                 FunStmt "print" args fs = pure $ map (\a->FunStmt "print" [a] []) args
  60                 s = pure [s]
  61         where
  62                 parseSColon :: (Parser Token a) -> Parser Token a
  63                 parseSColon p = p <* satTok SColonToken
  64
  65                 parseReturnStmt :: Parser Token Stmt
  66                 parseReturnStmt =
  67                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  68
  69                 parseAssStmt :: Parser Token Stmt
  70                 parseAssStmt =
  71                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  72
  73                 parseIfStmt :: Parser Token Stmt
  74                 parseIfStmt = liftM3 IfStmt
  75             (satTok IfToken *> parseBBraces parseExpr)
  76             (parseBlock <|> parseOneLine)
  77             (liftM (fromMaybe [])
  78                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  79
  80                 parseWhileStmt :: Parser Token Stmt
  81                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  82                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  83
  84                 parseBlock :: Parser Token [Stmt]
  85                 parseBlock = parseBCBraces (flatten <$> many parseStmt)
  86
  87                 parseOneLine :: Parser Token [Stmt]
  88                 parseOneLine = parseStmt
  89
  90 parseFunType :: Parser Token Type
  91 parseFunType = parseFT >>= \t -> case t of
  92         t1 ->> t2   = pure t
  93         simpleT     = pure $ FuncType simpleT
  94         where
  95         parseFT :: Parser Token Type
  96                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  97                         parseSF
  98                 parseSF :: Parser Token Type
  99                 parseSF = parseBBraces parseFT <|> parseType
 100
 101 parseVarDecl :: Parser Token VarDecl
 102 parseVarDecl = liftM4 VarDecl
 103     peekPos
 104         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
 105         (parseIdent <* satTok AssignmentToken)
 106         (parseExpr <* satTok SColonToken)
 107
 108 parseType :: Parser Token Type
 109 parseType =
 110         trans1 IntTypeToken IntType <|>
 111         trans1 CharTypeToken CharType <|>
 112         trans1 BoolTypeToken BoolType <|>
 113     trans1 VoidToken VoidType <|>
 114         (ListType <$> (parseBSqBraces parseType)) <|>
 115         (TupleType <$> (parseTuple parseType)) <|>
 116         (IdType <$> parseIdent)
 117
 118 parseExpr :: Parser Token Expr
 119 parseExpr = //Operators in order of binding strength
 120         parseOpR (trans1 ColonToken BiCons) $
 121         parseOpR (trans1 PipesToken BiOr) $
 122         parseOpR (trans1 AmpersandsToken BiAnd) $
 123         parseOpR (trans1 EqualsToken BiEquals <|>
 124                         trans1 LesserToken BiLesser <|>
 125                         trans1 BiggerToken BiGreater <|>
 126                         trans1 LesserEqToken BiLesserEq <|>
 127                         trans1 GreaterEqToken BiGreaterEq <|>
 128                         trans1 NotEqualToken BiUnEqual) $
 129         parseOpL (trans1 PlusToken BiPlus <|>
 130                         trans1 DashToken BiMinus) $
 131         parseOpL (trans1 StarToken BiTimes <|>
 132                         trans1 SlashToken BiDivide <|>
 133                         trans1 PercentToken BiMod) $ parseBasicExpr
 134         where
 135                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 136                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 137                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 138                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 139
 140                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 141                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 142                                 ops >>= \op->prev >>= \e->pure (op, e))
 143                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 144
 145                 parseBasicExpr :: Parser Token Expr
 146                 parseBasicExpr = peekPos >>= \pos ->
 147                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 148                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 149                         parseBBraces parseExpr <|>
 150                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 151                         trans1 TrueToken (BoolExpr pos True) <|>
 152                         trans1 FalseToken (BoolExpr pos False) <|>
 153                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 154                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 155                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 156                         (parseFunCall >>= \(ident, args, fs)->
 157                                 pure $ FunExpr pos ident args fs) <|>
 158                         (VarExpr pos <$> parseVarDef)
 159
 160 makeStrExpr :: Pos [Char] -> Expr
 161 makeStrExpr p [] = EmptyListExpr p
 162 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 163
 164 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 165 parseFunCall = liftM3 (\x y z->(x, y, z))
 166         parseIdent
 167         (parseBBraces $ parseSepList CommaToken parseExpr)
 168         parseFieldSelectors
 169
 170 parseVarDef :: Parser Token VarDef
 171 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 172
 173 parseFieldSelectors :: Parser Token [FieldSelector]
 174 parseFieldSelectors = many (satTok DotToken *>
 175         parseIdent >>= \i->case i of
 176                 "hd" = pure FieldHd
 177                 "tl" = pure FieldTl
 178                 "fst" = pure FieldFst
 179                 "snd" = pure FieldSnd
 180                 _ = empty)
 181
 182 parseOp1 :: Parser Token Op1
 183 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 184
 185 parseBBraces :: (Parser Token a) -> Parser Token a
 186 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 187
 188 parseBCBraces :: (Parser Token a) -> Parser Token a
 189 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 190
 191 parseBSqBraces :: (Parser Token a) -> Parser Token a
 192 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 193
 194 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 195 parseTuple p = satTok BraceOpenToken *>
 196         (liftM2 tuple (p <* satTok CommaToken) p)
 197         <* satTok BraceCloseToken
 198
 199 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 200 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 201
 202 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 203 trans2 t f = snd <$> trans t f
 204
 205 trans1 :: TokenValue a -> Parser Token a
 206 trans1 t r = trans2 t $ const r
 207
 208 peekPos :: Parser Token Pos
 209 peekPos = fst <$> peek
 210
 211 derive gPrint TokenValue
 212 derive gEq TokenValue
 213 satTok :: TokenValue -> Parser Token Token
 214 satTok t = top >>= \tok=:({line,col},token) -> if (tokEq t token)
 215         (pure tok) (fail <?> PositionalError line col
 216                 ("ParseError: Unexpected token: " +++ printToString token
 217             +++ "\nExpected: " +++ printToString t))
 218
 219 tokEq (IdentToken _) (IdentToken _) = True
 220 tokEq (NumberToken _) (NumberToken _) = True
 221 tokEq (CharToken _) (CharToken _) = True
 222 tokEq (StringToken _) (StringToken _) = True
 223 tokEq x y = gEq {|*|} x y
 224
 225 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 226 parseSepList sep p =
 227         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 228         (liftM pure p) <|> pure empty
 229
 230 parseIdent :: Parser Token String
 231 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 232
 233 //liftM only goes to liftM5
 234 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6