grammar robots.missions.TaskDSL with org.eclipse.xtext.common.Terminals

generate taskDSL "http://www.missions.robots/TaskDSL"

Robot:
	'Acceleration' acc=INT
	'Speed' spd=INT
	behaviour+=Behaviour+
	mission+=Mission+;

Mission: 
	'Mission' name=ID 'using' behaviours+=[Behaviour]+ 'and stops when' se=StoppingExpression;

StoppingExpression:
	'(' op=Operator s+=StoppingExpression s+=StoppingExpression+ ')' |
	'not ' negscond=StoppingCondition |
	scond=StoppingCondition;

StoppingCondition:
	'Collected at least' colors+=Color+ |
	'Touched on' touch=LeftRight |
	'Light on' light=LeftRight |
	'No object in sight on ' dist=BackFront |
	'Color is' color=Color;

Behaviour: 'Behaviour' name=ID 
	'take control:' tc=StoppingExpression?
	'action:' actions+=Action+;

Action:
	whichMotor=LeftRight 'motor' moveDir=Direction ('with speed' spd=INT 'acceleration' acc=INT)? |
	'turn' turnDir=LeftRight degrees=INT ('with speed' spd=INT 'acceleration' acc=INT)? |
	'measure' measureWhat=RockLake |
	'wait' time=Time;

Time: time=INT 'ms' | {Time} 'forever';
 
RockLake: d=RockLakeE;
enum RockLakeE: ROCK='rock' | LAKE='lake';
Direction: d=DirectionE;
enum DirectionE: BACKWARDS = 'backward' | FORWARDS = 'forward';
Operator: d=OperatorE;
enum OperatorE: AND = 'and' | OR = 'or';
BackFront: d=BackFrontE;
enum BackFrontE: BACK = 'back' | FRONT = 'front';
Comparison: d=ComparisonE;
enum ComparisonE: GE='>' | LE='<';
LeftRight: d=LeftRightE;
enum LeftRightE: LEFT='left' | RIGHT='right';
Color: d=ColorE;
enum ColorE:
	RED='Red' | GREEN='Green' | BLUE='Blue' | YELLOW='Yellow' | 
	MAGENTA='Magenta'| ORANGE='Orange'|	WHITE='White' | BLACK='Black' | 
	PINK='Pink' | GRAY='Gray' | LIGHTGRAY='LightGray' |
	DARKGRAY='DarkGray' | CYAN='Cyan' | BROWN='Brown';