src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left $ toString $ LexError e
  22 parser (Right r) = case runParser parseProgram r of
  23         (Right p, _) = Right p
  24         (Left e, _) = Left $ toString e
  25
  26 parseProgram :: Parser Token AST
  27 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  28         <* satTok EndOfFileToken
  29
  30 parseFunDecl :: Parser Token FunDecl
  31 parseFunDecl = liftM5 FunDecl
  32         (parseIdent <* satTok BraceOpenToken)
  33         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  34         (optional parseFunType <* satTok CBraceOpenToken)
  35         (many parseVarDecl)
  36         (many parseStmt <* satTok CBraceCloseToken)
  37
  38 parseStmt :: Parser Token Stmt
  39 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  40         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  41         (liftM FunStmt (parseSColon parseFunCall))
  42         where
  43                 parseSColon :: (Parser Token a) -> Parser Token a
  44                 parseSColon p = p <* satTok SColonToken
  45
  46                 parseReturnStmt :: Parser Token Stmt
  47                 parseReturnStmt =
  48                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  49
  50                 parseAssStmt :: Parser Token Stmt
  51                 parseAssStmt =
  52                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  53
  54                 parseIfStmt :: Parser Token Stmt
  55                 parseIfStmt = liftM3 IfStmt
  56                         (satTok IfToken *> parseBBraces parseExpr)
  57                         (parseBlock <|> parseOneLine)
  58                         (liftM (fromMaybe [])
  59                                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  60
  61                 parseWhileStmt :: Parser Token Stmt
  62                 parseWhileStmt = satTok WhileToken *>
  63                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  64
  65                 parseBlock :: Parser Token [Stmt]
  66                 parseBlock = parseBCBraces (many parseStmt)
  67
  68                 parseOneLine :: Parser Token [Stmt]
  69                 //first pure makes singleton list from the statement
  70                 parseOneLine = liftM pure parseStmt
  71
  72 parseFunType :: Parser Token FunType
  73 parseFunType = satTok DoubleColonToken *>
  74         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  75         where
  76                 parseInOutType :: Parser Token FunType
  77                 parseInOutType = liftM2 FunType
  78                         (some parseType <* satTok ArrowToken) parseVoidOrType
  79
  80                 parseVoidOrType :: Parser Token (Maybe Type)
  81                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  82                         (liftM Just parseType) <|> pure Nothing
  83
  84 parseVarDecl :: Parser Token VarDecl
  85 parseVarDecl = liftM3 VarDecl
  86         (parseType <|> trans1 VarToken VarType )
  87         (parseIdent <* satTok AssignmentToken)
  88         (parseExpr <* satTok SColonToken)
  89
  90 parseType :: Parser Token Type
  91 parseType =
  92         trans1 IntTypeToken IntType <|>
  93         trans1 CharTypeToken CharType <|>
  94         trans1 BoolTypeToken BoolType <|>
  95         (liftM ListType (parseBSqBraces parseType)) <|>
  96         (liftM TupleType (parseTuple parseType)) <|>
  97         (liftM IdType parseIdent)
  98
  99 parseExpr :: Parser Token Expr
 100 parseExpr = //Operators in order of binding strength
 101         parseOpR (trans1 ColonToken BiCons) $
 102         parseOpR (trans1 PipesToken BiOr) $
 103         parseOpR (trans1 AmpersandsToken BiAnd) $
 104         parseOpR (trans1 EqualsToken BiEquals <|>
 105                         trans1 LesserToken BiLesser <|>
 106                         trans1 BiggerToken BiGreater <|>
 107                         trans1 LesserEqToken BiLesserEq <|>
 108                         trans1 GreaterEqToken BiGreaterEq <|>
 109                         trans1 NotEqualToken BiUnEqual) $
 110         parseOpL (trans1 PlusToken BiPlus <|>
 111                         trans1 DashToken BiMinus) $
 112         parseOpL (trans1 StarToken BiTimes <|>
 113                         trans1 SlashToken BiDivide <|>
 114                         trans1 PercentToken BiMod) $ parseBasicExpr
 115         where
 116                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 117                 parseOpR ops prev = prev >>= \e1->optional (
 118                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 119                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 120
 121                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 122                 parseOpL ops prev = prev >>= \e1->many (
 123                                 ops >>= \op->prev >>= \e->pure (op, e)
 124                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 125
 126                 parseBasicExpr :: Parser Token Expr
 127                 parseBasicExpr =
 128                         (liftM TupleExpr (parseTuple parseExpr)) <|>
 129                         (liftM FunExpr parseFunCall) <|>
 130                         parseBBraces parseExpr <|>
 131                         trans1 EmptyListToken EmptyListExpr <|>
 132                         trans1 TrueToken (BoolExpr True) <|>
 133                         trans1 FalseToken (BoolExpr False) <|>
 134                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 135                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 136                         (liftM2 Op1Expr parseOp1 parseExpr) <|>
 137                         (liftM VarExpr parseVarDef)
 138
 139 parseFunCall :: Parser Token FunCall
 140 parseFunCall = liftM2 FunCall
 141         parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)
 142
 143 parseVarDef :: Parser Token VarDef
 144 parseVarDef = liftM2 VarDef
 145         parseIdent
 146         (many (satTok DotToken *> (
 147                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 148                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 149                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 150                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 151
 152 parseOp1 :: Parser Token Op1
 153 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 154
 155 parseBBraces :: (Parser Token a) -> Parser Token a
 156 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 157
 158 parseBCBraces :: (Parser Token a) -> Parser Token a
 159 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 160
 161 parseBSqBraces :: (Parser Token a) -> Parser Token a
 162 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 163
 164 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 165 parseTuple p = satTok BraceOpenToken *>
 166         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 167         <* satTok BraceCloseToken
 168
 169 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 170 trans2 t f = liftM (f o snd) $ satTok t
 171
 172 trans1 :: TokenValue a -> Parser Token a
 173 trans1 t r = trans2 t $ const r
 174
 175 derive gPrint TokenValue
 176 derive gEq TokenValue
 177 satTok :: TokenValue -> Parser Token Token
 178 satTok t = top >>= \tok=:(pos, tv) -> if (eq t tok) (return tok) (fail <?> (printToString tv, pos))
 179         where
 180                 eq (IdentToken _) (_, IdentToken _) = True
 181                 eq (NumberToken _) (_, NumberToken _) = True
 182                 eq (CharToken _) (_, CharToken _) = True
 183                 eq x (_, y) = gEq {|*|} x y
 184
 185 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 186 parseSepList sep p =
 187         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 188         (liftM pure p) <|> pure empty
 189
 190 parseIdent :: Parser Token String
 191 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 192
 193 instance toString AST where
 194         toString (AST v f) = concat (
 195                 ["\n":printersperse "\n" v] ++
 196                 ["\n":printersperse "\n" f])
 197
 198 class print a :: a -> [String]
 199
 200 printersperse :: String [a] -> [String] | print a
 201 printersperse i j = intercalate [i] (map print j)
 202
 203 instance print FunDecl where
 204         print (FunDecl i as t vs ss) =
 205                 ["\n", i, " (":printersperse "," as] ++
 206                 [")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
 207                 ["{\n\t":printersperse "\n\t" vs] ++
 208                 ["\n":printStatements ss 1] ++ ["}\n"]
 209
 210 printStatements :: [Stmt] Int -> [String]
 211 printStatements [] i = []
 212 printStatements [s:ss] i = (case s of
 213         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 214                 printCodeBlock thens i ++
 215                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 216         (WhileStmt b dos) = indent i ["while (":print b] ++
 217                 [")":printCodeBlock dos i]
 218         (AssStmt vardef val) =
 219                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 220         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 221         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 222         ) ++ printStatements ss i
 223         where
 224                 printCodeBlock :: [Stmt] Int -> [String]
 225                 printCodeBlock [] _ = ["{}\n"]
 226                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 227                 printCodeBlock x i =
 228                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 229
 230                 indent :: Int [String] -> [String]
 231                 indent i rest = replicate i "\t" ++ rest
 232
 233 instance print FunType where
 234         print (FunType at rt) = printersperse " " at ++
 235                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 236
 237 instance print VarDecl where
 238         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 239
 240 instance print Type where
 241         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
 242         print (ListType t) = ["[":print t] ++ ["]"]
 243         print (IdType s) = print s
 244         print IntType = print "Int"
 245         print BoolType = print "Bool"
 246         print CharType = print "Char"
 247         print VarType = print "var"
 248
 249 instance print String where
 250         print s = [s]
 251
 252 instance print FieldSelector where
 253         print FieldHd = print "hd"
 254         print FieldTl = print "tl"
 255         print FieldSnd = print "snd"
 256         print FieldFst = print "fst"
 257
 258 instance print VarDef where
 259         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 260
 261 instance print FunCall where
 262         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 263
 264 instance print Expr where
 265         print (VarExpr vd) = print vd
 266         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 267                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 268                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 269                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 270                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 271                 ," ":print e2] ++ [")"]
 272         print (Op1Expr o e) = ["(",case o of
 273                 UnNegation = "!"; UnMinus = "-"
 274                 :print e] ++ [")"]
 275         print (IntExpr i) = [toString i]
 276         print (CharExpr c) = ["\'", case c of
 277                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 278                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 279                 c = if (c == toChar 7) "\\a" (toString c)
 280                 ,"\'"]
 281         print (BoolExpr b) = [toString b]
 282         print (FunExpr fc) = print fc
 283         print EmptyListExpr = ["[]"]
 284         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]