implementation module parse

import StdString
import StdTuple
import StdList
from StdFunc import const, o
import Data.Either
import Data.Functor
import Data.Maybe
import Control.Monad
import Control.Applicative
import Data.Func
from Data.List import intercalate, replicate, instance Functor []
from Text import class Text(concat), instance Text String
import GenPrint

import yard
import lex

parser :: LexerOutput -> ParserOutput
parser (Left e) = Left e
parser (Right r) = fst $ runParser parseProgram r

parseProgram :: Parser Token AST
parseProgram = liftM2 AST (many parseVarDecl) (some parseFunDecl) 

parseFunDecl :: Parser Token FunDecl
parseFunDecl = liftM5 FunDecl
	(parseIdent <* satTok BraceOpenToken)
	(parseSepList CommaToken parseIdent <* satTok BraceCloseToken)
	(optional parseFunType <* satTok CBraceOpenToken)
	(many parseVarDecl)
	(many parseStmt <* satTok CBraceCloseToken)

parseStmt :: Parser Token Stmt
parseStmt = parseIfStmt <|> parseWhileStmt <|>
	parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
	(liftM FunStmt (parseSColon parseFunCall))
	where
		parseSColon :: (Parser Token a) -> Parser Token a
		parseSColon p = p <* satTok SColonToken

		parseReturnStmt :: Parser Token Stmt
		parseReturnStmt =
			satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)

		parseAssStmt :: Parser Token Stmt
		parseAssStmt = 
			liftM2 AssStmt (parseVarDef <* satTok AssignmentToken) parseExpr

		parseIfStmt :: Parser Token Stmt
		parseIfStmt = liftM3 IfStmt
            (satTok IfToken *> parseBBraces parseExpr)
            (parseBlock <|> parseOneLine)
            (liftM (fromMaybe []) 
                (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))


		parseWhileStmt :: Parser Token Stmt
		parseWhileStmt = satTok WhileToken *> 
			liftM2 WhileStmt (parseBBraces parseExpr) parseBlock

		parseBlock :: Parser Token [Stmt]
		parseBlock = parseBCBraces (many parseStmt)

		parseOneLine :: Parser Token [Stmt]
		//first pure makes singleton list from the statement
		parseOneLine = liftM pure parseStmt

parseFunType :: Parser Token FunType
parseFunType = satTok DoubleColonToken *> 
	(parseInOutType <|> (liftM (FunType []) parseVoidOrType))
	where
		parseInOutType :: Parser Token FunType
		parseInOutType = liftM2 FunType 
			(some parseType <* satTok ArrowToken) parseVoidOrType

		parseVoidOrType :: Parser Token (Maybe Type)
		parseVoidOrType = (satTok VoidToken *> pure Nothing) <|> 
			(liftM Just parseType) <|> pure Nothing

parseVarDecl :: Parser Token VarDecl
parseVarDecl = liftM3 VarDecl
	(parseType <|> trans1 VarToken VarType )
	(parseIdent <* satTok AssignmentToken)
	(parseExpr <* satTok SColonToken)

parseType :: Parser Token Type
parseType = 
	trans1 IntTypeToken IntType <|>
	trans1 CharTypeToken CharType <|>
	trans1 BoolTypeToken BoolType <|>
	(liftM ListType (parseBSqBraces parseType)) <|>
	(liftM TupleType (parseTuple parseType)) <|>
	(liftM IdType parseIdent)

parseExpr :: Parser Token Expr
parseExpr = //Operators in order of binding strength
	parseOpR (trans1 ColonToken BiCons) $
	parseOpR (trans1 PipesToken BiOr) $
	parseOpR (trans1 AmpersandsToken BiAnd) $
	parseOpR (trans1 EqualsToken BiEquals <|>
			trans1 LesserToken BiLesser <|>
			trans1 BiggerToken BiGreater <|>
			trans1 LesserEqToken BiLesserEq <|>
			trans1 GreaterEqToken BiGreaterEq <|>
			trans1 NotEqualToken BiUnEqual) $
	parseOpL (trans1 PlusToken BiPlus <|>
			trans1 DashToken BiMinus) $
	parseOpL (trans1 StarToken BiTimes <|>
			trans1 SlashToken BiDivide <|>
			trans1 PercentToken BiMod) $ parseBasicExpr
	where
		parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
		parseOpR ops prev = prev >>= \e1->optional (
				ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
			) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr e1 op e2) moe

		parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
		parseOpL ops prev = prev >>= \e1->many (
				ops >>= \op->prev >>= \e->pure (op, e)
			) >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr e op e2)) e1 moe

		parseBasicExpr :: Parser Token Expr
		parseBasicExpr = 
			(liftM TupleExpr (parseTuple parseExpr)) <|>
			(liftM FunExpr parseFunCall) <|>
			parseBBraces parseExpr <|>
			trans1 EmptyListToken EmptyListExpr <|>
			trans1 TrueToken (BoolExpr True) <|>
			trans1 FalseToken (BoolExpr False) <|>
			trans2 (NumberToken zero) (\(NumberToken i)->IntExpr i) <|>
			trans2 (CharToken zero) (\(CharToken c)->CharExpr c) <|>
			(liftM2 Op1Expr parseOp1 parseExpr) <|>
			(liftM VarExpr parseVarDef)

parseFunCall :: Parser Token FunCall
parseFunCall = liftM2 FunCall
	parseIdent (parseBBraces $ parseSepList CommaToken parseExpr)

parseVarDef :: Parser Token VarDef
parseVarDef = liftM2 VarDef
	parseIdent 
	(many (satTok DotToken *> (
		(parseIdent >>= (\i.if (i == "hd") (pure FieldHd) empty)) <|>
		(parseIdent >>= \i.if (i == "tl") (pure FieldTl) empty) <|>
		(parseIdent >>= \i.if (i == "fst") (pure FieldFst) empty) <|>
		(parseIdent >>= \i.if (i == "snd") (pure FieldSnd) empty))))

