implementation module lex

import Control.Monad
import Data.Either
import Data.Maybe
import Data.Map
import Data.Func
import StdString
import StdTuple
import StdBool
import StdList
import StdChar
import qualified Text

SingleCharTokens :: Map Char Token
SingleCharTokens = fromList [
	('(', BraceOpenToken), (')', BraceCloseToken), ('{', CBraceOpenToken),
	('}', CBraceCloseToken), ('[', SquareOpenToken), (']', SquareCloseToken),
	(',', CommaToken), (':', ColonToken), (';', SColonToken),
	('.', DotToken), ('+', PlusToken), ('-', DashToken), ('*', StarToken),
	('/', SlashToken), ('%', PercentToken), ('=', AssignmentToken),
	('<', LesserToken), ('>', BiggerToken), ('!', ExclamationToken)]

EscapeMap :: Map Char Char
EscapeMap = fromList [('a', toChar 7), ('b', '\b'), ('f', '\f'), ('n', '\n'),
	('r', '\r'), ('t', '\t'), ('v', '\v')]

lexer :: [Char] -> LexerOutput
lexer [] = Right []
lexer x = case lex x of
	(Right t, rest) = lexer rest >>= \ts.Right [t:ts]
	(Left e, _) = Left e

lex :: [Char] -> (Either String Token, [Char])
lex [] = (Right EndOfFileToken, [])
lex ['/':'/':xs] = lex $ dropWhile ((<>) '\n') xs
lex ['/':'*':xs] = lex $ tl $ map snd $ dropWhile ((<>) ('*', '/')) $ zip2 [zero:xs] xs
lex ['v':'a':'r':xs] = (Right VarToken, xs)
lex ['V':'o':'i':'d':xs] = (Right VoidToken, xs)
lex ['r':'e':'t':'u':'r':'n':xs] = (Right ReturnToken, xs)
lex ['i':'f':xs] = (Right IfToken, xs)
lex ['e':'l':'s':'e':xs] = (Right ElseToken, xs)
lex ['w':'h':'i':'l':'e':xs] = (Right WhileToken, xs)
lex ['T':'r':'u':'e':xs] = (Right TrueToken, xs)
lex ['F':'a':'l':'s':'e':xs] = (Right FalseToken, xs)
lex ['I':'n':'t':xs] = (Right IntTypeToken, xs)
lex ['C':'h':'a':'r':xs] = (Right CharTypeToken, xs)
lex ['B':'o':'o':'l':xs] = (Right BoolTypeToken, xs)
lex [':':':':xs] = (Right DoubleColonToken, xs)
lex ['!':'=':xs] = (Right NotEqualToken, xs)
lex ['<':'=':xs] = (Right LesserEqToken, xs)
lex ['>':'=':xs] = (Right GreaterEqToken, xs)
lex ['=':'=':xs] = (Right EqualsToken, xs)
lex ['&':'&':xs] = (Right AmpersandsToken, xs)
lex ['|':'|':xs] = (Right PipesToken, xs)
lex ['-':'>':xs] = (Right ArrowToken, xs)
lex ['\'':x:'\'':xs] = (Right (CharToken x), xs)
lex ['\'':'\\':x:'\'':xs] = case get x EscapeMap of
	Just t = (Right (CharToken t), xs)
	_ = (Left ("Unknown escape: \\" +++ toString x), [])
lex [x:xs]
# t = get x SingleCharTokens
| isJust t = (Right (fromJust t), xs)
| isSpace x = lex xs
| isDigit x = let (is, xs`) = span isDigit xs in
	(Right (NumberToken [x:is]), xs`)
| isAlpha x = let (is, xs`) = span (\c.isAlphanum c || c == '_') xs in
	(Right (IdentToken [x:is]), xs`)
| otherwise = (Left ("Unexpected character: " +++ toString x), [])