implementation module parse

import Control.Applicative
import Control.Monad
import Control.Monad.State
import Control.Monad.Trans
import Data.Either
import Data.GenEq
import Data.Functor
import Data.Func
import Data.List
import Data.Tuple
import StdEnv

import ast

(<:>) infixl 0 :: a (m [a]) -> m [a] | Functor m
(<:>) l r = (\xs->[l:xs]) <$> r

:: Token = TTEq | TTSemiColon | TTLambda | TTDot | TTBrackOpen | TTBrackClose | TTBool Bool | TTInt Int | TTOp [Char] | TTIdent [Char]
derive gEq Token
lex :: [Char] -> Either [String] [Token]
lex [] = pure []
lex [';':ts] = TTSemiColon <:> lex ts
lex [')':ts] = TTBrackClose <:> lex ts
lex ['(':ts] = TTBrackOpen <:> lex ts
lex ['True':ts] = TTBool True <:> lex ts
lex ['False':ts] = TTBool False <:> lex ts
lex ['-',t:ts]
	| isDigit t = lex [t:ts] >>= \v->case v of
		[TTInt i:rest] = Right [TTInt (~i):rest]
		x = pure x
lex [t:ts]
	| isSpace t = lex ts
	| isDigit t
		# (i, ts) = span isDigit [t:ts]
		= TTInt (toInt (toString i)) <:> lex ts
	| isAlpha t
		# (i, ts) = span isAlpha [t:ts]
		= TTIdent i <:> lex ts
	| isOp t
		# (i, ts) = span isOp [t:ts]
		| i =: ['='] = TTEq <:> lex ts
		| i =: ['.'] = TTDot <:> lex ts
		| i =: ['\\'] = TTLambda <:> lex ts
		= TTOp i <:> lex ts
	= Left ["Unexpected: " +++ toString t +++ " ord: " +++ toString (toInt t)]
where
	isOp c = isMember c ['!@#$%^&*=+/?-_|\\\'",<>.:']

:: Parser a :== StateT ParseState (Either [String]) a
:: ParseState =
	{ tokens :: [Token]
	, ifxs   :: [((Parser Expression) -> Parser Expression, Int)]
	}

pTop :: Parser Token
pTop = getState >>= \s->case s.tokens of
	[t:ts] = put {s & tokens=ts} >>| pure t
	[] = liftT (Left ["Fully consumed input"])

pEof :: Parser ()
pEof = getState >>= \s->case s.tokens of
	[] = pure ()
	[t:ts] = liftT (Left ["Expected EOF"])

(?) infixl 9 :: (Parser a) (a -> Bool) -> Parser a
(?) p f = p >>= \v->if (f v) (pure v) empty

pToken :: (Token -> Parser Token)
pToken = (?) pTop o (===)

pChainl :: (Parser (a a -> a)) (Parser a) -> Parser a
pChainl op p = foldl (flip ($)) <$> p <*> many (flip <$> op <*> p)

pChainr :: (Parser (a a -> a)) (Parser a) -> Parser a
pChainr op p = flip ($) <$> p <*> (flip <$> op <*> pChainr op p) <|> p

parse :: [Token] -> Either [String] [Function]
parse ts = fst <$> runStateT (pAST <* pEof) {tokens=ts, ifxs=[]}
where
	pAST :: Parser [Function]
	pAST = many pFunction >>= mapM \(id, args, body)->Function id args <$
		modify (\t->{t & tokens=body}) <*> pExpression <* pEof

	pId = (\(TTIdent i)->i) <$> pTop ? (\t->t=:(TTIdent _))
	pOp = (\(TTOp i)->i) <$> pTop ? (\t->t=:(TTOp _))

	pFunction :: Parser ([Char], [[Char]], [Token])
	pFunction
		=   tuple3
		<$> (pFunId <|> pId)
		<*> many pId
		<*  pToken TTEq
		<*> many (pTop ? ((=!=)TTSemiColon))
		<*  pToken TTSemiColon
	
	pFunId :: Parser [Char]
	pFunId = pOp
		>>= \i->pChainr <$ pId ? ((==) ['ifxr']) <|> pChainl <$ pId ? ((==)['ifxl'])
		>>= \p->(\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
		>>= \s->modify (\t->{t & ifxs=[(p (App o App (Var i) <$ pOp ? ((==)i)), s):t.ifxs]})
		>>| pure i

	pExpression :: Parser Expression
	pExpression = getState >>= \{ifxs}->flip (foldr ($))
			(map fst $ sortBy (on (<) snd) ifxs)
		$   pChainl (pure App)
		$   Lambda <$ pToken TTLambda <*> pId <* pToken TTDot <*> pExpression
		<|> pToken TTBrackOpen *> pExpression <* pToken TTBrackClose
		<|> Lit o Int <$> (\(TTInt i)->i) <$> pTop ? (\t->t=:(TTInt _))
		<|> (\(TTBool i)->Lit (Bool i)) <$> pTop ? (\t->t=:(TTBool _))
		<|> Var <$> pId