implementation module sem

import qualified Data.Map as Map
from Data.Func import $
import Data.Maybe
import Data.Either
import Data.Functor
import Control.Applicative
import Control.Monad
import Control.Monad.State
import Control.Monad.Identity
import Math.Random
import Control.Monad.Trans
import StdMisc
from StdFunc import id, const, o
import StdString
import StdTuple
import StdList
import StdBool

from Text import class Text(concat), instance Text String

import AST
from parse import :: ParserOutput, :: Error

:: Gamma :== ('Map'.Map String Type, [String])
:: Env a :== StateT Gamma (Either SemError) a
//StateT (Gamma -> Either SemError (a, Gamma))

//we need to redefine this even though it is in Control.Monad.State
instance MonadTrans (StateT Gamma) where
    liftT m = StateT \s-> m >>= \a-> return (a, s)

get = gets id

getRandomStream :: Int -> [String]
getRandomStream i = genIdents $ filter (isAlpha o toChar) (genRandInt i)
	where
		genIdents r = let (ic, r2) = splitAt 5 r in [toString ic: genIdents r2]

freshIdent :: Env String
freshIdent = get >>= \(st, [ident:rest])-> put (st, rest) 
    >>| case 'Map'.get ident st of
        Nothing = pure ident
        _       = freshIdent

putIdent :: String Type -> Env Void
putIdent i t = gets (\(st, r)->'Map'.get i st) >>= \mt -> case mt of
    Nothing = modify (\(st, r)->('Map'.put i t st, r))
    Just t2 = unify t t2 >>= \t3-> modify (\(st, r)->('Map'.put i t3 st, r))

replace :: String Type -> Env Void
replace ident type = get >>= \(st, fr)->put ('Map'.fromList $ 
        map (itupdate ident type) ('Map'.toList st), fr)
    where
        itupdate :: String Type (String, Type) -> (String, Type)
        itupdate ident newtype ov=:(key, IdType type) = if (ident == type)
            (key, newtype) ov
        itupdate ident newtype (key, TupleType (t1, t2))
        # (_, t1) = itupdate ident newtype (key, t1)
        # (_, t2) = itupdate ident newtype (key, t2)
        = (key, TupleType (t1, t2))
        itupdate ident newtype (key, ListType t1)
        # (_, t1) = itupdate ident newtype (key, t1)
        = (key, ListType t1)
        itupdate _ _ k = k

instance toString SemError where
	toString (ParseError p e) = concat [
		toString p,"SemError: ParseError: ", e]
	toString (Error e) = "SemError: " +++ e
	toString (UnifyError p t1 t2) = concat [
		toString p,
		"SemError: Cannot unify types. Expected: ",
		toString t1, ". Given: ", toString t2]
    toString (FieldSelectorError p t fs) = concat [
        toString p,
        "SemError: Cannot select ", toString fs, " from type: ",
        toString t]
	toString (OperatorError p o t) = concat [
		toString p, 
		"SemError: No ", toString o, " for type ",
		toString t]
    toString (UndeclaredVariableError p ident) = concat [
        toString p, "SemError: identifier: ", ident, " undefined."]

sem :: AST -> SemOutput
sem (AST vd fd) = case runStateT m ('Map'.newMap, getRandomStream 1) of
    Left e = Left [e]
    Right ((vds, fds), gamma) = Right ((AST vds fds), gamma)
where 
    m :: Env ([VarDecl], [FunDecl])
    m = mapM semVarDecl vd >>= \vds ->
        mapM semFunDecl fd >>= \fds -> 
        pure (vds, fds)

semFunDecl :: FunDecl -> Env FunDecl
semFunDecl fd=:(FunDecl p f args mt vds stmts) = (case mt of
    Nothing = let t = IdType f in putIdent f t >>| pure t//typeFun f args
    Just t = putIdent f t >>| pure t) >>= \ft ->
    mapM_ semVarDecl vds >>| 
    mapM_ (checkStmt $ resultType ft) stmts >>| pure fd 
    //case mt of 
//    Nothing = let t = IdType f in putIdent f t >>| pure fd
//    Just t = putIdent f t >>| pure fd

semVarDecl :: VarDecl -> Env VarDecl
semVarDecl (VarDecl pos type ident ex) = unify type ex
    >>= \t-> putIdent ident t >>| (pure $ VarDecl pos t ident ex)

checkStmt ::Type Stmt -> Env Stmt
checkStmt t (IfStmt c st se) = unify BoolType c >>| mapM (checkStmt t) st 
    >>= \st1-> mapM (checkStmt t) se >>= \se1-> pure (IfStmt c st1 se1)
checkStmt t w=:(WhileStmt c et) = unify BoolType c >>| mapM (checkStmt t) et
    >>= \et1-> pure w
checkStmt t (AssStmt (VarDef ident fs) e) = undef
checkStmt t r=:(FunStmt (FunCall f es)) = typeFun f es >>| pure r
checkStmt VoidType r=:(ReturnStmt Nothing) = pure r
checkStmt t r=:(ReturnStmt (Just e)) = unify t e >>| pure r

typeExpr :: Expr -> Env Type
typeExpr (IntExpr _ _) = pure IntType
typeExpr (CharExpr _ _) = pure CharType
typeExpr (BoolExpr _ _) = pure BoolType
typeExpr (Op1Expr p UnNegation expr) = unify BoolType expr
typeExpr (Op1Expr p UnMinus expr) = unify IntType expr
typeExpr (TupleExpr p (e1, e2)) = typeExpr e1 
    >>= \t1-> typeExpr e2 >>= \t2-> pure $ TupleType (t1, t2)
