yard.icl

   1 implementation module yard
   2
   3 import StdTuple
   4 import StdClass
   5 import StdString
   6 import StdList
   7 import StdInt
   8 from Data.List import intersperse
   9 from Text import instance Text String, class Text(concat)
  10 import Data.Functor
  11 import Data.Either
  12 import Control.Monad
  13 import Control.Applicative
  14 from Data.Func import $
  15 import Data.Void
  16
  17 instance toString Error where
  18         toString (PositionalError l c e) =
  19                 concat [toString l,":",toString c,": ",e, "\n"]
  20         toString (Error e) = concat ["-:-: ", e, "\n"]
  21
  22 runParser :: (Parser a b) [a] -> (Either Error b, [a])
  23 runParser (Parser f) i = f i
  24
  25 instance + Error where
  26         (+) r1 r2 = r2 //TODO
  27
  28 instance Functor (Parser a) where
  29     fmap f m = liftM f m
  30
  31 instance Applicative (Parser a) where
  32     pure a      = Parser \i -> (Right a, i)
  33     (<*>) sf p  = ap sf p
  34
  35 instance Monad (Parser a) where
  36     bind p f    = Parser \i -> case runParser p i of
  37         (Right r, rest) = runParser (f r) rest
  38         (Left e, _)     = (Left e, i)
  39
  40 instance Alternative (Parser a) where
  41     empty       = Parser \i -> (Left $ Error "" , i)
  42     (<|>) p1 p2 = Parser \i -> case runParser p1 i of
  43         (Right r, rest) = (Right r, rest)
  44         (Left e1, rest) = case runParser p2 i of
  45             (Left e2, rest)  = (Left $ e1+e2, i)
  46             (Right r, rest)  = (Right r, rest)
  47
  48 //Try the parser, if it fails decorate the error with Expected of the given String and position
  49 (<?>) :: (Parser a b) Error -> Parser a b
  50 (<?>) p e = Parser \i -> case runParser p i of
  51     (Left e1, rest) = (Left $ e1 + e, rest)
  52     (Right r, rest) = (Right r, rest)
  53
  54 fail :: Parser a b
  55 fail = empty
  56
  57 top :: Parser a a
  58 top = Parser \i -> case i of
  59     []      = (Left $ Error "", [])
  60     [x:xs]  = (Right x, xs)
  61
  62 peek :: Parser a a
  63 peek = Parser \i -> case i of
  64     []      = (Left $ Error "", [])
  65     [x:xs]  = (Right x, [x:xs])
  66
  67 //runs the left parser until the right parser succeeds. Returns the result of the left parser
  68 //Note: if the right parser consumes input then this input is lost!
  69 //If the left parser fails before the right parser succeeds the whole parser fails
  70 (until) infix 2 :: (Parser a b) (Parser a c) -> Parser a [b]
  71 (until) p guard = try $ until` p guard []
  72     where
  73         until` :: (Parser a b) (Parser a c) [b] -> Parser a [b]
  74         until` p guard acc = Parser \i -> case runParser guard i of
  75             (Right _, rest) = (Right acc, rest)
  76             (Left _, _)     = case runParser p i of
  77                 (Right r, rest) = runParser (until` p guard [r:acc]) rest
  78                 (Left e, _)     = (Left e, i)
  79         try :: (Parser a b) -> Parser a b
  80         try p = Parser \i -> case runParser p i of
  81             (Left e, _)     = (Left e, i)
  82             (Right r, rest) = (Right r, rest)
  83
  84
  85 eof :: Parser a Void
  86 eof = Parser \i -> case i of
  87     []      = (Right Void, [])
  88     _       = (Left $ Error "", i)
  89
  90 satisfy :: (a -> Bool) -> Parser a a
  91 satisfy f = top >>= \r -> if (f r) (return r) fail
  92
  93 check :: (a -> Bool) -> Parser a a
  94 check f = peek >>= \r -> if (f r) (return r) fail
  95
  96 item :: a -> Parser a a | Eq a
  97 item a  = satisfy ((==)a)
  98
  99 list :: [a] -> Parser a [a] | Eq a
 100 list as = mapM item as