parseOp1 :: Parser Token Op1
parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation

parseBBraces :: (Parser Token a) -> Parser Token a
parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken

parseBCBraces :: (Parser Token a) -> Parser Token a
parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken

parseBSqBraces :: (Parser Token a) -> Parser Token a
parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken

parseTuple :: (Parser Token a) -> Parser Token (a, a)
parseTuple p = satTok BraceOpenToken *> 
	(liftM2 (\a->(\b->(a,b))) (p <* satTok CommaToken) p) 
	<* satTok BraceCloseToken

trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
trans2 t f = liftM (\{token}->f token) $ satTok t

trans1 :: TokenValue a -> Parser Token a
trans1 t r = trans2 t $ const r

derive gPrint TokenValue
derive gEq TokenValue
satTok :: TokenValue -> Parser Token Token
satTok t = top >>= \tok=:{line,column,token} -> if (eq t token) 
	(return tok) (fail <?> PositionalError line column ("ParseError: Unexpected token: " +++ printToString token))
	where
		eq (IdentToken _)  (IdentToken _) = True
		eq (NumberToken _) (NumberToken _) = True
		eq (CharToken _)   (CharToken _) = True
		eq x y = gEq {|*|} x y

parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
parseSepList sep p = 
	(liftM2 (\es->(\e->reverse [e:es])) (some (p <* satTok sep)) p) <|>
	(liftM pure p) <|> pure empty

parseIdent :: Parser Token String
parseIdent = trans2 (IdentToken "") (\(IdentToken e).toString e)

instance toString AST where
	toString (AST v f) = concat (
		["\n":printersperse "\n" v] ++
		["\n":printersperse "\n" f])

class print a :: a -> [String]

printersperse :: String [a] -> [String] | print a
printersperse i j = intercalate [i] (map print j)

instance print FunDecl where
	print (FunDecl i as t vs ss) =
		["\n", i, " (":printersperse "," as] ++
		[")"] ++ maybe [] (\tt->[" :: ":print tt]) t ++
		["{\n\t":printersperse "\n\t" vs] ++
		["\n":printStatements ss 1] ++ ["}\n"]

printStatements :: [Stmt] Int -> [String]
printStatements [] i = []
printStatements [s:ss] i = (case s of
	(IfStmt b thens elses) = indent i ["if (":print b] ++ [")"] ++
		printCodeBlock thens i ++ 
		indent i ["else ":printCodeBlock elses i] ++ ["\n"]
	(WhileStmt b dos) = indent i ["while (":print b] ++ 
		[")":printCodeBlock dos i]
	(AssStmt vardef val) =
		indent i $ print vardef ++ ["=":print val] ++ [";\n"]
	(FunStmt fc) = indent i $ print fc ++ [";\n"]
	(ReturnStmt me) = indent i ["return ":maybe [""] print me] ++ [";\n"]
	) ++ printStatements ss i
	where
		printCodeBlock :: [Stmt] Int -> [String]
		printCodeBlock [] _ = ["{}\n"]
		printCodeBlock [x] i = ["\n":printStatements [x] (i+1)]
		printCodeBlock x i =
			["{\n":printStatements x (i+1)] ++ indent i ["}\n"]

		indent :: Int [String] -> [String]
		indent i rest = replicate i "\t" ++ rest

instance print FunType where
	print (FunType at rt) = printersperse " " at ++
		[if (isEmpty at) "" "->":maybe ["Void"] print rt]

instance print VarDecl where
	print (VarDecl t i e) = print t ++ [" ":i:"=":print e] ++ [";"]

instance print Type where
	print (TupleType (t1, t2)) = ["(":print t1] ++ [",":print t2] ++ [")"]
	print (ListType t) = ["[":print t] ++ ["]"]
	print (IdType s) = print s
	print IntType = print "Int"
	print BoolType = print "Bool"
	print CharType = print "Char"
	print VarType = print "var"

instance print String where
	print s = [s]

instance print FieldSelector where	
	print FieldHd = print "hd"
	print FieldTl = print "tl"
	print FieldSnd = print "snd"
	print FieldFst = print "fst"

instance print VarDef where
	print (VarDef i fs) = printersperse "." [i:flatten $ map print fs]

instance print FunCall where
	print (FunCall i args) = [i,"(":printersperse "," args] ++ [")"]

instance print Expr where
	print (VarExpr vd) = print vd
	print (Op2Expr e1 o e2) = ["(":print e1] ++ [" ",case o of
		BiPlus = "+"; BiMinus = "-"; BiTimes = "*"; BiDivide = "/"
		BiMod = "%"; BiEquals = "="; BiLesser = "<"; BiGreater = ">"
		BiLesserEq = "<="; BiGreaterEq = ">="; BiUnEqual = "!=";
		BiAnd = "&&"; BiOr = "||"; BiCons = ":"
		," ":print e2] ++ [")"]
	print (Op1Expr o e) = ["(",case o of
		UnNegation = "!"; UnMinus = "-"
		:print e] ++ [")"]
	print (IntExpr i) = [toString i]
	print (CharExpr c) = ["\'", case c of
		'\b' = "\\b"; '\f' = "\\f"; '\n' = "\\n"
		'\r' = "\\r"; '\t' = "\\t"; '\v' = "\\v"
		c = if (c == toChar 7) "\\a" (toString c)
		,"\'"]
	print (BoolExpr b) = [toString b]
	print (FunExpr fc) = print fc
	print EmptyListExpr = ["[]"]
	print (TupleExpr (e1, e2)) = ["(":print e1] ++ [",":print e2] ++ [")"]