parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19 import AST
  20
  21 parser :: LexerOutput -> ParserOutput
  22 parser (Left e) = Left e
  23 parser (Right r) = case runParser parseProgram r of
  24         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  25                 "Unable to parse from: " +++ printToString t)
  26         x = fst x
  27
  28 parseProgram :: Parser Token AST
  29 parseProgram = AST <$> (many parseVarDecl) <*> (some parseFunDecl)
  30
  31 parseFunDecl :: Parser Token FunDecl
  32 parseFunDecl = liftM6 FunDecl
  33     (peekPos)
  34     (parseIdent)
  35         (parseBBraces $ parseSepList CommaToken parseIdent)
  36         (optional parseFunType)
  37         (satTok CBraceOpenToken *> many parseVarDecl)
  38         (many parseStmt <* satTok CBraceCloseToken)
  39
  40 parseStmt :: Parser Token Stmt
  41 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  42         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  43         (FunStmt <$> parseSColon parseFunCall)
  44         where
  45                 parseSColon :: (Parser Token a) -> Parser Token a
  46                 parseSColon p = p <* satTok SColonToken
  47
  48                 parseReturnStmt :: Parser Token Stmt
  49                 parseReturnStmt =
  50                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  51
  52                 parseAssStmt :: Parser Token Stmt
  53                 parseAssStmt =
  54                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  55
  56                 parseIfStmt :: Parser Token Stmt
  57                 parseIfStmt = liftM3 IfStmt
  58             (satTok IfToken *> parseBBraces parseExpr)
  59             (parseBlock <|> parseOneLine)
  60             (liftM (fromMaybe [])
  61                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  62
  63                 parseWhileStmt :: Parser Token Stmt
  64                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  65                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  66
  67                 parseBlock :: Parser Token [Stmt]
  68                 parseBlock = parseBCBraces (many parseStmt)
  69
  70                 parseOneLine :: Parser Token [Stmt]
  71                 //first pure makes singleton list from the statement
  72                 parseOneLine = pure <$> parseStmt
  73
  74 parseFunType :: Parser Token FunType
  75 parseFunType = satTok DoubleColonToken *>
  76         (parseInOutType <|> ((FunType []) <$> parseVoidOrType))
  77         where
  78                 parseInOutType :: Parser Token FunType
  79                 parseInOutType =  FunType <$> (some parseType <* satTok ArrowToken) <*> parseVoidOrType
  80
  81                 parseVoidOrType :: Parser Token (Maybe Type)
  82                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  83                         (Just <$> parseType) <|> pure Nothing
  84
  85 parseVarDecl :: Parser Token VarDecl
  86 parseVarDecl = liftM4 VarDecl
  87     peekPos
  88         (parseType <|> trans1 VarToken VarType )
  89         (parseIdent <* satTok AssignmentToken)
  90         (parseExpr <* satTok SColonToken)
  91
  92 parseType :: Parser Token Type
  93 parseType =
  94         trans1 IntTypeToken IntType <|>
  95         trans1 CharTypeToken CharType <|>
  96         trans1 BoolTypeToken BoolType <|>
  97         (ListType <$> (parseBSqBraces parseType)) <|>
  98         (TupleType <$> (parseTuple parseType)) <|>
  99         (IdType <$> parseIdent)
 100
 101 parseExpr :: Parser Token Expr
 102 parseExpr = //Operators in order of binding strength
 103         parseOpR (trans1 ColonToken BiCons) $
 104         parseOpR (trans1 PipesToken BiOr) $
 105         parseOpR (trans1 AmpersandsToken BiAnd) $
 106         parseOpR (trans1 EqualsToken BiEquals <|>
 107                         trans1 LesserToken BiLesser <|>
 108                         trans1 BiggerToken BiGreater <|>
 109                         trans1 LesserEqToken BiLesserEq <|>
 110                         trans1 GreaterEqToken BiGreaterEq <|>
 111                         trans1 NotEqualToken BiUnEqual) $
 112         parseOpL (trans1 PlusToken BiPlus <|>
 113                         trans1 DashToken BiMinus) $
 114         parseOpL (trans1 StarToken BiTimes <|>
 115                         trans1 SlashToken BiDivide <|>
 116                         trans1 PercentToken BiMod) $ parseBasicExpr
 117         where
 118                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 119                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 120                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 121                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 122
 123                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 124                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 125                                 ops >>= \op->prev >>= \e->pure (op, e)
 126                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 127
 128                 parseBasicExpr :: Parser Token Expr
 129                 parseBasicExpr = peekPos >>= \pos ->
 130                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 131                         (FunExpr pos <$> parseFunCall) <|>
 132                         parseBBraces parseExpr <|>
 133                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 134                         trans1 TrueToken (BoolExpr pos True) <|>
 135                         trans1 FalseToken (BoolExpr pos False) <|>
 136                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 137                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 138                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 139                         (VarExpr pos <$> parseVarDef)
 140
 141 parseFunCall :: Parser Token FunCall
 142 parseFunCall = FunCall <$> parseIdent <*> (parseBBraces $ parseSepList CommaToken parseExpr)
 143
 144 parseVarDef :: Parser Token VarDef
 145 parseVarDef = liftM2 VarDef
 146         parseIdent
 147         (many (satTok DotToken *> (
 148                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 149                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 150                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 151                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 152
 153 parseOp1 :: Parser Token Op1
 154 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 155
 156 parseBBraces :: (Parser Token a) -> Parser Token a
 157 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 158
 159 parseBCBraces :: (Parser Token a) -> Parser Token a
 160 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 161
 162 parseBSqBraces :: (Parser Token a) -> Parser Token a
 163 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 164
 165 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 166 parseTuple p = satTok BraceOpenToken *>
 167         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 168         <* satTok BraceCloseToken
 169
 170 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 171 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 172
 173 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 174 trans2 t f = snd <$> trans t f
 175
 176 trans1 :: TokenValue a -> Parser Token a
 177 trans1 t r = trans2 t $ const r
 178
 179 peekPos :: Parser Token Pos
 180 peekPos = fst <$> peek
 181
 182 derive gPrint TokenValue
 183 derive gEq TokenValue
 184 satTok :: TokenValue -> Parser Token Token
 185 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 186         (pure tok) (fail <?> PositionalError line col
 187                 ("ParseError: Unexpected token: " +++ printToString token))
 188         where
 189                 eq (IdentToken _)  (IdentToken _) = True
 190                 eq (NumberToken _) (NumberToken _) = True
 191                 eq (CharToken _)   (CharToken _) = True
 192                 eq x y = gEq {|*|} x y
 193
 194 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 195 parseSepList sep p =
 196         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 197         (liftM pure p) <|> pure empty
 198
 199 parseIdent :: Parser Token String
 200 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 201
 202 //liftM only goes to liftM5
 203 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6