implementation module mTaskInterpret

//import iTasks
import gdynamic, gCons, GenEq, StdMisc, StdArray, GenBimap
import GenPrint
import mTask

import StdFile
import StdString

from StdFunc import o
import StdBool
import StdTuple
import Data.Tuple
import StdList
from Data.Func import $
from Text import class Text(concat,join,toUpperCase), instance Text String

toByteVal :: BC -> String
toByteVal a = toString $ toChar $ consIndex{|*|} a

derive gPrint BC, AnalogPin
derive consIndex BC
derive consName BC

toReadableByteVal :: BC -> String
toReadableByteVal a = printToString a

instance arith ByteCode where
	lit x = BC [BCPush $ toCode x]
	(+.) x y = x <++> y <+-> [BCAdd]
	(-.) x y = x <++> y <+-> [BCSub]
	(*.) x y = x <++> y <+-> [BCMul]
	(/.) x y = x <++> y <+-> [BCDiv]

instance boolExpr ByteCode where
	(&.) x y = x <++> y <+-> [BCAnd]
	(|.) x y = x <++> y <+-> [BCOr]
	Not x = x <+-> [BCNot]
	(==.) x y = x <++> y <+-> [BCEq]
	(!=.) x y = x <++> y <+-> [BCNeq]
	(<.) x y = x <++> y <+-> [ BCLes]
	(>.)  x y = x <++> y <+-> [BCGre]
	(<=.) x y = x <++> y <+-> [BCLeq]
	(>=.) x y = x <++> y <+-> [BCGeq]

instance analogIO ByteCode where
	analogRead p = BC [BCAnalogRead $ toCode p]
	analogWrite p b = b <+-> [BCAnalogWrite $ toCode p]

instance digitalIO ByteCode where
	digitalRead p = BC [BCDigitalRead $ toCode p]
	digitalWrite p b = b <+-> [BCDigitalWrite $ toCode p]

instance If ByteCode Stmt Stmt Stmt where If b t e = BCIfStmt b t e
instance If ByteCode Stmt e Stmt where If b t e = BCIfStmt b t e
instance If ByteCode Stmt Stmt e where If b t e = BCIfStmt b t e
instance If ByteCode x y Expr where If b t e = BCIfStmt b t e
instance IF ByteCode where
	IF b t e = BCIfStmt b t e
	(?) b t = BCIfStmt b t $ BC []
BCIfStmt b t e = b <+-> [BCJmpF $ length <$> t + 1] <++> t
	<+-> [BCJmp $ length <$> e] <++> e

instance noOp ByteCode where noOp = BC []

instance serial ByteCode where
	serialAvailable = BC [BCSerialAvail]
	serialPrint s = BC [BCSerialPrint]
	serialPrintln s = BC [BCSerialPrintln]
	serialRead = BC [BCSerialRead]
	serialParseInt = BC [BCSerialParseInt]

(<++>) infixl 7
(<++>) (BC x) (BC y) = BC $ x ++ y
(<+->) infixl 7
(<+->) (BC x) y = BC $ x ++ y
(<-+>) infixl 7
(<-+>) x (BC y) = BC $ x ++ y

(<$>) infixl 9
(<$>) f (BC x) = f x

instance zero BCState where
	zero = {a=()}

toRealByteCode :: (ByteCode a Expr) -> String
toRealByteCode (BC x) = concat $ map toByteVal x

//Start :: ByteCode Int Expr
//Start = (lit 36 +. lit 42) +. lit 84

//Run test programma en pretty print
Start = toRealByteCode $ If (lit True) (analogRead A1) (analogRead A0)
//Start :: ByteCode Int Expr
//Start = If (lit True) (analogRead A1) (analogRead A0)
//Start = If ((lit 36) ==. (lit 42)) (noOp) (noOp)