src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left $ toString $ LexError e
  22 parser (Right r) = case runParser parseProgram r of
  23         (Right p, _) = Right p
  24         (Left e, _) = Left $ toString e
  25
  26 parseProgram :: Parser Token AST
  27 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  28         <* satTok EndOfFileToken
  29
  30 parseFunDecl :: Parser Token FunDecl
  31 parseFunDecl = liftM5 FunDecl
  32         (parseIdent <* satTok BraceOpenToken)
  33         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  34         (optional parseFunType <* satTok CBraceOpenToken)
  35         (many parseVarDecl)
  36         (many parseStmt <* satTok CBraceCloseToken)
  37
  38 parseStmt :: Parser Token Stmt
  39 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  40         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  41         (liftM FunStmt (parseSColon parseFunCall))
  42         where
  43                 parseSColon :: (Parser Token a) -> Parser Token a
  44                 parseSColon p = p <* satTok SColonToken
  45
  46                 parseReturnStmt :: Parser Token Stmt
  47                 parseReturnStmt =
  48                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  49
  50                 parseAssStmt :: Parser Token Stmt
  51                 parseAssStmt =
  52                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  53
  54                 parseIfStmt :: Parser Token Stmt
  55                 parseIfStmt = liftM3 IfStmt
  56             (satTok IfToken *> parseBBraces parseExpr)
  57             (parseBlock <|> parseOneLine)
  58             (liftM (fromMaybe [])
  59                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  60
  61
  62                 parseWhileStmt :: Parser Token Stmt
  63                 parseWhileStmt = satTok WhileToken *>
  64                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  65
  66                 parseBlock :: Parser Token [Stmt]
  67                 parseBlock = parseBCBraces (many parseStmt)
  68
  69                 parseOneLine :: Parser Token [Stmt]
  70                 //first pure makes singleton list from the statement
  71                 parseOneLine = liftM pure parseStmt
  72
  73 parseFunType :: Parser Token FunType
  74 parseFunType = satTok DoubleColonToken *>
  75         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  76         where
  77                 parseInOutType :: Parser Token FunType
  78                 parseInOutType = liftM2 FunType
  79                         (some parseType <* satTok ArrowToken) parseVoidOrType
  80
  81                 parseVoidOrType :: Parser Token (Maybe Type)
  82                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  83                         (liftM Just parseType) <|> pure Nothing
  84
  85 parseVarDecl :: Parser Token VarDecl
  86 parseVarDecl = liftM3 VarDecl
  87         (parseType <|> trans1 VarToken VarType )
  88         (parseIdent <* satTok AssignmentToken)
  89         (parseExpr <* satTok SColonToken)
  90
  91 parseType :: Parser Token Type
  92 parseType =
  93         trans1 IntTypeToken IntType <|>
  94         trans1 CharTypeToken CharType <|>
  95         trans1 BoolTypeToken BoolType <|>
  96         (liftM ListType (parseBSqBraces parseType)) <|>
  97         (liftM TupleType (parseTuple parseType)) <|>
  98         (liftM IdType parseIdent)
  99
 100 parseExpr :: Parser Token Expr
 101 parseExpr = //Operators in order of binding strength
 102         parseOpR (trans1 ColonToken BiCons) $
 103         parseOpR (trans1 PipesToken BiOr) $
 104         parseOpR (trans1 AmpersandsToken BiAnd) $
 105         parseOpR (trans1 EqualsToken BiEquals <|>
 106                         trans1 LesserToken BiLesser <|>
 107                         trans1 BiggerToken BiGreater <|>
 108                         trans1 LesserEqToken BiLesserEq <|>
 109                         trans1 GreaterEqToken BiGreaterEq <|>
 110                         trans1 NotEqualToken BiUnEqual) $
 111         parseOpL (trans1 PlusToken BiPlus <|>
 112                         trans1 DashToken BiMinus) $
 113         parseOpL (trans1 StarToken BiTimes <|>
 114                         trans1 SlashToken BiDivide <|>
 115                         trans1 PercentToken BiMod) $ parseBasicExpr
 116         where
 117                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 118                 parseOpR ops prev = prev >>= \e1->optional (
 119                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 120                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 121
 122                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 123                 parseOpL ops prev = prev >>= \e1->many (
 124                                 ops >>= \op->prev >>= \e->pure (op, e)
 125                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 126
 127                 parseBasicExpr :: Parser Token Expr
 128                 parseBasicExpr =
 129                         (liftM TupleExpr (parseTuple parseExpr)) <|>
 130                         (liftM FunExpr parseFunCall) <|>
 131                         parseBBraces parseExpr <|>
 132                         trans1 EmptyListToken EmptyListExpr <|>
 133                         trans1 TrueToken (BoolExpr True) <|>
 134                         trans1 FalseToken (BoolExpr False) <|>
 135                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 136                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 137                         (liftM2 Op1Expr parseOp1 parseExpr) <|>
 138                         (liftM VarExpr parseVarDef)
 139
 140 parseFunCall :: Parser Token FunCall
 141 parseFunCall = liftM2 FunCall
 142         parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)
 143
 144 parseVarDef :: Parser Token VarDef
 145 parseVarDef = liftM2 VarDef
 146         parseIdent
 147         (many (satTok DotToken *> (
 148                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 149                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 150                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 151                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))
 152
 153 parseOp1 :: Parser Token Op1
 154 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 155
 156 parseBBraces :: (Parser Token a) -> Parser Token a
 157 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 158
 159 parseBCBraces :: (Parser Token a) -> Parser Token a
 160 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 161
 162 parseBSqBraces :: (Parser Token a) -> Parser Token a
 163 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 164
 165 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 166 parseTuple p = satTok BraceOpenToken *>
 167         (liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p)
 168         <* satTok BraceCloseToken
 169
 170 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 171 trans2 t f = liftM (f o snd) $ satTok t
 172
 173 trans1 :: TokenValue a -> Parser Token a
 174 trans1 t r = trans2 t $ const r
 175
 176 derive gPrint TokenValue
 177 derive gEq TokenValue
 178 satTok :: TokenValue -> Parser Token Token
 179 satTok t = top >>= \tok=:(pos, tv) -> if (eq t tok)
 180                                             (return tok)
 181                                             (fail <?> (printToString tv+++printToString t, pos))
 182         where
 183                 eq (IdentToken _) (_, IdentToken _) = True
 184                 eq (NumberToken _) (_, NumberToken _) = True
 185                 eq (CharToken _) (_, CharToken _) = True
 186                 eq x (_, y) = gEq {|*|} x y
 187
 188 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 189 parseSepList sep p =
 190         (liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
 191         (liftM pure p) <|> pure empty
 192
 193 parseIdent :: Parser Token String
 194 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 195
 196 instance toString AST where
 197         toString (AST v f) = concat (
 198                 ["\n":printersperse "\n" v] ++
 199                 ["\n":printersperse "\n" f])
 200
 201 class print a :: a -> [String]
 202
 203 printersperse :: String [a] -> [String] | print a
 204 printersperse i j = intercalate [i] (map print j)
 205
 206 instance print FunDecl where
 207         print (FunDecl i as t vs ss) =
 208                 ["\n", i, " (":printersperse "," as] ++
 209                 [")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
 210                 ["{\n\t":printersperse "\n\t" vs] ++
 211                 ["\n":printStatements ss 1] ++ ["}\n"]
 212
 213 printStatements :: [Stmt] Int -> [String]
 214 printStatements [] i = []
 215 printStatements [s:ss] i = (case s of
 216         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 217                 printCodeBlock thens i ++
 218                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 219         (WhileStmt b dos) = indent i ["while (":print b] ++
 220                 [")":printCodeBlock dos i]
 221         (AssStmt vardef val) =
 222                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 223         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 224         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 225         ) ++ printStatements ss i
 226         where
 227                 printCodeBlock :: [Stmt] Int -> [String]
 228                 printCodeBlock [] _ = ["{}\n"]
 229                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 230                 printCodeBlock x i =
 231                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 232
 233                 indent :: Int [String] -> [String]
 234                 indent i rest = replicate i "\t" ++ rest
 235
 236 instance print FunType where
 237         print (FunType at rt) = printersperse " " at ++
 238                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 239
 240 instance print VarDecl where
 241         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 242
 243 instance print Type where
 244         print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
 245         print (ListType t) = ["[":print t] ++ ["]"]
 246         print (IdType s) = print s
 247         print IntType = print "Int"
 248         print BoolType = print "Bool"
 249         print CharType = print "Char"
 250         print VarType = print "var"
 251
 252 instance print String where
 253         print s = [s]
 254
 255 instance print FieldSelector where
 256         print FieldHd = print "hd"
 257         print FieldTl = print "tl"
 258         print FieldSnd = print "snd"
 259         print FieldFst = print "fst"
 260
 261 instance print VarDef where
 262         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 263
 264 instance print FunCall where
 265         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 266
 267 instance print Expr where
 268         print (VarExpr vd) = print vd
 269         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 270                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 271                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 272                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 273                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 274                 ," ":print e2] ++ [")"]
 275         print (Op1Expr o e) = ["(",case o of
 276                 UnNegation = "!"; UnMinus = "-"
 277                 :print e] ++ [")"]
 278         print (IntExpr i) = [toString i]
 279         print (CharExpr c) = ["\'", case c of
 280                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 281                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 282                 c = if (c == toChar 7) "\\a" (toString c)
 283                 ,"\'"]
 284         print (BoolExpr b) = [toString b]
 285         print (FunExpr fc) = print fc
 286         print EmptyListExpr = ["[]"]
 287         print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]