implementation module lex

import Control.Monad
import Data.Either
import Data.Maybe
import Data.Map
import StdString
import StdBool
import StdList
import StdChar
import StdFile
import System.CommandLine
import qualified Text

SingleCharTokens :: Map Char Token
SingleCharTokens = fromList [
	('(', BraceOpenToken), (')', BraceCloseToken), ('{', CBraceOpenToken),
	('}', CBraceCloseToken), ('[', SquareOpenToken), (']', SquareCloseToken),
	(',', CommaToken), (':', ColonToken), (';', SColonToken),
	('.', DotToken), ('+', PlusToken), ('-', DashToken), ('*', StarToken),
	('/', SlashToken), ('%', PercentToken), ('=', AssignmentToken),
	('<', LesserToken), ('>', BiggerToken), ('!', ExclamationToken)]

EscapeMap :: Map Char Char
EscapeMap = fromList [
	('a', toChar 7), ('b', '\b'), ('f', '\f'), ('n', '\n'), ('r', '\r'),
	('t', '\t'), ('v', '\v')]

lexer :: [Char] -> LexerOutput
lexer [] = Right []
lexer x = case lex x of
	(Right t, rest) = lexer rest >>= \ts.Right [t:ts]
	(Left e, _) = Left e

lex :: [Char] -> (Either String Token, [Char])
lex [] = (Right EndOfFileToken, [])
//Comments
lex ['/':'/':x:rest] = if (x == '\n') (lex rest) (lex ['/':'/':rest])
lex ['/':'*':x1:x2:rest] = if (x1 == '*' && x2 == '/') 
	(lex rest) (lex ['/':'*':rest])
//Keyword tokens
lex ['v':'a':'r':rest] = (Right VarToken, rest)
lex ['V':'o':'i':'d':rest] = (Right VoidToken, rest)
lex ['r':'e':'t':'u':'r':'n':rest] = (Right ReturnToken, rest)
lex ['i':'f':rest] = (Right IfToken, rest)
lex ['e':'l':'s':'e':rest] = (Right ElseToken, rest)
lex ['w':'h':'i':'l':'e':rest] = (Right WhileToken, rest)
lex ['T':'r':'u':'e':rest] = (Right TrueToken, rest)
lex ['F':'a':'l':'s':'e':rest] = (Right FalseToken, rest)
lex ['I':'n':'t':rest] = (Right IntTypeToken, rest)
lex ['C':'h':'a':'r':rest] = (Right CharTypeToken, rest)
lex ['B':'o':'o':'l':rest] = (Right BoolTypeToken, rest)
//Two character tokens
lex [':':':':rest] = (Right DoubleColonToken, rest)
lex ['!':'=':rest] = (Right NotEqualToken, rest)
lex ['<':'=':rest] = (Right LesserEqToken, rest)
lex ['>':'=':rest] = (Right GreaterEqToken, rest)
lex ['=':'=':rest] = (Right EqualsToken, rest)
lex ['&':'&':rest] = (Right AmpersandsToken, rest)
lex ['|':'|':rest] = (Right PipesToken, rest)
lex ['-':'>':rest] = (Right ArrowToken, rest)
//One character tokens
//Value tokens
lex ['\'':x:'\'':rest] = (Right (CharToken x), rest)
lex ['\'':'\\':x:'\'':rest] = case get x EscapeMap of
	Just t = (Right (CharToken t), rest)
	_ = (Left ("Unknown escape: \\" +++ toString x), [])
lex [x:rest]
# t = get x SingleCharTokens
| isJust t = (Right (fromJust t), rest)
| isSpace x = lex rest
| isDigit x = let (is, rest`) = span isDigit rest in
	(Right (NumberToken [x:is]), rest`)
| isAlpha x = let (is, rest`) = span (\c.isAlphanum c || c == '_') rest in
	(Right (IdentToken [x:is]), rest`)
| otherwise = (Left ("Unexpected character: " +++ toString x), [])