src/yard.icl

   1 implementation module yard
   2
   3 import StdTuple
   4 import StdClass
   5 import StdString
   6 import Data.Functor
   7 import Data.Either
   8 import Control.Monad
   9 import Control.Applicative
  10 from Data.Func import $
  11
  12 instance toString Error where
  13         toString ParseError = "General parse error"
  14         toString (LexError e) = "Lexer error: " +++ e
  15
  16 runParser :: (Parser a b) [a] -> (Either Error b, [a])
  17 runParser (Parser f) i = f i
  18
  19 instance Functor (Parser a) where
  20     fmap f m = liftM f m
  21
  22 instance Applicative (Parser a) where
  23     pure a      = Parser \i -> (Right a, i)
  24     (<*>) sf p  = ap sf p
  25
  26 instance Monad (Parser a) where
  27     bind p f    = Parser \i -> case runParser p i of
  28         (Right r, rest) = runParser (f r) rest
  29         (Left e, rest)  = (Left e, rest)
  30
  31 instance Alternative (Parser a) where
  32     empty       = Parser \i -> (Left ParseError, i)
  33     (<|>) p1 p2 = Parser \i -> case runParser p1 i of
  34         (Right r, rest) = (Right r, rest)
  35         (Left _, rest)  = runParser p2 i
  36
  37 fail :: Parser a b
  38 fail = empty
  39
  40 top :: Parser a a
  41 top = Parser \i -> case i of
  42     []      = (Left ParseError, [])
  43     [x:xs]  = (Right x, xs)
  44
  45 satisfy :: (a -> Bool) -> Parser a a
  46 satisfy f = top >>= \r -> if (f r) (return r) fail
  47
  48 item :: a -> Parser a a | Eq a
  49 item a  = satisfy ((==)a)
  50
  51 list :: [a] -> Parser a [a] | Eq a
  52 list as = mapM item as