parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Data.Tuple
  11 import Control.Monad
  12 import Control.Applicative
  13 import Data.Func
  14 import StdMisc
  15 from Data.List import intercalate, replicate, instance Functor []
  16 from Text import class Text(concat), instance Text String
  17 import GenPrint
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = AST <$> some parseFunDecl
  31
  32 parseFunDecl :: Parser Token FunDecl
  33 parseFunDecl = liftM6 FunDecl
  34     (peekPos)
  35     (parseIdent)
  36         (parseBBraces $ parseSepList CommaToken parseIdent)
  37         (optional parseFunType)
  38         (satTok CBraceOpenToken *> many parseVarDecl)
  39         (many parseStmt <* satTok CBraceCloseToken)
  40
  41 parseStmt :: Parser Token Stmt
  42 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  43         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  44         (parseSColon parseFunCall >>= \(ident, args)->pure $ FunStmt ident args)
  45         where
  46                 parseSColon :: (Parser Token a) -> Parser Token a
  47                 parseSColon p = p <* satTok SColonToken
  48
  49                 parseReturnStmt :: Parser Token Stmt
  50                 parseReturnStmt =
  51                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  52
  53                 parseAssStmt :: Parser Token Stmt
  54                 parseAssStmt =
  55                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  56
  57                 parseIfStmt :: Parser Token Stmt
  58                 parseIfStmt = liftM3 IfStmt
  59             (satTok IfToken *> parseBBraces parseExpr)
  60             (parseBlock <|> parseOneLine)
  61             (liftM (fromMaybe [])
  62                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  63
  64                 parseWhileStmt :: Parser Token Stmt
  65                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  66                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  67
  68                 parseBlock :: Parser Token [Stmt]
  69                 parseBlock = parseBCBraces (many parseStmt)
  70
  71                 parseOneLine :: Parser Token [Stmt]
  72                 parseOneLine = pure <$> parseStmt
  73
  74 parseFunType :: Parser Token Type
  75 parseFunType = satTok DoubleColonToken *> parseFT
  76         where
  77         parseFT :: Parser Token Type
  78         parseFT = ((->>) <$> parseType <* satTok ArrowToken <*> parseFT) <|> parseType
  79
  80 parseVarDecl :: Parser Token VarDecl
  81 parseVarDecl = liftM4 VarDecl
  82     peekPos
  83         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
  84         (parseIdent <* satTok AssignmentToken)
  85         (parseExpr <* satTok SColonToken)
  86
  87 parseType :: Parser Token Type
  88 parseType =
  89         trans1 IntTypeToken IntType <|>
  90         trans1 CharTypeToken CharType <|>
  91         trans1 BoolTypeToken BoolType <|>
  92     trans1 VoidToken VoidType <|>
  93         (ListType <$> (parseBSqBraces parseType)) <|>
  94         (TupleType <$> (parseTuple parseType)) <|>
  95         (IdType <$> parseIdent)
  96
  97 parseExpr :: Parser Token Expr
  98 parseExpr = //Operators in order of binding strength
  99         parseOpR (trans1 ColonToken BiCons) $
 100         parseOpR (trans1 PipesToken BiOr) $
 101         parseOpR (trans1 AmpersandsToken BiAnd) $
 102         parseOpR (trans1 EqualsToken BiEquals <|>
 103                         trans1 LesserToken BiLesser <|>
 104                         trans1 BiggerToken BiGreater <|>
 105                         trans1 LesserEqToken BiLesserEq <|>
 106                         trans1 GreaterEqToken BiGreaterEq <|>
 107                         trans1 NotEqualToken BiUnEqual) $
 108         parseOpL (trans1 PlusToken BiPlus <|>
 109                         trans1 DashToken BiMinus) $
 110         parseOpL (trans1 StarToken BiTimes <|>
 111                         trans1 SlashToken BiDivide <|>
 112                         trans1 PercentToken BiMod) $ parseBasicExpr
 113         where
 114                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 115                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 116                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 117                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 118
 119                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 120                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 121                                 ops >>= \op->prev >>= \e->pure (op, e))
 122                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 123
 124                 parseBasicExpr :: Parser Token Expr
 125                 parseBasicExpr = peekPos >>= \pos ->
 126                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 127                         (parseFunCall >>= \(ident, args)->parseFieldSelectors >>= \fs->
 128                                 pure $ FunExpr pos ident args fs) <|>
 129                         parseBBraces parseExpr <|>
 130                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 131                         trans1 TrueToken (BoolExpr pos True) <|>
 132                         trans1 FalseToken (BoolExpr pos False) <|>
 133                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 134                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 135                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 136                         (VarExpr pos <$> parseVarDef)
 137
 138 parseFunCall :: Parser Token (String, [Expr])
 139 parseFunCall = tuple <$> parseIdent <*> (
 140         (parseBBraces $ parseSepList CommaToken parseExpr) <|> pure [])
 141
 142 parseVarDef :: Parser Token VarDef
 143 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 144
 145 parseFieldSelectors :: Parser Token [FieldSelector]
 146 parseFieldSelectors = many (satTok DotToken *> (
 147                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 148                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 149                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 150                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty)))
 151
 152 parseOp1 :: Parser Token Op1
 153 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 154
 155 parseBBraces :: (Parser Token a) -> Parser Token a
 156 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 157
 158 parseBCBraces :: (Parser Token a) -> Parser Token a
 159 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 160
 161 parseBSqBraces :: (Parser Token a) -> Parser Token a
 162 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 163
 164 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 165 parseTuple p = satTok BraceOpenToken *>
 166         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 167         <* satTok BraceCloseToken
 168
 169 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 170 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 171
 172 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 173 trans2 t f = snd <$> trans t f
 174
 175 trans1 :: TokenValue a -> Parser Token a
 176 trans1 t r = trans2 t $ const r
 177
 178 peekPos :: Parser Token Pos
 179 peekPos = fst <$> peek
 180
 181 derive gPrint TokenValue
 182 derive gEq TokenValue
 183 satTok :: TokenValue -> Parser Token Token
 184 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 185         (pure tok) (fail <?> PositionalError line col
 186                 ("ParseError: Unexpected token: " +++ printToString token))
 187         where
 188                 eq (IdentToken _)  (IdentToken _) = True
 189                 eq (NumberToken _) (NumberToken _) = True
 190                 eq (CharToken _)   (CharToken _) = True
 191                 eq x y = gEq {|*|} x y
 192
 193 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 194 parseSepList sep p =
 195         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 196         (liftM pure p) <|> pure empty
 197
 198 parseIdent :: Parser Token String
 199 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 200
 201 //liftM only goes to liftM5
 202 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6