src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15
  16 import yard
  17 import lex
  18
  19 parser :: LexerOutput -> ParserOutput
  20 parser (Left e) = Left $ toString $ LexError e
  21 parser (Right r) = case runParser parseProgram r of
  22         (Right p, _) = Right p
  23         (Left e, _) = Left $ toString e
  24
  25 parseProgram :: Parser Token AST
  26 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  27
  28 parseFunDecl :: Parser Token FunDecl
  29 parseFunDecl = liftM5 FunDecl
  30         (parseIdent <* satTok BraceOpenToken)
  31         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  32         (parseFunType <* satTok CBraceOpenToken)
  33         (many parseVarDecl)
  34         (many parseStmt <* satTok CBraceCloseToken)
  35
  36 parseStmt :: Parser Token Stmt
  37 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  38         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  39         (liftM FunStmt (parseSColon parseFunCall))
  40         where
  41                 parseSColon :: (Parser Token a) -> Parser Token a
  42                 parseSColon p = p <* satTok SColonToken
  43
  44                 parseReturnStmt :: Parser Token Stmt
  45                 parseReturnStmt =
  46                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  47
  48                 parseAssStmt :: Parser Token Stmt
  49                 parseAssStmt =
  50                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  51
  52                 parseIfStmt :: Parser Token Stmt
  53                 parseIfStmt = liftM3 IfStmt
  54                         (satTok IfToken *> parseBBraces parseExpr)
  55                         (parseBlock <|> parseOneLine)
  56                         (optional (satTok ElseToken *> (parseBlock <|> parseOneLine)
  57                                 ) >>= pure o fromMaybe [])
  58
  59                 parseWhileStmt :: Parser Token Stmt
  60                 parseWhileStmt = satTok WhileToken *>
  61                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  62
  63                 parseBlock :: Parser Token [Stmt]
  64                 parseBlock = parseBCBraces (many parseStmt)
  65
  66                 parseOneLine :: Parser Token [Stmt]
  67                 //first pure makes singleton list from the statement
  68                 parseOneLine = liftM pure parseStmt
  69
  70 parseBBraces :: (Parser Token a) -> Parser Token a
  71 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
  72
  73 parseBCBraces :: (Parser Token a) -> Parser Token a
  74 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
  75
  76 parseFunType :: Parser Token FunType
  77 parseFunType = satTok DoubleColonToken *>
  78         (parseInOutType <|> (parseVoidOrType >>= \t->pure $ FunType [] t))
  79         where
  80                 parseInOutType :: Parser Token FunType
  81                 parseInOutType = some parseType <* satTok ArrowToken
  82                         >>= \intypes-> parseVoidOrType
  83                         >>= \outtypes->pure $ FunType intypes outtypes
  84
  85                 parseVoidOrType :: Parser Token (Maybe Type)
  86                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  87                         (parseType >>= \type->pure $ Just type)
  88
  89 parseVarDecl :: Parser Token VarDecl
  90 parseVarDecl =
  91         (parseType <|> trans1 VarToken VarType )
  92         >>= \t->parseIdent <* satTok AssignmentToken
  93         >>= \i->parseExpr <* satTok SColonToken
  94         >>= \e->pure $ VarDecl i t e
  95
  96 parseType :: Parser Token Type
  97 parseType =
  98         trans1 IntTypeToken IntType <|>
  99         trans1 CharTypeToken CharType <|>
 100         trans1 BoolTypeToken BoolType <|>
 101         (satTok SquareOpenToken *> parseType <* satTok SquareCloseToken
 102                 >>= \t.pure $ ListType t) <|>
 103         (satTok BraceOpenToken *> parseType <* satTok CommaToken
 104                 >>= \t1->parseType <* satTok BraceCloseToken
 105                 >>= \t2->pure $ TupleType t1 t2) <|>
 106         (parseIdent >>= \e.pure $ IdType e) <|>
 107         empty
 108
 109 parseExpr :: Parser Token Expr
 110 parseExpr = //Operators in order of binding strength
 111         parseOpR (trans1 ColonToken BiCons) $
 112         parseOpR (trans1 PipesToken BiOr) $
 113         parseOpR (trans1 AmpersandsToken BiAnd) $
 114         parseOpR (trans1 EqualsToken BiEquals <|>
 115                         trans1 LesserToken BiLesser <|>
 116                         trans1 BiggerToken BiGreater <|>
 117                         trans1 LesserEqToken BiLesserEq <|>
 118                         trans1 GreaterEqToken BiGreaterEq <|>
 119                         trans1 NotEqualToken BiUnEqual) $
 120         parseOpL (trans1 PlusToken BiPlus <|>
 121                         trans1 DashToken BiMinus) $
 122         parseOpL (trans1 StarToken BiTimes <|>
 123                         trans1 SlashToken BiDivide <|>
 124                         trans1 PercentToken BiMod) $ parseBasicExpr
 125         where
 126                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 127                 parseOpR ops prev = prev >>= \e1->optional (
 128                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 129                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 130
 131                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 132                 parseOpL ops prev = prev >>= \e1->many (
 133                                 ops >>= \op->prev >>= \e->pure (op, e)
 134                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 135
 136                 parseBasicExpr :: Parser Token Expr
 137                 parseBasicExpr =
 138                         (satTok BraceOpenToken *> parseExpr <* satTok CommaToken
 139                                 >>= \e1->parseExpr <* satTok BraceCloseToken
 140                                 >>= \e2->pure $ TupleExpr e1 e2) <|>
 141                         (parseFunCall >>= \fc->pure $ FunExpr fc) <|>
 142                         parseBBraces parseExpr <|>
 143                         trans1 EmptyListToken EmptyListExpr <|>
 144                         trans2 TrueToken (const $ BoolExpr True) <|>
 145                         trans2 FalseToken (const $ BoolExpr False) <|>
 146                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 147                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 148                         (parseOp1 >>= \o->parseExpr >>= \e.pure $ Op1Expr o e) <|>
 149                         (parseVarDef >>= \ve->pure $ VarExpr ve)
 150
 151 parseFunCall :: Parser Token FunCall
 152 parseFunCall = parseIdent <* satTok BraceOpenToken
 153         >>= \i->parseSepList CommaToken parseExpr
 154         <* satTok BraceCloseToken >>= \es->pure $ FunCall i es
 155
 156 parseVarDef :: Parser Token VarDef
 157 parseVarDef = parseIdent
 158         >>= \i-> many (satTok DotToken *> (
 159                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 160                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 161                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 162                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))
 163         ) >>= \f->pure $ VarDef i f
 164
 165 parseOp1 :: Parser Token Op1
 166 parseOp1 = trans1 DashToken UnMinus <|>
 167         trans1 ExclamationToken UnNegation
 168
 169 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 170 trans2 t f = satTok t >>= \(_, r).pure (f r)
 171
 172 trans1 :: TokenValue a -> Parser Token a
 173 trans1 t r = trans2 t $ const r
 174
 175 satTok :: TokenValue -> Parser Token Token
 176 satTok t = satisfy ((===) t)
 177
 178 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 179 parseSepList sep p =
 180         (some (p <* satTok sep) >>= \es->p >>= \e.pure $ reverse [e:es]) <|>
 181         (p >>= \e->pure [e]) <|> pure []
 182
 183 parseIdent :: Parser Token String
 184 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 185
 186 instance toString AST where
 187         toString (AST v f) = concat (
 188                 ["\n":printersperse "\n" v] ++
 189                 ["\n":printersperse "\n" f])
 190
 191 class print a :: a -> [String]
 192
 193 printersperse :: String [a] -> [String] | print a
 194 printersperse i j = intercalate [i] (map print j)
 195
 196 instance print FunDecl where
 197         print (FunDecl i as t vs ss) =
 198                 ["\n", i, " (":printersperse "," as] ++
 199                 [") :: ":print t] ++
 200                 ["{":printersperse "\n\t" vs] ++
 201                 ["\n":printStatements ss 1] ++ ["}"]
 202
 203 printStatements :: [Stmt] Int -> [String]
 204 printStatements [] i = []
 205 printStatements [s:ss] i = (case s of
 206         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 207                 printCodeBlock thens i ++
 208                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 209         (WhileStmt b dos) = indent i ["while (":print b] ++
 210                 [")":printCodeBlock dos i]
 211         (AssStmt vardef val) =
 212                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 213         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 214         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 215         ) ++ printStatements ss i
 216         where
 217                 printCodeBlock :: [Stmt] Int -> [String]
 218                 printCodeBlock [] _ = ["{}"]
 219                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 220                 printCodeBlock x i =
 221                         ["{\n":printStatements x (i+1)] ++ indent i ["}"]
 222
 223                 indent :: Int [String] -> [String]
 224                 indent i rest = replicate i "\t" ++ rest
 225
 226 instance print FunType where
 227         print (FunType at rt) = printersperse " " at ++
 228                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 229
 230 instance print VarDecl where
 231         print (VarDecl i t e) = print t ++ [" ":i:"=":print e] ++ [";"]
 232
 233 instance print Type where
 234         print (TupleType t1 t2) = ["(":print t1] ++ [",":print t2] ++ [")"]
 235         print (ListType t) = ["[":print t] ++ ["]"]
 236         print (IdType s) = print s
 237         print IntType = print "Int"
 238         print BoolType = print "Bool"
 239         print CharType = print "Char"
 240         print VarType = print "var"
 241
 242 instance print String where
 243         print s = [s]
 244
 245 instance print FieldSelector where
 246         print FieldHd = print "hd"
 247         print FieldTl = print "tl"
 248         print FieldSnd = print "snd"
 249         print FieldFst = print "fst"
 250
 251 instance print VarDef where
 252         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 253
 254 instance print FunCall where
 255         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 256
 257 instance print Expr where
 258         print (VarExpr vd) = print vd
 259         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 260                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 261                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 262                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 263                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 264                 ," ":print e2] ++ [")"]
 265         print (Op1Expr o e) = ["(",case o of
 266                 UnNegation = "!"; UnMinus = "-"
 267                 :print e] ++ [")"]
 268         print (IntExpr i) = [toString i]
 269         print (CharExpr c) = ["\'", case c of
 270                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 271                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 272                 c = if (c == toChar 7) "\\a" (toString c)
 273                 ,"\'"]
 274         print (BoolExpr b) = [toString b]
 275         print (FunExpr fc) = print fc
 276         print EmptyListExpr = ["[]"]
 277         print (TupleExpr e1 e2) = ["(":print e1] ++ [",":print e2] ++ [")"]