src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left $ toString $ LexError e
  22 parser (Right r) = case runParser parseProgram r of
  23         (Right p, _) = Right p
  24         (Left e, _) = Left $ toString e
  25
  26 parseProgram :: Parser Token AST
  27 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  28
  29 parseFunDecl :: Parser Token FunDecl
  30 parseFunDecl = liftM5 FunDecl
  31         (parseIdent <* satTok BraceOpenToken)
  32         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  33         (parseFunType <* satTok CBraceOpenToken)
  34         (many parseVarDecl)
  35         (many parseStmt <* satTok CBraceCloseToken)
  36
  37 parseStmt :: Parser Token Stmt
  38 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  39         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  40         (liftM FunStmt (parseSColon parseFunCall))
  41         where
  42                 parseSColon :: (Parser Token a) -> Parser Token a
  43                 parseSColon p = p <* satTok SColonToken
  44
  45                 parseReturnStmt :: Parser Token Stmt
  46                 parseReturnStmt =
  47                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  48
  49                 parseAssStmt :: Parser Token Stmt
  50                 parseAssStmt =
  51                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  52
  53                 parseIfStmt :: Parser Token Stmt
  54                 parseIfStmt = liftM3 IfStmt
  55                         (satTok IfToken *> parseBBraces parseExpr)
  56                         (parseBlock <|> parseOneLine)
  57                         (liftM (fromMaybe [])
  58                                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  59
  60                 parseWhileStmt :: Parser Token Stmt
  61                 parseWhileStmt = satTok WhileToken *>
  62                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  63
  64                 parseBlock :: Parser Token [Stmt]
  65                 parseBlock = parseBCBraces (many parseStmt)
  66
  67                 parseOneLine :: Parser Token [Stmt]
  68                 //first pure makes singleton list from the statement
  69                 parseOneLine = liftM pure parseStmt
  70
  71 parseBBraces :: (Parser Token a) -> Parser Token a
  72 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
  73
  74 parseBCBraces :: (Parser Token a) -> Parser Token a
  75 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
  76
  77 parseBSqBraces :: (Parser Token a) -> Parser Token a
  78 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
  79
  80 parseFunType :: Parser Token FunType
  81 parseFunType = satTok DoubleColonToken *>
  82         (parseInOutType <|> (liftM (FunType []) parseVoidOrType))
  83         where
  84                 parseInOutType :: Parser Token FunType
  85                 parseInOutType = liftM2 FunType
  86                         (some parseType <* satTok ArrowToken) parseVoidOrType
  87
  88                 parseVoidOrType :: Parser Token (Maybe Type)
  89                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  90                         (liftM Just parseType)
  91
  92 parseVarDecl :: Parser Token VarDecl
  93 parseVarDecl = liftM3 VarDecl
  94         (parseType <|> trans1 VarToken VarType )
  95         (parseIdent <* satTok AssignmentToken)
  96         (parseExpr <* satTok SColonToken)
  97
  98 parseType :: Parser Token Type
  99 parseType =
 100         trans1 IntTypeToken IntType <|>
 101         trans1 CharTypeToken CharType <|>
 102         trans1 BoolTypeToken BoolType <|>
 103         (liftM ListType (parseBSqBraces parseType)) <|>
 104         (liftM2 TupleType
 105                 (satTok BraceOpenToken *> parseType <* satTok CommaToken)
 106                 (parseType <* satTok BraceCloseToken)) <|>
 107         (liftM IdType parseIdent)
 108
 109 //TODO hieronder omzetten naar liftm notatie
 110 parseExpr :: Parser Token Expr
 111 parseExpr = //Operators in order of binding strength
 112         parseOpR (trans1 ColonToken BiCons) $
 113         parseOpR (trans1 PipesToken BiOr) $
 114         parseOpR (trans1 AmpersandsToken BiAnd) $
 115         parseOpR (trans1 EqualsToken BiEquals <|>
 116                         trans1 LesserToken BiLesser <|>
 117                         trans1 BiggerToken BiGreater <|>
 118                         trans1 LesserEqToken BiLesserEq <|>
 119                         trans1 GreaterEqToken BiGreaterEq <|>
 120                         trans1 NotEqualToken BiUnEqual) $
 121         parseOpL (trans1 PlusToken BiPlus <|>
 122                         trans1 DashToken BiMinus) $
 123         parseOpL (trans1 StarToken BiTimes <|>
 124                         trans1 SlashToken BiDivide <|>
 125                         trans1 PercentToken BiMod) $ parseBasicExpr
 126         where
 127                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 128                 parseOpR ops prev = prev >>= \e1->optional (
 129                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 130                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 131
 132                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 133                 parseOpL ops prev = prev >>= \e1->many (
 134                                 ops >>= \op->prev >>= \e->pure (op, e)
 135                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 136
 137                 parseBasicExpr :: Parser Token Expr
 138                 parseBasicExpr =
 139                         (satTok BraceOpenToken *> parseExpr <* satTok CommaToken
 140                                 >>= \e1->parseExpr <* satTok BraceCloseToken
 141                                 >>= \e2->pure $ TupleExpr e1 e2) <|>
 142                         (parseFunCall >>= \fc->pure $ FunExpr fc) <|>
 143                         parseBBraces parseExpr <|>
 144                         trans1 EmptyListToken EmptyListExpr <|>
 145                         trans2 TrueToken (const $ BoolExpr True) <|>
 146                         trans2 FalseToken (const $ BoolExpr False) <|>
 147                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 148                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 149                         (parseOp1 >>= \o->parseExpr >>= \e.pure $ Op1Expr o e) <|>
 150                         (parseVarDef >>= \ve->pure $ VarExpr ve)
 151
 152 parseFunCall :: Parser Token FunCall
 153 parseFunCall = parseIdent <* satTok BraceOpenToken
 154         >>= \i->parseSepList CommaToken parseExpr
 155         <* satTok BraceCloseToken >>= \es->pure $ FunCall i es
 156
 157 parseVarDef :: Parser Token VarDef
 158 parseVarDef = parseIdent
 159         >>= \i-> many (satTok DotToken *> (
 160                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 161                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 162                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 163                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))
 164         ) >>= \f->pure $ VarDef i f
 165
 166 parseOp1 :: Parser Token Op1
 167 parseOp1 = trans1 DashToken UnMinus <|>
 168         trans1 ExclamationToken UnNegation
 169
 170 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 171 trans2 t f = satTok t >>= \(_, r).pure (f r)
 172
 173 trans1 :: TokenValue a -> Parser Token a
 174 trans1 t r = trans2 t $ const r
 175
 176 derive gPrint TokenValue
 177 derive gEq TokenValue
 178 satTok :: TokenValue -> Parser Token Token
 179 satTok t = top >>= \tok=:(pos, tv) -> if (eq t tok) (return tok) (fail <?> (printToString tv, pos))
 180         where
 181                 eq (IdentToken _) (_, IdentToken _) = True
 182                 eq (NumberToken _) (_, NumberToken _) = True
 183                 eq (CharToken _) (_, CharToken _) = True
 184                 eq x (_, y) = gEq {|*|} x y
 185
 186 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 187 parseSepList sep p =
 188         (some (p <* satTok sep) >>= \es->p >>= \e.pure $ reverse [e:es]) <|>
 189         (p >>= \e->pure [e]) <|> pure []
 190
 191 parseIdent :: Parser Token String
 192 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 193
 194 instance toString AST where
 195         toString (AST v f) = concat (
 196                 ["\n":printersperse "\n" v] ++
 197                 ["\n":printersperse "\n" f])
 198
 199 class print a :: a -> [String]
 200
 201 printersperse :: String [a] -> [String] | print a
 202 printersperse i j = intercalate [i] (map print j)
 203
 204 instance print FunDecl where
 205         print (FunDecl i as t vs ss) =
 206                 ["\n", i, " (":printersperse "," as] ++
 207                 [") :: ":print t] ++
 208                 ["{":printersperse "\n\t" vs] ++
 209                 ["\n":printStatements ss 1] ++ ["}"]
 210
 211 printStatements :: [Stmt] Int -> [String]
 212 printStatements [] i = []
 213 printStatements [s:ss] i = (case s of
 214         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 215                 printCodeBlock thens i ++
 216                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 217         (WhileStmt b dos) = indent i ["while (":print b] ++
 218                 [")":printCodeBlock dos i]
 219         (AssStmt vardef val) =
 220                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 221         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 222         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 223         ) ++ printStatements ss i
 224         where
 225                 printCodeBlock :: [Stmt] Int -> [String]
 226                 printCodeBlock [] _ = ["{}"]
 227                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 228                 printCodeBlock x i =
 229                         ["{\n":printStatements x (i+1)] ++ indent i ["}\n"]
 230
 231                 indent :: Int [String] -> [String]
 232                 indent i rest = replicate i "\t" ++ rest
 233
 234 instance print FunType where
 235         print (FunType at rt) = printersperse " " at ++
 236                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 237
 238 instance print VarDecl where
 239         print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]
 240
 241 instance print Type where
 242         print (TupleType t1 t2) = ["(":print t1] ++ [",":print t2] ++ [")"]
 243         print (ListType t) = ["[":print t] ++ ["]"]
 244         print (IdType s) = print s
 245         print IntType = print "Int"
 246         print BoolType = print "Bool"
 247         print CharType = print "Char"
 248         print VarType = print "var"
 249
 250 instance print String where
 251         print s = [s]
 252
 253 instance print FieldSelector where
 254         print FieldHd = print "hd"
 255         print FieldTl = print "tl"
 256         print FieldSnd = print "snd"
 257         print FieldFst = print "fst"
 258
 259 instance print VarDef where
 260         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 261
 262 instance print FunCall where
 263         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 264
 265 instance print Expr where
 266         print (VarExpr vd) = print vd
 267         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 268                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 269                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 270                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 271                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 272                 ," ":print e2] ++ [")"]
 273         print (Op1Expr o e) = ["(",case o of
 274                 UnNegation = "!"; UnMinus = "-"
 275                 :print e] ++ [")"]
 276         print (IntExpr i) = [toString i]
 277         print (CharExpr c) = ["\'", case c of
 278                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 279                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 280                 c = if (c == toChar 7) "\\a" (toString c)
 281                 ,"\'"]
 282         print (BoolExpr b) = [toString b]
 283         print (FunExpr fc) = print fc
 284         print EmptyListExpr = ["[]"]
 285         print (TupleExpr e1 e2) = ["(":print e1] ++ [",":print e2] ++ [")"]