typeExpr (Op2Expr p e1 op e2)
| isMember op [BiPlus, BiMinus, BiTimes, BiDivide, BiMod] =
	typeOp2 e1 e2 op [IntType] IntType
| isMember op [BiEquals, BiUnEqual] =
	typeOp2 e1 e2 op [IntType, BoolType, CharType] BoolType
| isMember op [BiLesser, BiGreater, BiLesserEq, BiGreaterEq] =
	typeOp2 e1 e2 op [IntType, CharType] BoolType
| isMember op [BiAnd, BiOr] =
	typeOp2 e1 e2 op [BoolType] BoolType
| op == BiCons = typeExpr e1 >>= \t1-> typeExpr e2 
	>>= \t2-> unify (ListType t1) t2
typeExpr (EmptyListExpr p) = freshIdent >>= \frsh-> let t = IdType frsh in
    putIdent frsh t >>| pure t
typeExpr (FunExpr p (FunCall f es)) = typeFun f es
typeExpr (VarExpr p (VarDef ident fs)) = gets (\(st, r)->'Map'.get ident st)
    >>= \mt->case mt of
        Nothing = liftT $ Left $ UndeclaredVariableError p ident
        Just t = unify t fs

typeOp2 :: Expr Expr Op2 [Type] Type -> Env Type
typeOp2 e1 e2 op ts ret = typeExpr e1 >>= \t1-> typeExpr e2 >>= \t2->
    unify t1 t2 >>= \t3->if (isMember t3 ts) (pure ret)
        (liftT $ Left $ OperatorError (extrPos e1) op t3)

buildFunctionType :: String [Expr] -> Env Type 
buildFunctionType frsh [] = let t = IdType frsh in putIdent frsh t >>| pure t
buildFunctionType frsh [e:es] = (->>) <$> typeExpr e <*> buildFunctionType frsh es

unifyApp :: Type [Expr] -> Env Type
unifyApp t [] = pure t //whoop whoop, functions can return functions
unifyApp (tf1 ->> tf2) [t1:ts] = unify tf1 t1 >>| unifyApp tf2 ts
unifyApp t1 t2 = liftT $ Left $ UnifyError zero t1 (IdType "[expressions, FIXME]")

typeFun :: String [Expr] -> Env Type
typeFun f es = gets (\(st, r)->'Map'.get f st) >>= \mt-> case mt of
    Nothing = freshIdent >>= \frsh-> buildFunctionType frsh es 
        >>= \ft-> putIdent f ft >>| (pure $ IdType frsh)
    Just t = unifyApp t es

resultType :: Type -> Type
resultType (_ ->> t) = resultType t
resultType t = t

class unify a :: Type a -> Env Type

instance unify [FieldSelector] where
    unify t [] = pure t
    unify (ListType t) [FieldHd:fs] = unify t fs
    unify t=:(ListType _) [FieldTl:fs] = unify t fs
    unify (TupleType (t, _)) [FieldFst:fs] = unify t fs
    unify (TupleType (_, t)) [FieldSnd:fs] = unify t fs
    unify t [fs:_] = liftT $ Left $ FieldSelectorError zero t fs

instance unify Expr where
	unify (_ ->> _) e = liftT $ Left $ ParseError (extrPos e)
			"Expression cannot be a higher order function. Yet..."
	unify VoidType e = liftT $ Left $ ParseError (extrPos e)
			"Expression cannot be a Void type."
	unify (IdType _) e = liftT $ Left $ ParseError (extrPos e)
			"Expression cannot be an polymorf type."
    unify VarType e = typeExpr e
    //we have to cheat to decorate the error, can be done nicer?
    unify t e = StateT $ \s0 -> let res = runStateT m s0 in case res of
        Left err = Left $ decErr e err
        Right t = Right t //note, t :: (Type, Gamma) 
    where m = typeExpr e >>= \tex-> unify t tex 

instance unify Type where
	unify IntType IntType = pure IntType
	unify BoolType BoolType = pure BoolType
	unify CharType CharType = pure CharType
    unify (IdType i) t=:(IdType j) = replace i t >>| pure t
    unify t (IdType i) = unify (IdType i) t
    unify (IdType i) t = replace i t >>| pure t
    unify (ListType t1) (ListType t2) = unify t1 t2 >>| (pure $ ListType t1)
    unify (ta1 ->> ta2) (tb1 ->> tb2) = unify ta1 tb1 >>= \ta-> unify ta2 tb2 
        >>= \tb-> pure (ta ->> tb)
	unify t1 t2 = liftT $ Left $ UnifyError zero t1 t2

instance zero Pos where
	zero = {line=0,col=0}

decErr :: Expr SemError -> SemError
decErr e (UnifyError _ t1 t2) = UnifyError (extrPos e) t1 t2
decErr e (FieldSelectorError _ t fs) = FieldSelectorError (extrPos e) t fs
decErr e (ParseError _ s) = ParseError (extrPos e) s
decErr e err = err

dc2 :: Expr (Either SemError a) -> Either SemError a
dc2 e (Right t) = Right t
dc2 e (Left err) = Left err

extrPos :: Expr -> Pos
extrPos (VarExpr p _) = p
extrPos (Op2Expr p _ _ _) = p
extrPos (Op1Expr p _ _) = p
extrPos (IntExpr p _) = p
extrPos (CharExpr p _) = p
extrPos (BoolExpr p _) = p
extrPos (FunExpr p _) = p
extrPos (EmptyListExpr p) = p
extrPos (TupleExpr p _) = p

instance toString Gamma where
	toString (mp, _) = concat
		[concat [k, ": ", toString v, "\n"]\\(k, v) <- 'Map'.toList mp]