src/parse.icl

   1 implementation module parse
   2
   3 import StdString
   4 import StdTuple
   5 import StdList
   6 from StdFunc import const, o
   7 import Data.Either
   8 import Data.Functor
   9 import Data.Maybe
  10 import Control.Monad
  11 import Control.Applicative
  12 import Data.Func
  13 from Data.List import intercalate, replicate, instance Functor []
  14 from Text import class Text(concat), instance Text String
  15 import GenPrint
  16
  17 import yard
  18 import lex
  19
  20 parser :: LexerOutput -> ParserOutput
  21 parser (Left e) = Left $ toString $ LexError e
  22 parser (Right r) = case runParser parseProgram r of
  23         (Right p, _) = Right p
  24         (Left e, _) = Left $ toString e
  25
  26 parseProgram :: Parser Token AST
  27 parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl)
  28
  29 parseFunDecl :: Parser Token FunDecl
  30 parseFunDecl = liftM5 FunDecl
  31         (parseIdent <* satTok BraceOpenToken)
  32         (parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
  33         (parseFunType <* satTok CBraceOpenToken)
  34         (many parseVarDecl)
  35         (many parseStmt <* satTok CBraceCloseToken)
  36
  37 parseStmt :: Parser Token Stmt
  38 parseStmt = parseIfStmt <|> parseWhileStmt <|>
  39         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  40         (liftM FunStmt (parseSColon parseFunCall))
  41         where
  42                 parseSColon :: (Parser Token a) -> Parser Token a
  43                 parseSColon p = p <* satTok SColonToken
  44
  45                 parseReturnStmt :: Parser Token Stmt
  46                 parseReturnStmt =
  47                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  48
  49                 parseAssStmt :: Parser Token Stmt
  50                 parseAssStmt =
  51                         liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr
  52
  53                 parseIfStmt :: Parser Token Stmt
  54                 parseIfStmt = liftM3 IfStmt
  55                         (satTok IfToken *> parseBBraces parseExpr)
  56                         (parseBlock <|> parseOneLine)
  57                         (optional (satTok ElseToken *> (parseBlock <|> parseOneLine)
  58                                 ) >>= pure o fromMaybe [])
  59
  60                 parseWhileStmt :: Parser Token Stmt
  61                 parseWhileStmt = satTok WhileToken *>
  62                         liftM2 WhileStmt (parseBBraces parseExpr) parseBlock
  63
  64                 parseBlock :: Parser Token [Stmt]
  65                 parseBlock = parseBCBraces (many parseStmt)
  66
  67                 parseOneLine :: Parser Token [Stmt]
  68                 //first pure makes singleton list from the statement
  69                 parseOneLine = liftM pure parseStmt
  70
  71 parseBBraces :: (Parser Token a) -> Parser Token a
  72 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
  73
  74 parseBCBraces :: (Parser Token a) -> Parser Token a
  75 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
  76
  77 parseFunType :: Parser Token FunType
  78 parseFunType = satTok DoubleColonToken *>
  79         (parseInOutType <|> (parseVoidOrType >>= \t->pure $ FunType [] t))
  80         where
  81                 parseInOutType :: Parser Token FunType
  82                 parseInOutType = some parseType <* satTok ArrowToken
  83                         >>= \intypes-> parseVoidOrType
  84                         >>= \outtypes->pure $ FunType intypes outtypes
  85
  86                 parseVoidOrType :: Parser Token (Maybe Type)
  87                 parseVoidOrType = (satTok VoidToken *> pure Nothing) <|>
  88                         (parseType >>= \type->pure $ Just type)
  89
  90 parseVarDecl :: Parser Token VarDecl
  91 parseVarDecl =
  92         (parseType <|> trans1 VarToken VarType )
  93         >>= \t->parseIdent <* satTok AssignmentToken
  94         >>= \i->parseExpr <* satTok SColonToken
  95         >>= \e->pure $ VarDecl i t e
  96
  97 parseType :: Parser Token Type
  98 parseType =
  99         trans1 IntTypeToken IntType <|>
 100         trans1 CharTypeToken CharType <|>
 101         trans1 BoolTypeToken BoolType <|>
 102         (satTok SquareOpenToken *> parseType <* satTok SquareCloseToken
 103                 >>= \t.pure $ ListType t) <|>
 104         (satTok BraceOpenToken *> parseType <* satTok CommaToken
 105                 >>= \t1->parseType <* satTok BraceCloseToken
 106                 >>= \t2->pure $ TupleType t1 t2) <|>
 107         (parseIdent >>= \e.pure $ IdType e) <|>
 108         empty
 109
 110 parseExpr :: Parser Token Expr
 111 parseExpr = //Operators in order of binding strength
 112         parseOpR (trans1 ColonToken BiCons) $
 113         parseOpR (trans1 PipesToken BiOr) $
 114         parseOpR (trans1 AmpersandsToken BiAnd) $
 115         parseOpR (trans1 EqualsToken BiEquals <|>
 116                         trans1 LesserToken BiLesser <|>
 117                         trans1 BiggerToken BiGreater <|>
 118                         trans1 LesserEqToken BiLesserEq <|>
 119                         trans1 GreaterEqToken BiGreaterEq <|>
 120                         trans1 NotEqualToken BiUnEqual) $
 121         parseOpL (trans1 PlusToken BiPlus <|>
 122                         trans1 DashToken BiMinus) $
 123         parseOpL (trans1 StarToken BiTimes <|>
 124                         trans1 SlashToken BiDivide <|>
 125                         trans1 PercentToken BiMod) $ parseBasicExpr
 126         where
 127                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 128                 parseOpR ops prev = prev >>= \e1->optional (
 129                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 130                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe
 131
 132                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 133                 parseOpL ops prev = prev >>= \e1->many (
 134                                 ops >>= \op->prev >>= \e->pure (op, e)
 135                         ) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe
 136
 137                 parseBasicExpr :: Parser Token Expr
 138                 parseBasicExpr =
 139                         (satTok BraceOpenToken *> parseExpr <* satTok CommaToken
 140                                 >>= \e1->parseExpr <* satTok BraceCloseToken
 141                                 >>= \e2->pure $ TupleExpr e1 e2) <|>
 142                         (parseFunCall >>= \fc->pure $ FunExpr fc) <|>
 143                         parseBBraces parseExpr <|>
 144                         trans1 EmptyListToken EmptyListExpr <|>
 145                         trans2 TrueToken (const $ BoolExpr True) <|>
 146                         trans2 FalseToken (const $ BoolExpr False) <|>
 147                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
 148                         trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
 149                         (parseOp1 >>= \o->parseExpr >>= \e.pure $ Op1Expr o e) <|>
 150                         (parseVarDef >>= \ve->pure $ VarExpr ve)
 151
 152 parseFunCall :: Parser Token FunCall
 153 parseFunCall = parseIdent <* satTok BraceOpenToken
 154         >>= \i->parseSepList CommaToken parseExpr
 155         <* satTok BraceCloseToken >>= \es->pure $ FunCall i es
 156
 157 parseVarDef :: Parser Token VarDef
 158 parseVarDef = parseIdent
 159         >>= \i-> many (satTok DotToken *> (
 160                 (parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
 161                 (parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
 162                 (parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
 163                 (parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))
 164         ) >>= \f->pure $ VarDef i f
 165
 166 parseOp1 :: Parser Token Op1
 167 parseOp1 = trans1 DashToken UnMinus <|>
 168         trans1 ExclamationToken UnNegation
 169
 170 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 171 trans2 t f = satTok t >>= \(_, r).pure (f r)
 172
 173 trans1 :: TokenValue a -> Parser Token a
 174 trans1 t r = trans2 t $ const r
 175
 176 derive gPrint TokenValue
 177 satTok :: TokenValue -> Parser Token Token
 178 satTok t = top >>= \tok=:(pos, tv) -> if (t === tok) (return tok) (fail <?> (printToString t, pos))
 179
 180 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 181 parseSepList sep p =
 182         (some (p <* satTok sep) >>= \es->p >>= \e.pure $ reverse [e:es]) <|>
 183         (p >>= \e->pure [e]) <|> pure []
 184
 185 parseIdent :: Parser Token String
 186 parseIdent = trans2 (IdentToken []) (\(IdentToken e).toString e)
 187
 188 instance toString AST where
 189         toString (AST v f) = concat (
 190                 ["\n":printersperse "\n" v] ++
 191                 ["\n":printersperse "\n" f])
 192
 193 class print a :: a -> [String]
 194
 195 printersperse :: String [a] -> [String] | print a
 196 printersperse i j = intercalate [i] (map print j)
 197
 198 instance print FunDecl where
 199         print (FunDecl i as t vs ss) =
 200                 ["\n", i, " (":printersperse "," as] ++
 201                 [") :: ":print t] ++
 202                 ["{":printersperse "\n\t" vs] ++
 203                 ["\n":printStatements ss 1] ++ ["}"]
 204
 205 printStatements :: [Stmt] Int -> [String]
 206 printStatements [] i = []
 207 printStatements [s:ss] i = (case s of
 208         (IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
 209                 printCodeBlock thens i ++
 210                 indent i ["else ":printCodeBlock elses i] ++ ["\n"]
 211         (WhileStmt b dos) = indent i ["while (":print b] ++
 212                 [")":printCodeBlock dos i]
 213         (AssStmt vardef val) =
 214                 indent i $ print vardef ++ ["=":print val] ++ [";\n"]
 215         (FunStmt fc) = indent i $ print fc ++ [";\n"]
 216         (ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
 217         ) ++ printStatements ss i
 218         where
 219                 printCodeBlock :: [Stmt] Int -> [String]
 220                 printCodeBlock [] _ = ["{}"]
 221                 printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
 222                 printCodeBlock x i =
 223                         ["{\n":printStatements x (i+1)] ++ indent i ["}"]
 224
 225                 indent :: Int [String] -> [String]
 226                 indent i rest = replicate i "\t" ++ rest
 227
 228 instance print FunType where
 229         print (FunType at rt) = printersperse " " at ++
 230                 [if (isEmpty at) "" "->":maybe ["Void"] print rt]
 231
 232 instance print VarDecl where
 233         print (VarDecl i t e) = print t ++ [" ":i:"=":print e] ++ [";"]
 234
 235 instance print Type where
 236         print (TupleType t1 t2) = ["(":print t1] ++ [",":print t2] ++ [")"]
 237         print (ListType t) = ["[":print t] ++ ["]"]
 238         print (IdType s) = print s
 239         print IntType = print "Int"
 240         print BoolType = print "Bool"
 241         print CharType = print "Char"
 242         print VarType = print "var"
 243
 244 instance print String where
 245         print s = [s]
 246
 247 instance print FieldSelector where
 248         print FieldHd = print "hd"
 249         print FieldTl = print "tl"
 250         print FieldSnd = print "snd"
 251         print FieldFst = print "fst"
 252
 253 instance print VarDef where
 254         print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]
 255
 256 instance print FunCall where
 257         print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]
 258
 259 instance print Expr where
 260         print (VarExpr vd) = print vd
 261         print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
 262                 BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
 263                 BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
 264                 BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
 265                 BiAnd = "&&"; BiOr = "||"; BiCons = ":"
 266                 ," ":print e2] ++ [")"]
 267         print (Op1Expr o e) = ["(",case o of
 268                 UnNegation = "!"; UnMinus = "-"
 269                 :print e] ++ [")"]
 270         print (IntExpr i) = [toString i]
 271         print (CharExpr c) = ["\'", case c of
 272                 '\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
 273                 '\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
 274                 c = if (c == toChar 7) "\\a" (toString c)
 275                 ,"\'"]
 276         print (BoolExpr b) = [toString b]
 277         print (FunExpr fc) = print fc
 278         print EmptyListExpr = ["[]"]
 279         print (TupleExpr e1 e2) = ["(":print e1] ++ [",":print e2] ++ [")"]