src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left $ toString $ LexError e
  22 parser (Right r) = case runParser parseProgram r of
  23         (Right p, _) = Right p
  24         (Left e, _) = Left $ toString e
  25
  26 parseProgram :: Parser Token AST
  27 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  28
  29 parseFunDecl :: Parser Token FunDecl
  30 parseFunDecl = liftM5 FunDecl
  31         (parseIdent <* satTok BraceOpenToken)
  32         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  33         (parseFunType <* satTok CBraceOpenToken)
  34         (many parseVarDecl)
  35         (many parseStmt <* satTok CBraceCloseToken)
  36
  37 parseStmt :: Parser Token Stmt
  38 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  39         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  40         (liftM FunStmt (parseSColon parseFunCall))
  41         where
  42                 parseSColon :: (Parser Token a) -> Parser Token a
  43                 parseSColon p = p <* satTok SColonToken
  44
  45                 parseReturnStmt :: Parser Token Stmt
  46                 parseReturnStmt =
  47                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  48
  49                 parseAssStmt :: Parser Token Stmt
  50                 parseAssStmt =
  51                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  52
  53                 parseIfStmt :: Parser Token Stmt
  54                 parseIfStmt = liftM3 IfStmt
  55                         (satTok IfToken *> parseBBraces parseExpr)
  56                         (parseBlock <|> parseOneLine)
  57                         (liftM (fromMaybe [])
  58                                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  59
  60                 parseWhileStmt :: Parser Token Stmt
  61                 parseWhileStmt = satTok WhileToken *>
  62                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  63
  64                 parseBlock :: Parser Token [Stmt]
  65                 parseBlock = parseBCBraces (many parseStmt)
  66
  67                 parseOneLine :: Parser Token [Stmt]
  68                 //first pure makes singleton list from the statement
  69                 parseOneLine = liftM pure parseStmt
  70
  71 parseFunType :: Parser Token FunType
  72 parseFunType = satTok DoubleColonToken *>
  73         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  74         where
  75                 parseInOutType :: Parser Token FunType
  76                 parseInOutType = liftM2 FunType
  77                         (some parseType <* satTok ArrowToken) parseVoidOrType
  78
  79                 parseVoidOrType :: Parser Token (Maybe Type)
  80                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  81                         (liftM Just parseType)
  82
  83 parseVarDecl :: Parser Token VarDecl
  84 parseVarDecl = liftM3 VarDecl
  85         (parseType <|> trans1 VarToken VarType )
  86         (parseIdent <* satTok AssignmentToken)
  87         (parseExpr <* satTok SColonToken)
  88
  89 parseType :: Parser Token Type
  90 parseType =
  91         trans1 IntTypeToken IntType <|>
  92         trans1 CharTypeToken CharType <|>
  93         trans1 BoolTypeToken BoolType <|>
  94         (liftM ListType (parseBSqBraces parseType)) <|>
  95         (liftM TupleType (parseTuple parseType)) <|>
  96         (liftM IdType parseIdent)
  97
  98 parseExpr :: Parser Token Expr
  99 parseExpr = //Operators in order of binding strength
 100         parseOpR (trans1 ColonToken BiCons) $
 101         parseOpR (trans1 PipesToken BiOr) $
 102         parseOpR (trans1 AmpersandsToken BiAnd) $
 103         parseOpR (trans1 EqualsToken BiEquals <|>
 104                         trans1 LesserToken BiLesser <|>
 105                         trans1 BiggerToken BiGreater <|>
 106                         trans1 LesserEqToken BiLesserEq <|>
 107                         trans1 GreaterEqToken BiGreaterEq <|>
 108                         trans1 NotEqualToken BiUnEqual) $
 109         parseOpL (trans1 PlusToken BiPlus <|>
 110                         trans1 DashToken BiMinus) $
 111         parseOpL (trans1 StarToken BiTimes <|>
 112                         trans1 SlashToken BiDivide <|>
 113                         trans1 PercentToken BiMod) $ parseBasicExpr
 114         where
 115                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 116                 parseOpR ops prev = prev >>= \e1->optional (
 117                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 118                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 119
 120                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 121                 parseOpL ops prev = prev >>= \e1->many (
 122                                 ops >>= \op->prev >>= \e->pure (op, e)
 123                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 124
 125                 parseBasicExpr :: Parser Token Expr
 126                 parseBasicExpr =
 127                         (liftM TupleExpr (parseTuple parseExpr)) <|>
 128                         (liftM FunExpr parseFunCall) <|>
 129                         parseBBraces parseExpr <|>
 130                         trans1 EmptyListToken EmptyListExpr <|>
 131                         trans1 TrueToken (BoolExpr True) <|>
 132                         trans1 FalseToken (BoolExpr False) <|>
 133                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 134                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 135                         (liftM2 Op1Expr parseOp1 parseExpr) <|>
 136                         (liftM VarExpr parseVarDef)
 137
 138 parseFunCall :: Parser Token FunCall
 139 parseFunCall = liftM2 FunCall
 140         parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)
 141
 142 parseVarDef :: Parser Token VarDef
 143 parseVarDef = liftM2 VarDef
 144         parseIdent
 145         (many (satTok DotToken *> (
 146                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 147                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 148                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 149                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 150
 151 parseOp1 :: Parser Token Op1
 152 parseOp1 = trans1 DashToken UnMinus <|>
 153         trans1 ExclamationToken UnNegation
 154
 155 parseBBraces :: (Parser Token a) -> Parser Token a
 156 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 157
 158 parseBCBraces :: (Parser Token a) -> Parser Token a
 159 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 160
 161 parseBSqBraces :: (Parser Token a) -> Parser Token a
 162 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 163
 164 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 165 parseTuple p = satTok BraceOpenToken *>
 166         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 167         <* satTok BraceCloseToken
 168
 169 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 170 trans2 t f = satTok t >>= \(_, r).pure (f r)
 171
 172 trans1 :: TokenValue a -> Parser Token a
 173 trans1 t r = trans2 t $ const r
 174
 175 derive gPrint TokenValue
 176 derive gEq TokenValue
 177 satTok :: TokenValue -> Parser Token Token
 178 satTok t = top >>= \tok=:(pos, tv) -> if (eq t tok) (return tok) (fail <?> (printToString t, pos))
 179         where
 180                 eq (IdentToken _) (_, IdentToken _) = True
 181                 eq (NumberToken _) (_, NumberToken _) = True
 182                 eq (CharToken _) (_, CharToken _) = True
 183                 eq x (_, y) = gEq {|*|} x y
 184
 185 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 186 parseSepList sep p =
 187         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 188         (liftM pure p) <|> pure empty
 189
 190 parseIdent :: Parser Token String
 191 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 192
 193 instance toString AST where
 194         toString (AST v f) = concat (
 195                 ["\n":printersperse "\n" v] ++
 196                 ["\n":printersperse "\n" f])
 197
 198 class print a :: a -> [String]
 199
 200 printersperse :: String [a] -> [String] | print a
 201 printersperse i j = intercalate [i] (map print j)
 202
 203 instance print FunDecl where
 204         print (FunDecl i as t vs ss) =
 205                 ["\n", i, " (":printersperse "," as] ++
 206                 [") :: ":print t] ++
 207                 ["{\n\t":printersperse "\n\t" vs] ++
 208                 ["\n":printStatements ss 1] ++ ["}\n"]
 209
 210 printStatements :: [Stmt] Int -> [String]
 211 printStatements [] i = []
 212 printStatements [s:ss] i = (case s of
 213         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 214                 printCodeBlock thens i ++
 215                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 216         (WhileStmt b dos) = indent i ["while (":print b] ++
 217                 [")":printCodeBlock dos i]
 218         (AssStmt vardef val) =
 219                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 220         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 221         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 222         ) ++ printStatements ss i
 223         where
 224                 printCodeBlock :: [Stmt] Int -> [String]
 225                 printCodeBlock [] _ = ["{}\n"]
 226                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 227                 printCodeBlock x i =
 228                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 229
 230                 indent :: Int [String] -> [String]
 231                 indent i rest = replicate i "\t" ++ rest
 232
 233 instance print FunType where
 234         print (FunType at rt) = printersperse " " at ++
 235                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 236
 237 instance print VarDecl where
 238         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 239
 240 instance print Type where
 241         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
 242         print (ListType t) = ["[":print t] ++ ["]"]
 243         print (IdType s) = print s
 244         print IntType = print "Int"
 245         print BoolType = print "Bool"
 246         print CharType = print "Char"
 247         print VarType = print "var"
 248
 249 instance print String where
 250         print s = [s]
 251
 252 instance print FieldSelector where
 253         print FieldHd = print "hd"
 254         print FieldTl = print "tl"
 255         print FieldSnd = print "snd"
 256         print FieldFst = print "fst"
 257
 258 instance print VarDef where
 259         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 260
 261 instance print FunCall where
 262         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 263
 264 instance print Expr where
 265         print (VarExpr vd) = print vd
 266         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 267                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 268                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 269                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 270                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 271                 ," ":print e2] ++ [")"]
 272         print (Op1Expr o e) = ["(",case o of
 273                 UnNegation = "!"; UnMinus = "-"
 274                 :print e] ++ [")"]
 275         print (IntExpr i) = [toString i]
 276         print (CharExpr c) = ["\'", case c of
 277                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 278                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 279                 c = if (c == toChar 7) "\\a" (toString c)
 280                 ,"\'"]
 281         print (BoolExpr b) = [toString b]
 282         print (FunExpr fc) = print fc
 283         print EmptyListExpr = ["[]"]
 284         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]