parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19 import AST
  20
  21 parser :: [Token] -> ParserOutput
  22 parser ts = case runParser parseProgram ts of
  23         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  24                 "Unable to parse from: " +++ printToString t)
  25         x = fst x
  26
  27 parseProgram :: Parser Token AST
  28 parseProgram = AST <$> (many parseVarDecl) <*> (some parseFunDecl)
  29
  30 parseFunDecl :: Parser Token FunDecl
  31 parseFunDecl = liftM6 FunDecl
  32     (peekPos)
  33     (parseIdent)
  34         (parseBBraces $ parseSepList CommaToken parseIdent)
  35         (optional parseFunType)
  36         (satTok CBraceOpenToken *> many parseVarDecl)
  37         (many parseStmt <* satTok CBraceCloseToken)
  38
  39 parseStmt :: Parser Token Stmt
  40 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  41         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  42         (FunStmt <$> parseSColon parseFunCall)
  43         where
  44                 parseSColon :: (Parser Token a) -> Parser Token a
  45                 parseSColon p = p <* satTok SColonToken
  46
  47                 parseReturnStmt :: Parser Token Stmt
  48                 parseReturnStmt =
  49                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  50
  51                 parseAssStmt :: Parser Token Stmt
  52                 parseAssStmt =
  53                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  54
  55                 parseIfStmt :: Parser Token Stmt
  56                 parseIfStmt = liftM3 IfStmt
  57             (satTok IfToken *> parseBBraces parseExpr)
  58             (parseBlock <|> parseOneLine)
  59             (liftM (fromMaybe [])
  60                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  61
  62                 parseWhileStmt :: Parser Token Stmt
  63                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  64                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  65
  66                 parseBlock :: Parser Token [Stmt]
  67                 parseBlock = parseBCBraces (many parseStmt)
  68
  69                 parseOneLine :: Parser Token [Stmt]
  70                 parseOneLine = pure <$> parseStmt
  71
  72 parseFunType :: Parser Token Type
  73 parseFunType = satTok DoubleColonToken *> parseFT
  74         where
  75         parseFT :: Parser Token Type
  76         parseFT = ((->>) <$> parseType <* satTok ArrowToken <*> parseFT) <|> parseType
  77
  78 parseVarDecl :: Parser Token VarDecl
  79 parseVarDecl = liftM4 VarDecl
  80     peekPos
  81         (parseType <|> trans1 VarToken VarType )
  82         (parseIdent <* satTok AssignmentToken)
  83         (parseExpr <* satTok SColonToken)
  84
  85 parseType :: Parser Token Type
  86 parseType =
  87         trans1 IntTypeToken IntType <|>
  88         trans1 CharTypeToken CharType <|>
  89         trans1 BoolTypeToken BoolType <|>
  90     trans1 VoidToken VoidType <|>
  91         (ListType <$> (parseBSqBraces parseType)) <|>
  92         (TupleType <$> (parseTuple parseType)) <|>
  93         (IdType <$> parseIdent)
  94
  95 parseExpr :: Parser Token Expr
  96 parseExpr = //Operators in order of binding strength
  97         parseOpR (trans1 ColonToken BiCons) $
  98         parseOpR (trans1 PipesToken BiOr) $
  99         parseOpR (trans1 AmpersandsToken BiAnd) $
 100         parseOpR (trans1 EqualsToken BiEquals <|>
 101                         trans1 LesserToken BiLesser <|>
 102                         trans1 BiggerToken BiGreater <|>
 103                         trans1 LesserEqToken BiLesserEq <|>
 104                         trans1 GreaterEqToken BiGreaterEq <|>
 105                         trans1 NotEqualToken BiUnEqual) $
 106         parseOpL (trans1 PlusToken BiPlus <|>
 107                         trans1 DashToken BiMinus) $
 108         parseOpL (trans1 StarToken BiTimes <|>
 109                         trans1 SlashToken BiDivide <|>
 110                         trans1 PercentToken BiMod) $ parseBasicExpr
 111         where
 112                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 113                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 114                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 115                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 116
 117                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 118                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 119                                 ops >>= \op->prev >>= \e->pure (op, e))
 120                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 121
 122                 parseBasicExpr :: Parser Token Expr
 123                 parseBasicExpr = peekPos >>= \pos ->
 124                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 125                         (FunExpr pos <$> parseFunCall) <|>
 126                         parseBBraces parseExpr <|>
 127                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 128                         trans1 TrueToken (BoolExpr pos True) <|>
 129                         trans1 FalseToken (BoolExpr pos False) <|>
 130                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 131                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 132                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 133                         (VarExpr pos <$> parseVarDef)
 134
 135 parseFunCall :: Parser Token FunCall
 136 parseFunCall = FunCall <$> parseIdent <*>
 137         (parseBBraces $ parseSepList CommaToken parseExpr)
 138
 139 parseVarDef :: Parser Token VarDef
 140 parseVarDef = liftM2 VarDef
 141         parseIdent
 142         (many (satTok DotToken *> (
 143                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 144                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 145                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 146                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 147
 148 parseOp1 :: Parser Token Op1
 149 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 150
 151 parseBBraces :: (Parser Token a) -> Parser Token a
 152 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 153
 154 parseBCBraces :: (Parser Token a) -> Parser Token a
 155 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 156
 157 parseBSqBraces :: (Parser Token a) -> Parser Token a
 158 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 159
 160 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 161 parseTuple p = satTok BraceOpenToken *>
 162         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 163         <* satTok BraceCloseToken
 164
 165 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 166 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 167
 168 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 169 trans2 t f = snd <$> trans t f
 170
 171 trans1 :: TokenValue a -> Parser Token a
 172 trans1 t r = trans2 t $ const r
 173
 174 peekPos :: Parser Token Pos
 175 peekPos = fst <$> peek
 176
 177 derive gPrint TokenValue
 178 derive gEq TokenValue
 179 satTok :: TokenValue -> Parser Token Token
 180 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 181         (pure tok) (fail <?> PositionalError line col
 182                 ("ParseError: Unexpected token: " +++ printToString token))
 183         where
 184                 eq (IdentToken _)  (IdentToken _) = True
 185                 eq (NumberToken _) (NumberToken _) = True
 186                 eq (CharToken _)   (CharToken _) = True
 187                 eq x y = gEq {|*|} x y
 188
 189 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 190 parseSepList sep p =
 191         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 192         (liftM pure p) <|> pure empty
 193
 194 parseIdent :: Parser Token String
 195 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 196
 197 //liftM only goes to liftM5
 198 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6