--- /dev/null
+" pathogen.vim - path option manipulation
+" Maintainer: Tim Pope <http://tpo.pe/>
+" Version: 2.3
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below. For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+ finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage. Give a relative path to invoke
+" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround(). For backwards compatibility purposes, a full path that
+" does not end in {} or * is given to pathogen#runtime_prepend_subdirectories()
+" instead.
+function! pathogen#infect(...) abort " {{{1
+ for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
+ if path =~# '^[^\\/]\+$'
+ call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+ call pathogen#interpose(path . '/{}')
+ elseif path =~# '^[^\\/]\+[\\/]\%({}\|\*\)$'
+ call pathogen#interpose(path)
+ elseif path =~# '[\\/]\%({}\|\*\)$'
+ call pathogen#surround(path)
+ else
+ call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+ call pathogen#surround(path . '/{}')
+ endif
+ endfor
+ call pathogen#cycle_filetype()
+ return ''
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+ if type(a:path) == type([]) | return a:path | endif
+ let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+ return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+ if type(a:1) == type(1) && a:1
+ let i = 1
+ let space = ' '
+ else
+ let i = 0
+ let space = ''
+ endif
+ let path = ""
+ while i < a:0
+ if type(a:000[i]) == type([])
+ let list = a:000[i]
+ let j = 0
+ while j < len(list)
+ let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+ let path .= ',' . escaped
+ let j += 1
+ endwhile
+ else
+ let path .= "," . a:000[i]
+ endif
+ let i += 1
+ endwhile
+ return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+ return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+ if exists('g:did_load_filetypes')
+ filetype off
+ filetype on
+ endif
+endfunction " }}}1
+
+" Check if a bundle is disabled. A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_disabled.
+function! pathogen#is_disabled(path) abort " {{{1
+ let sep = pathogen#slash()
+ let blacklist = get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', []))
+ return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction "}}}1
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory. If the directory is already included, move it to the
+" outermost position. Wildcards are added as is. Ending a path in /{} causes
+" all subdirectories to be added (except those in g:pathogen_disabled).
+function! pathogen#surround(path) abort " {{{1
+ let sep = pathogen#slash()
+ let rtp = pathogen#split(&rtp)
+ if a:path =~# '[\\/]{}$'
+ let path = fnamemodify(a:path[0:-4], ':p:s?[\\/]\=$??')
+ let before = filter(pathogen#glob_directories(path.sep.'*'), '!pathogen#is_disabled(v:val)')
+ let after = filter(reverse(pathogen#glob_directories(path.sep."*".sep."after")), '!pathogen#is_disabled(v:val[0:-7])')
+ call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+ else
+ let path = fnamemodify(a:path, ':p:s?[\\/]\=$??')
+ let before = [path]
+ let after = [path . sep . 'after']
+ call filter(rtp, 'index(before + after, v:val) == -1')
+ endif
+ let &rtp = pathogen#join(before, rtp, after)
+ return &rtp
+endfunction " }}}1
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended. If the argument ends in '/{}', add a separate entry for
+" each subdirectory.
+function! pathogen#interpose(name) abort " {{{1
+ let sep = pathogen#slash()
+ let name = a:name
+ if has_key(s:done_bundles, name)
+ return ""
+ endif
+ let s:done_bundles[name] = 1
+ let list = []
+ for dir in pathogen#split(&rtp)
+ if dir =~# '\<after$'
+ if name =~# '{}$'
+ let list += filter(pathogen#glob_directories(substitute(dir,'after$',name[0:-3],'').'*'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+ else
+ let list += [dir, substitute(dir, 'after$', '', '') . name . sep . 'after']
+ endif
+ else
+ if name =~# '{}$'
+ let list += [dir] + filter(pathogen#glob_directories(dir.sep.name[0:-3].'*'), '!pathogen#is_disabled(v:val)')
+ else
+ let list += [dir . sep . name, dir]
+ endif
+ endif
+ endfor
+ let &rtp = pathogen#join(pathogen#uniq(list))
+ return 1
+endfunction
+
+let s:done_bundles = {}
+
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort " {{{1
+ let sep = pathogen#slash()
+ for glob in pathogen#split(&rtp)
+ for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+ if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+ silent! execute 'helptags' pathogen#fnameescape(dir)
+ endif
+ endfor
+ endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command. This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort " {{{1
+ for command in a:000
+ execute command
+ endfor
+ return ''
+endfunction " }}}1
+
+" Section: Unofficial
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort " {{{1
+ return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+function! pathogen#separator() abort " {{{1
+ return pathogen#slash()
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+ let files = split(glob(a:pattern),"\n")
+ return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+ return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+ let i = 0
+ let seen = {}
+ while i < len(a:list)
+ if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+ call remove(a:list,i)
+ elseif a:list[i] ==# ''
+ let i += 1
+ let empty = 1
+ else
+ let seen[a:list[i]] = 1
+ let i += 1
+ endif
+ endwhile
+ return a:list
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort " {{{1
+ if exists('*fnameescape')
+ return fnameescape(a:string)
+ elseif a:string ==# '-'
+ return '\-'
+ else
+ return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+ endif
+endfunction " }}}1
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort "{{{1
+ let rtp = pathogen#join(1,pathogen#split(&rtp))
+ let file = findfile(a:file,rtp,a:count)
+ if file ==# ''
+ return ''
+ else
+ return fnamemodify(file,':p')
+ endif
+endfunction " }}}1
+
+" Section: Deprecated
+
+function! s:warn(msg)
+ echohl WarningMsg
+ echomsg a:msg
+ echohl NONE
+endfunction
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories. Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+ call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
+ return pathogen#surround(a:path . pathogen#slash() . '{}')
+endfunction " }}}1
+
+function! pathogen#incubate(...) abort " {{{1
+ let name = a:0 ? a:1 : 'bundle/{}'
+ call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
+ return pathogen#interpose(name)
+endfunction " }}}1
+
+" Deprecated alias for pathogen#interpose().
+function! pathogen#runtime_append_all_bundles(...) abort " {{{1
+ if a:0
+ call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
+ else
+ call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
+ endif
+ return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
+endfunction " }}}1
+
+if exists(':Vedit')
+ finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd) " {{{1
+ let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+ let file = pathogen#runtime_findfile(a:file,a:count)
+ if file ==# ''
+ return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+ endif
+ if !s:vopen_warning
+ let s:vopen_warning = 1
+ let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+ else
+ let warning = ''
+ endif
+ if a:lcd
+ let path = file[0:-strlen(a:file)-2]
+ execute 'lcd `=path`'
+ return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+ else
+ return a:cmd.' '.pathogen#fnameescape(file) . warning
+ endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+ let sep = pathogen#slash()
+ let cheats = {
+ \'a': 'autoload',
+ \'d': 'doc',
+ \'f': 'ftplugin',
+ \'i': 'indent',
+ \'p': 'plugin',
+ \'s': 'syntax'}
+ if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+ let request = cheats[a:A[0]].a:A[1:-1]
+ else
+ let request = a:A
+ endif
+ let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+ let found = {}
+ for path in pathogen#split(&runtimepath)
+ let path = expand(path, ':p')
+ let matches = split(glob(path.sep.pattern),"\n")
+ call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+ call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+ for match in matches
+ let found[match] = 1
+ endfor
+ endfor
+ return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2:
--- /dev/null
+" Vim syntax file\r
+" Filename: praat.vim\r
+" Language: Praat - doing phonetics by computer (www.praat.org)\r
+" Maintainer: Pablo Arantes - parantes(at)fastmail(dot)fm\r
+" Last Change: 2006 Feb 17\r
+"\r
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""\r
+\r
+syntax clear\r
+syntax case match\r
+\r
+" Arguments to form (Manual, section 6.1)\r
+\r
+syntax keyword praatType boolean button choice comment integer\r
+syntax keyword praatType natural option optionmenu positive\r
+syntax keyword praattype real sentence word text\r
+\r
+" Loops and conditionals\r
+\r
+syntax keyword praatConditional if else elsif elif endif fi\r
+syntax keyword praatRepeat for from to endfor repeat until while endwhile\r
+\r
+" Statements\r
+\r
+syntax keyword praatStatement call clearinfo echo execute pause nowarn \r
+syntax keyword praatStatement plus minus printline printtab Remove\r
+syntax keyword praatStatement select yes all filedelete fileappend\r
+\r
+" Compound statements (like Read from file...)\r
+\r
+syntax match praatDottedStat "[A-Z]\{1\}[A-Za-z \-]*\.\{3\}"\r
+syntax match praatCompStat "\W*\*s[A-Z]\{1\}[A-Za-z \-]*$"\r
+\r
+" Environments\r
+\r
+syntax keyword praatEnvironment editor endeditor procedure endproc\r
+syntax keyword praatEnvironment form endform \r
+\r
+" Mathematical Functions (Praat Manual, Formulas, section 4)\r
+\r
+syntax keyword praatFunction abs arccos arcosh arcsin arcsinh arctan\r
+syntax keyword praatFunction arctan2 arctanh barkToHertz binomialP\r
+syntax keyword praatFunction ceiling chiSquareP chiSquareQ cos cosh\r
+syntax keyword praatFunction differenceLimensToPhon erb erbToHertz\r
+syntax keyword praatFunction erf erfc exp fisherP fisherQ floor\r
+syntax keyword praatFunction gaussP gaussQ hertzToBark hertzToErb\r
+syntax keyword praatFunction hertzToMel hertzToSemitones imax imin\r
+syntax keyword praatFunction invBinomialP invBinomialQ invChiSquareQ\r
+syntax keyword praatFunction invFisherQ invGaussQ invStudentQ ln\r
+syntax keyword praatFunction lnGamma log10 log2 max melToHertz min\r
+syntax keyword praatFunction phonToDifferenceLimens randomGauss\r
+syntax keyword praatFunction randomInteger randomPoisson randomUniform\r
+syntax keyword praatFunction round semitonesToHertz sigmoid sin sinh\r
+syntax keyword praatFunction sort sqrt stundentP studentQ tan tanh nSelected\r
+\r
+" Constants (Praat Manual, Formulas, section 3)\r
+\r
+syntax keyword praatConstant pi e undefined\r
+\r
+" String Functions (Praat Manual, Formulas, section 5)\r
+\r
+syntax keyword praatStrFunc contained left$ right$ mid$ \r
+syntax keyword praatStrFunc contained fixed$ date$ tab$ \r
+syntax keyword praatStrFunc contained extractWord$ newline$ \r
+syntax keyword praatStrFunc contained extractLine$ percent$ \r
+syntax keyword praatStrSpec colength index rindex startsWith\r
+syntax keyword praatStrSpec coendsWith extractNumber\r
+\r
+" Attributes of objects (Praat Manual, Formulas, section 7)\r
+\r
+syntax keyword praatAttribute xmin xmax ncol nrow nx dx ymin ymax ny dy\r
+\r
+" Types of objects (Praat Manual, Types of objects section)\r
+\r
+syntax keyword praatObject ArtWord BarkFilter CC Cepstrum Cochleagram\r
+syntax keyword praatObject DurationTier Excitation Formant FormantTier\r
+syntax keyword praatObject FormantFilter Harmonicity Intensity \r
+syntax keyword praatObject IntensityTier LFCC LPC LongSound Ltas MFCC\r
+syntax keyword praatObject Manipulation Matrix MelFilter ParamCurve\r
+syntax keyword praatObject Pitch PitchTier PointProcess Polygon Sequence\r
+syntax keyword praatObject Sequence Sound Speaker Spectrogram Spectrum\r
+syntax keyword praatObject SpellingChecker Strings TableOfReal TextGrid\r
+syntax keyword praatObject TextTier Wavelet WordList Table\r
+\r
+" String variables\r
+\r
+syntax match praatStrVar "\l\w*\$" contains=praatStrFunc\r
+\r
+" String Assignment\r
+syntax region praatString start=+"+ skip=+\\+ end=+"+\r
+syntax region praatString start=+'+ skip=+\\+ end=+'+\r
+\r
+" Delimiters\r
+\r
+syntax match praatDelim "[{}()\\]"\r
+syntax match praatDelim "[][]"\r
+\r
+" Operators (Praat Manual, Formulas section 2)\r
+\r
+" syntax keyword praatOperator div mod not\r
+syntax keyword praatOperator = / * ^ > <\r
+\r
+" Numbers\r
+\r
+syntax match praatNumber "\d"\r
+\r
+" Comments\r
+syntax match praatComment "#.*$"\r
+syntax match praatComment "!.*$"\r
+syntax match praatComment ";.*$"\r
+\r
+" Define the default highlighting\r
+" For version 5.7 and earlier: only when not done already\r
+" For version 5.8 and later: only when an item doesn't have\r
+" highlighting yet\r
+\r
+if version >= 508 || !exists("did_praat_syn_inits")\r
+ if version < 508\r
+ let did_praat_syn_inits = 1\r
+ command -nargs=+ HiLink hi link <args>\r
+ else\r
+ command -nargs=+ HiLink hi def <args>\r
+ endif\r
+\r
+highlight link praatType Type\r
+highlight link praatConditional Conditional\r
+highlight link praatRepeat Repeat\r
+highlight link praatStatement Statement\r
+highlight link praatEnvironment Repeat \r
+highlight link praatFunction Function\r
+highlight link praatConstant Constant\r
+highlight link praatStrFunc Function\r
+highlight link praatStrSpec Function\r
+highlight link praatAttribute Statement\r
+highlight link praatObject Type\r
+highlight link praatString String\r
+highlight link praatStrVar Identifier\r
+highlight link praatDelim Delimiter\r
+highlight link praatComment Comment\r
+highlight link praatNumber Number\r
+highlight link praatDottedStat Statement\r
+highlight link praatCompStat Statement\r
+highlight link praatOperator Type\r
+ delcommand HiLink\r
+endif\r
+\r
+let b:current_syntax = "praat"\r
repositories / dotfiles.git / commitdiff