src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Text import class Text(concat), instance Text String
  14
  15 import yard
  16 import lex
  17
  18 parser :: LexerOutput -> ParserOutput
  19 parser (Left e) = Left $ toString $ LexError e
  20 parser (Right r) = case runParser parseProgram r of
  21         (Right p, _) = Right p
  22         (Left e, _) = Left $ toString e
  23
  24 parseProgram :: Parser Token AST
  25 parseProgram = some parseVarDecl
  26         >>= \vd->some parseFunDecl >>= \fd->pure $ AST vd fd
  27
  28 parseFunDecl :: Parser Token FunDecl
  29 parseFunDecl = empty
  30
  31 parseVarDecl :: Parser Token VarDecl
  32 parseVarDecl =
  33         (parseType <|> trans1 VarToken VarType )
  34         >>= \t->parseIdent <* satTok AssignmentToken
  35         >>= \i->parseExpr <* satTok SColonToken
  36         >>= \e->pure $ VarDecl i t e
  37
  38 parseType :: Parser Token Type
  39 parseType =
  40         trans1 IntTypeToken IntType <|>
  41         trans1 CharTypeToken CharType <|>
  42         trans1 BoolTypeToken BoolType <|>
  43         (satTok SquareOpenToken *> parseType <* satTok SquareCloseToken
  44                 >>= \t.pure $ ListType t) <|>
  45         (satTok BraceOpenToken *> parseType <* satTok CommaToken
  46                 >>= \t1->parseType <* satTok BraceCloseToken
  47                 >>= \t2->pure $ TupleType t1 t2) <|>
  48         (parseIdent >>= \e.pure $ IdType e) <|>
  49         empty
  50
  51 parseExpr :: Parser Token Expr
  52 parseExpr =
  53         parseOps (trans1 ColonToken BiCons) $
  54         parseOps (trans1 PipesToken BiOr) $
  55         parseOps (trans1 AmpersandsToken BiAnd) $
  56         parseOps (trans1 EqualsToken BiEquals <|>
  57                         trans1 LesserToken BiLesser <|>
  58                         trans1 BiggerToken BiGreater <|>
  59                         trans1 LesserEqToken BiLesserEq <|>
  60                         trans1 GreaterEqToken BiGreaterEq <|>
  61                         trans1 NotEqualToken BiUnEqual) $
  62         parseOps (trans1 PlusToken BiPlus <|>
  63                         trans1 DashToken BiMinus) $
  64         parseOps (trans1 StarToken BiTimes <|>
  65                         trans1 SlashToken BiDivide <|>
  66                         trans1 PercentToken BiMod) $
  67                 parseBasicExpr
  68         where
  69                 parseOps :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
  70                 parseOps ops prev = prev >>= \e1->optional (
  71                                 ops >>= \op->parseOps ops prev >>= \e->pure (op, e)
  72                         ) >>= \moe-> pure case moe of
  73                                 Nothing = e1
  74                                 (Just (op, e2)) = Op2Expr e1 op e2
  75
  76                 parseBasicExpr :: Parser Token Expr
  77                 parseBasicExpr =
  78                         (satTok BraceOpenToken *> parseExpr <* satTok BraceCloseToken) <|>
  79                         (satTok BraceOpenToken *> parseExpr <* satTok CommaToken
  80                                 >>= \e1->parseExpr <* satTok BraceCloseToken
  81                                 >>= \e2->pure $ TupleExpr e1 e2) <|>
  82                         trans1 EmptyListToken EmptyListExpr <|>
  83                         trans2 TrueToken (const $ BoolExpr True) <|>
  84                         trans2 FalseToken (const $ BoolExpr True) <|>
  85                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
  86                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
  87                         (parseOp1 >>= \o->parseExpr >>= \e.pure $ Op1Expr o e) <|>
  88                         (parseIdent <* satTok BraceOpenToken
  89                                 >>= \i->parseActArgs <* satTok BraceCloseToken
  90                                 >>= \es->pure $ FunExpr i es) <|>
  91                         (parseIdent >>= \i. parseFieldSelector >>= \f.pure $ VarExpr i f)
  92
  93 parseActArgs :: Parser Token [Expr]
  94 parseActArgs =
  95         (some (parseExpr <* satTok CommaToken) >>= \es->parseExpr
  96                 >>= \e.pure [e:es]) <|>
  97         (parseExpr >>= \e->pure [e]) <|>
  98         empty
  99
 100 parseOp1 :: Parser Token Op1
 101 parseOp1 = trans1 DashToken UnMinus <|>
 102         trans1 ExclamationToken UnNegation
 103
 104 parseFieldSelector :: Parser Token (Maybe FieldSelector)
 105 parseFieldSelector = optional (satTok DotToken *> (
 106         (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 107         (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 108         (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 109         (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty)))
 110
 111 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 112 trans2 t f = satTok t >>= \(_, r).pure (f r)
 113
 114 trans1 :: TokenValue a -> Parser Token a
 115 trans1 t r = trans2 t $ const r
 116
 117 satTok :: TokenValue -> Parser Token Token
 118 satTok t = satisfy ((===) t)
 119
 120 parseIdent :: Parser Token String
 121 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 122
 123 instance toString AST where
 124         toString (AST v f) = concat (print v ++ ["\n":print f])
 125
 126 class print a :: a -> [String]
 127
 128 instance print [a] | print a where
 129         print [] = ["\n"]
 130         print [v:vs] = print v ++ ["\n":print vs]
 131
 132 instance print VarDecl where
 133         print (VarDecl i t e) = print t ++ [" ":i:"=":print e] ++ [";"]
 134 instance print FunDecl where
 135         print _ = ["Function printing not yet implemented"]
 136
 137 instance print Type where
 138         print (TupleType t1 t2) = ["(":print t1] ++ [", ":print t2] ++ [")"]
 139         print (ListType t) = ["[":print t] ++ ["]"]
 140         print (IdType s) = [s]
 141         print IntType = ["Int"]
 142         print BoolType = ["Bool"]
 143         print CharType = ["Char"]
 144         print VarType = ["var"]
 145
 146 instance print Expr where
 147         print (VarExpr i Nothing) = [i]
 148         print (VarExpr i (Just mf)) = [i, case mf of
 149                 FieldHd = ".hd"; FieldTl = ".tl"
 150                 FieldSnd = ".snd"; FieldFst = ".fst"]
 151         print (Op2Expr e1 o e2) = print e1 ++ [case o of
 152                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 153                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 154                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 155                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 156                 :print e2]
 157         print (Op1Expr o e) = [case o of
 158                 UnNegation = "!"; UnMinus = "-"
 159                 :print e]
 160         print (IntExpr i) = [toString i]
 161         print (CharExpr c) = ["\'", case c of
 162                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 163                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 164                 c = if (c == toChar 7) "\\a" (toString c)
 165                 ,"\'"]
 166         print (BoolExpr b) = [toString b]
 167         print (FunExpr i es) = pe ++ flatten [[",":x]\\x<-tl pes]
 168                 where [pe:pes] = map print es
 169         print EmptyListExpr = ["[]"]
 170         print (TupleExpr e1 e2) = ["(":print e1] ++ [",":print e2] ++ [")"]