parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Maybe
   9 import Data.Functor
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19 import AST
  20
  21 parser :: LexerOutput -> ParserOutput
  22 parser (Left e) = Left e
  23 parser (Right r) = fst $ runParser parseProgram r
  24
  25 parseProgram :: Parser Token AST
  26 parseProgram = AST <$> (many parseVarDecl) <*> (some parseFunDecl)
  27
  28 parseFunDecl :: Parser Token FunDecl
  29 parseFunDecl = liftM6 FunDecl
  30     (peekPos)
  31     (parseIdent)
  32         (parseBBraces $ parseSepList CommaToken parseIdent)
  33         (optional parseFunType)
  34         (satTok CBraceOpenToken *> many parseVarDecl)
  35         (many parseStmt <* satTok CBraceCloseToken)
  36
  37 parseStmt :: Parser Token Stmt
  38 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  39         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  40         (FunStmt <$> parseSColon parseFunCall)
  41         where
  42                 parseSColon :: (Parser Token a) -> Parser Token a
  43                 parseSColon p = p <* satTok SColonToken
  44
  45                 parseReturnStmt :: Parser Token Stmt
  46                 parseReturnStmt =
  47                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  48
  49                 parseAssStmt :: Parser Token Stmt
  50                 parseAssStmt =
  51                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  52
  53                 parseIfStmt :: Parser Token Stmt
  54                 parseIfStmt = liftM3 IfStmt
  55             (satTok IfToken *> parseBBraces parseExpr)
  56             (parseBlock <|> parseOneLine)
  57             (liftM (fromMaybe [])
  58                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  59
  60                 parseWhileStmt :: Parser Token Stmt
  61                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  62                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  63
  64                 parseBlock :: Parser Token [Stmt]
  65                 parseBlock = parseBCBraces (many parseStmt)
  66
  67                 parseOneLine :: Parser Token [Stmt]
  68                 //first pure makes singleton list from the statement
  69                 parseOneLine = pure <$> parseStmt
  70
  71 parseFunType :: Parser Token FunType
  72 parseFunType = satTok DoubleColonToken *>
  73         (parseInOutType <|> ((FunType []) <$> parseVoidOrType))
  74         where
  75                 parseInOutType :: Parser Token FunType
  76                 parseInOutType =  FunType <$> (some parseType <* satTok ArrowToken) <*> parseVoidOrType
  77
  78                 parseVoidOrType :: Parser Token (Maybe Type)
  79                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  80                         (Just <$> parseType) <|> pure Nothing
  81
  82 parseVarDecl :: Parser Token VarDecl
  83 parseVarDecl = liftM4 VarDecl
  84     peekPos
  85         (parseType <|> trans1 VarToken VarType )
  86         (parseIdent <* satTok AssignmentToken)
  87         (parseExpr <* satTok SColonToken)
  88
  89 parseType :: Parser Token Type
  90 parseType =
  91         trans1 IntTypeToken IntType <|>
  92         trans1 CharTypeToken CharType <|>
  93         trans1 BoolTypeToken BoolType <|>
  94         (ListType <$> (parseBSqBraces parseType)) <|>
  95         (TupleType <$> (parseTuple parseType)) <|>
  96         (IdType <$> parseIdent)
  97
  98 parseExpr :: Parser Token Expr
  99 parseExpr = //Operators in order of binding strength
 100         parseOpR (trans1 ColonToken BiCons) $
 101         parseOpR (trans1 PipesToken BiOr) $
 102         parseOpR (trans1 AmpersandsToken BiAnd) $
 103         parseOpR (trans1 EqualsToken BiEquals <|>
 104                         trans1 LesserToken BiLesser <|>
 105                         trans1 BiggerToken BiGreater <|>
 106                         trans1 LesserEqToken BiLesserEq <|>
 107                         trans1 GreaterEqToken BiGreaterEq <|>
 108                         trans1 NotEqualToken BiUnEqual) $
 109         parseOpL (trans1 PlusToken BiPlus <|>
 110                         trans1 DashToken BiMinus) $
 111         parseOpL (trans1 StarToken BiTimes <|>
 112                         trans1 SlashToken BiDivide <|>
 113                         trans1 PercentToken BiMod) $ parseBasicExpr
 114         where
 115                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 116                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 117                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 118                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 119
 120                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 121                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 122                                 ops >>= \op->prev >>= \e->pure (op, e)
 123                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 124
 125                 parseBasicExpr :: Parser Token Expr
 126                 parseBasicExpr = peekPos >>= \pos ->
 127                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 128                         (FunExpr pos <$> parseFunCall) <|>
 129                         parseBBraces parseExpr <|>
 130                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 131                         trans1 TrueToken (BoolExpr pos True) <|>
 132                         trans1 FalseToken (BoolExpr pos False) <|>
 133                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 134                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 135                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 136                         (VarExpr pos <$> parseVarDef)
 137
 138 parseFunCall :: Parser Token FunCall
 139 parseFunCall = FunCall <$> parseIdent <*> (parseBBraces $ parseSepList CommaToken parseExpr)
 140
 141 parseVarDef :: Parser Token VarDef
 142 parseVarDef = liftM2 VarDef
 143         parseIdent
 144         (many (satTok DotToken *> (
 145                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 146                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 147                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 148                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 149
 150 parseOp1 :: Parser Token Op1
 151 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 152
 153 parseBBraces :: (Parser Token a) -> Parser Token a
 154 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 155
 156 parseBCBraces :: (Parser Token a) -> Parser Token a
 157 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 158
 159 parseBSqBraces :: (Parser Token a) -> Parser Token a
 160 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 161
 162 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 163 parseTuple p = satTok BraceOpenToken *>
 164         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 165         <* satTok BraceCloseToken
 166
 167 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 168 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 169
 170 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 171 trans2 t f = snd <$> trans t f
 172
 173 trans1 :: TokenValue a -> Parser Token a
 174 trans1 t r = trans2 t $ const r
 175
 176 peekPos :: Parser Token Pos
 177 peekPos = fst <$> peek
 178
 179 derive gPrint TokenValue
 180 derive gEq TokenValue
 181 satTok :: TokenValue -> Parser Token Token
 182 satTok t = top >>= \tok=:({line,col},token) -> if (eq t token)
 183         (pure tok) (fail <?> PositionalError line col
 184                 ("ParseError: Unexpected token: " +++ printToString token))
 185         where
 186                 eq (IdentToken _)  (IdentToken _) = True
 187                 eq (NumberToken _) (NumberToken _) = True
 188                 eq (CharToken _)   (CharToken _) = True
 189                 eq x y = gEq {|*|} x y
 190
 191 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 192 parseSepList sep p =
 193         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 194         (liftM pure p) <|> pure empty
 195
 196 parseIdent :: Parser Token String
 197 parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)
 198
 199 //liftM only goes to liftM5
 200 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6