implementation module parse

import Control.Applicative
import Control.Monad
import Control.Monad.State
import Control.Monad.Trans
import Data.Either
import Data.GenEq
import Data.Functor
import Data.Func
import Data.List
import Data.Tuple
import Text.GenPrint
import StdEnv

import ast

cons x xs = [x:xs]

(<:>) infixl 0 :: a (m [a]) -> m [a] | Functor m
(<:>) l r = cons l <$> r

:: Token = TTSemiColon | TTBrackOpen | TTBrackClose | TTBool Bool | TTInt Int
	| TTOp [Char] | TTIdent [Char]

derive gEq Token
derive gPrint Token

instance toString Token where toString t = printToString t

lex :: [Char] -> Either [String] [Token]
lex [] = pure []
lex ['//\n':ts] = lex ts
lex ['//',t:ts] = lex ['/','/':ts]
lex ['/**/':ts] = lex $ dropWhile ((<>)'\n') ts
lex ['/*',t:ts] = lex ['/','*':ts]
lex [';':ts] = TTSemiColon <:> lex ts
lex [')':ts] = TTBrackClose <:> lex ts
lex ['(':ts] = TTBrackOpen <:> lex ts
lex ['True':ts] = TTBool True <:> lex ts
lex ['False':ts] = TTBool False <:> lex ts
lex ['-',t:ts]
	| isDigit t = lex [t:ts] >>= \v->case v of
		[TTInt i:rest] = Right [TTInt (~i):rest]
		x = pure x
lex [t:ts]
	| isSpace t = lex ts
	| isDigit t
		# (d, ts) = span isDigit [t:ts]
		= TTInt (toInt (toString d)) <:> lex ts
	| isAlpha t
		# (d, ts) = span isAlpha [t:ts]
		= TTIdent d <:> lex ts
	| isOp t
		# (d, ts) = span isOp [t:ts]
		= TTOp d <:> lex ts
	= Left ["Unexpected: " +++ toString t +++ " ord: " +++ toString (toInt t)]
where
	isOp c = isMember c ['!@#$%^&*=+/?-_|\\\'",<>.:']

:: Parser a :== StateT ParseState (Either [String]) a
:: ParseState =
	{ tokens :: [Token]
	, ifxs   :: [((Parser Expression) -> Parser Expression, Int)]
	}

pTop :: Parser Token
pTop = getState >>= \s->case s.tokens of
	[t:ts] = put {s & tokens=ts} >>| pure t
	[] = liftT (Left ["Fully consumed input"])

pEof :: Parser ()
pEof = getState >>= \s->case s.tokens of
	[] = pure ()
	[t:ts] = liftT (Left ["Expected EOF but got ":map toString [t:ts]])

(?) infixl 9 :: (Parser a) (a -> Bool) -> Parser a
(?) p f = p >>= \v->if (f v) (pure v) empty

pToken :: (Token -> Parser Token)
pToken = (?) pTop o (===)

pChainl :: (Parser (a a -> a)) (Parser a) -> Parser a
pChainl op p = foldl (flip ($)) <$> p <*> many (flip <$> op <*> p)

pChainr :: (Parser (a a -> a)) (Parser a) -> Parser a
pChainr op p = flip ($) <$> p <*> (flip <$> op <*> pChainr op p) <|> p

parse :: [Token] -> Either [String] [Either TypeDef Function]
parse ts = fst <$> runStateT (reverse <$> pAST <* pEof) {tokens=ts, ifxs=[]}
where
	pAST :: Parser [Either TypeDef Function]
	pAST = many (Right <$> pFunction <|> Left <$> pTypeDef)
		>>= mapM (either (pure o Left) \(id, args, body)->Right o
			Function id args <$ modify (\t->{t & tokens=body}) <*> pExpression <* pEof)

	pTypeDef :: Parser TypeDef
	pTypeDef = TypeDef
		<$  pToken (TTOp ['::'])
		<*> pId
		<*> many pId
		<*  pToken (TTOp ['='])
		<*> (cons <$> pCons <*> many (pToken (TTOp ['|']) *> pCons))
		<*  pToken TTSemiColon

	pCons = tuple <$> pId <*> many pType

	pType
		=   TInt  <$ pTop ? (\t->t=:(TTIdent ['Int']))
		<|> TBool <$ pTop ? (\t->t=:(TTIdent ['Bool']))
		<|> TVar  <$> pId
//		<|> 

	pId = (\(TTIdent i)->i) <$> pTop ? (\t->t=:(TTIdent _))
	pOp = (\(TTOp i)->i) <$> pTop ? (\t->t=:(TTOp _))
	pInt = (\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
	pBrack p = pToken TTBrackOpen *> p <* pToken TTBrackClose

	pFunction :: Parser ([Char], [[Char]], [Token])
	pFunction
		=   tuple3
		<$> (pFunId <|> pId)
		<*> many pId
		<*  pToken (TTOp ['='])
		<*> many (pTop ? ((=!=)TTSemiColon))
		<*  pToken TTSemiColon
	
	pFunId :: Parser [Char]
	pFunId = pOp
		>>= \i->pChainr <$ pId ? ((==) ['ifxr']) <|> pChainl <$ pId ? ((==)['ifxl'])
		>>= \p->pInt
		>>= \s->modify (\t->{t & ifxs=[(p (App o App (Var i) <$ pOp ? ((==)i)), s):t.ifxs]})
		>>| pure i

	pExpression :: Parser Expression
	pExpression = getState >>= \{ifxs}->flip (foldr ($))
			(map fst $ sortBy (on (<) snd) ifxs)
		$   pChainl (pure App)
		$   Lambda <$ pToken (TTOp ['\\']) <*> pId <* pToken (TTOp ['.']) <*> pExpression
		<|> pBrack (   Tuple <$> pExpression <* pToken (TTOp [',']) <*> pExpression
			       <|> Var <$> pOp
			       <|> pExpression)
		<|> Lit o Int <$> pInt
		<|> (\(TTBool i)->Lit (Bool i)) <$> pTop ? (\t->t=:(TTBool _))
		<|> (\x->Var ['_':x]) <$ pToken (TTIdent ['code']) <*> pId
		<|> Var <$> pId