From: Mart Lubbers <mart.lubbers@mpi.nl>
Date: Thu, 17 Jul 2014 07:32:10 +0000 (+0200)
Subject: added .vim
X-Git-Url: https://git.martlubbers.net/?a=commitdiff_plain;h=86dbf26a559c9eecc7aa534ecbe757cc77e5e1d0;p=dotfiles.git

added .vim
---

diff --git a/.vim/.VimballRecord b/.vim/.VimballRecord
new file mode 100644
index 0000000..3a7ab8f
--- /dev/null
+++ b/.vim/.VimballRecord
@@ -0,0 +1 @@
+Vim-R-plugin.vmb: call delete('/home/marlub/.vim/autoload/rcomplete.vim')|call delete('/home/marlub/.vim/doc/r-plugin.txt')|call delete('/home/marlub/.vim/ftdetect/r.vim')|call delete('/home/marlub/.vim/ftplugin/r.vim')|call delete('/home/marlub/.vim/ftplugin/rbrowser.vim')|call delete('/home/marlub/.vim/ftplugin/rdoc.vim')|call delete('/home/marlub/.vim/ftplugin/rhelp.vim')|call delete('/home/marlub/.vim/ftplugin/rmd.vim')|call delete('/home/marlub/.vim/ftplugin/rnoweb.vim')|call delete('/home/marlub/.vim/ftplugin/rrst.vim')|call delete('/home/marlub/.vim/indent/r.vim')|call delete('/home/marlub/.vim/indent/rhelp.vim')|call delete('/home/marlub/.vim/indent/rmd.vim')|call delete('/home/marlub/.vim/indent/rnoweb.vim')|call delete('/home/marlub/.vim/indent/rrst.vim')|call delete('/home/marlub/.vim/r-plugin/common_buffer.vim')|call delete('/home/marlub/.vim/r-plugin/common_global.vim')|call delete('/home/marlub/.vim/r-plugin/global_r_plugin.vim')|call delete('/home/marlub/.vim/r-plugin/objlist/README')|call delete('/home/marlub/.vim/r-plugin/r.snippets')|call delete('/home/marlub/.vim/r-plugin/tex_indent.vim')|call delete('/home/marlub/.vim/r-plugin/vimcom.py')|call delete('/home/marlub/.vim/r-plugin/vimrconfig.vim')|call delete('/home/marlub/.vim/r-plugin/windows.py')|call delete('/home/marlub/.vim/syntax/r.vim')|call delete('/home/marlub/.vim/syntax/rbrowser.vim')|call delete('/home/marlub/.vim/syntax/rdoc.vim')|call delete('/home/marlub/.vim/syntax/rhelp.vim')|call delete('/home/marlub/.vim/syntax/rmd.vim')|call delete('/home/marlub/.vim/syntax/rout.vim')|call delete('/home/marlub/.vim/syntax/rrst.vim')
diff --git a/.vim/.netrwhist b/.vim/.netrwhist
new file mode 100644
index 0000000..d4be927
--- /dev/null
+++ b/.vim/.netrwhist
@@ -0,0 +1,7 @@
+let g:netrw_dirhistmax  =10
+let g:netrw_dirhist_cnt =5
+let g:netrw_dirhist_1='/home/mart/.mutt'
+let g:netrw_dirhist_2='/home/marlub/Documents/scripts/pralign'
+let g:netrw_dirhist_3='/home/marlub/.ssh'
+let g:netrw_dirhist_4='/home/marlub/documents'
+let g:netrw_dirhist_5='/home/marlub/documents/dutch/corpus'
diff --git a/.vim/autoload/pathogen.vim b/.vim/autoload/pathogen.vim
new file mode 100644
index 0000000..a3a8f1d
--- /dev/null
+++ b/.vim/autoload/pathogen.vim
@@ -0,0 +1,332 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.3
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.  For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  For backwards compatibility purposes, a full path that
+" does not end in {} or * is given to pathogen#runtime_prepend_subdirectories()
+" instead.
+function! pathogen#infect(...) abort " {{{1
+  for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
+    if path =~# '^[^\\/]\+$'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#interpose(path . '/{}')
+    elseif path =~# '^[^\\/]\+[\\/]\%({}\|\*\)$'
+      call pathogen#interpose(path)
+    elseif path =~# '[\\/]\%({}\|\*\)$'
+      call pathogen#surround(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  return ''
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+  if type(a:path) == type([]) | return a:path | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+  return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction " }}}1
+
+" Check if a bundle is disabled.  A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_disabled.
+function! pathogen#is_disabled(path) abort " {{{1
+  let sep = pathogen#slash()
+  let blacklist = get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', []))
+  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction "}}}1
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  If the directory is already included, move it to the
+" outermost position.  Wildcards are added as is.  Ending a path in /{} causes
+" all subdirectories to be added (except those in g:pathogen_disabled).
+function! pathogen#surround(path) abort " {{{1
+  let sep = pathogen#slash()
+  let rtp = pathogen#split(&rtp)
+  if a:path =~# '[\\/]{}$'
+    let path = fnamemodify(a:path[0:-4], ':p:s?[\\/]\=$??')
+    let before = filter(pathogen#glob_directories(path.sep.'*'), '!pathogen#is_disabled(v:val)')
+    let after  = filter(reverse(pathogen#glob_directories(path.sep."*".sep."after")), '!pathogen#is_disabled(v:val[0:-7])')
+    call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+  else
+    let path = fnamemodify(a:path, ':p:s?[\\/]\=$??')
+    let before = [path]
+    let after = [path . sep . 'after']
+    call filter(rtp, 'index(before + after, v:val) == -1')
+  endif
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction " }}}1
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  If the argument ends in '/{}', add a separate entry for
+" each subdirectory.
+function! pathogen#interpose(name) abort " {{{1
+  let sep = pathogen#slash()
+  let name = a:name
+  if has_key(s:done_bundles, name)
+    return ""
+  endif
+  let s:done_bundles[name] = 1
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      if name =~# '{}$'
+        let list +=  filter(pathogen#glob_directories(substitute(dir,'after$',name[0:-3],'').'*'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+      else
+        let list += [dir, substitute(dir, 'after$', '', '') . name . sep . 'after']
+      endif
+    else
+      if name =~# '{}$'
+        let list +=  [dir] + filter(pathogen#glob_directories(dir.sep.name[0:-3].'*'), '!pathogen#is_disabled(v:val)')
+      else
+        let list += [dir . sep . name, dir]
+      endif
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = {}
+
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort " {{{1
+  let sep = pathogen#slash()
+  for glob in pathogen#split(&rtp)
+    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+        silent! execute 'helptags' pathogen#fnameescape(dir)
+      endif
+    endfor
+  endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort " {{{1
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction " }}}1
+
+" Section: Unofficial
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort " {{{1
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+function! pathogen#separator() abort " {{{1
+  return pathogen#slash()
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort " {{{1
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction " }}}1
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort "{{{1
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction " }}}1
+
+" Section: Deprecated
+
+function! s:warn(msg)
+  echohl WarningMsg
+  echomsg a:msg
+  echohl NONE
+endfunction
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#slash() . '{}')
+endfunction " }}}1
+
+function! pathogen#incubate(...) abort " {{{1
+  let name = a:0 ? a:1 : 'bundle/{}'
+  call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
+  return pathogen#interpose(name)
+endfunction " }}}1
+
+" Deprecated alias for pathogen#interpose().
+function! pathogen#runtime_append_all_bundles(...) abort " {{{1
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
+  endif
+  return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
+endfunction " }}}1
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd) " {{{1
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+  let sep = pathogen#slash()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2:
diff --git a/.vim/bundle/nerdtree b/.vim/bundle/nerdtree
new file mode 160000
index 0000000..b0bb781
--- /dev/null
+++ b/.vim/bundle/nerdtree
@@ -0,0 +1 @@
+Subproject commit b0bb781fc73ef40365e4c996a16f04368d64fc9d
diff --git a/.vim/bundle/tlib_vim b/.vim/bundle/tlib_vim
new file mode 160000
index 0000000..8e5bf4d
--- /dev/null
+++ b/.vim/bundle/tlib_vim
@@ -0,0 +1 @@
+Subproject commit 8e5bf4d9d445565b4fc88ef700635d6210f4c69c
diff --git a/.vim/bundle/vim-addon-mw-utils b/.vim/bundle/vim-addon-mw-utils
new file mode 160000
index 0000000..0c5612f
--- /dev/null
+++ b/.vim/bundle/vim-addon-mw-utils
@@ -0,0 +1 @@
+Subproject commit 0c5612fa31ee434ba055e21c76f456244b3b5109
diff --git a/.vim/bundle/vim-flake8 b/.vim/bundle/vim-flake8
new file mode 160000
index 0000000..8a573a9
--- /dev/null
+++ b/.vim/bundle/vim-flake8
@@ -0,0 +1 @@
+Subproject commit 8a573a9806eacf000b03b4bbf37aff4ce06d73a6
diff --git a/.vim/bundle/vim-snipmate b/.vim/bundle/vim-snipmate
new file mode 160000
index 0000000..9e2ea92
--- /dev/null
+++ b/.vim/bundle/vim-snipmate
@@ -0,0 +1 @@
+Subproject commit 9e2ea920ad5055fec5237f1273c44b03fdf6f5e8
diff --git a/.vim/colors/256-grayvim.vim b/.vim/colors/256-grayvim.vim
new file mode 100644
index 0000000..fc81da0
--- /dev/null
+++ b/.vim/colors/256-grayvim.vim
@@ -0,0 +1,46 @@
+" Vim color file
+" Maintainer:	Piotr Husiatyński <phusiatynski@gmail.com>
+
+set background=dark
+set t_Co=256
+let g:colors_name="256-grayvim"
+
+let python_highlight_all = 1
+let c_gnu = 1
+
+
+hi Normal	    ctermfg=253         ctermbg=235        cterm=None
+hi Cursor       ctermfg=Red         ctermbg=None       cterm=None
+hi SpecialKey	ctermfg=87          ctermbg=None       cterm=Bold
+hi Directory	ctermfg=76          ctermbg=None       cterm=None
+hi ErrorMsg     ctermfg=124         ctermbg=White      cterm=None
+hi PreProc	    ctermfg=246         ctermbg=None       cterm=Bold
+hi Search	    ctermfg=160         ctermbg=232        cterm=Bold
+hi Type		    ctermfg=75          ctermbg=None       cterm=Bold
+hi Statement	ctermfg=75          ctermbg=None       cterm=None
+hi Comment	    ctermfg=244         ctermbg=None       cterm=None
+hi Identifier	ctermfg=111         ctermbg=None       cterm=Bold
+hi DiffText	    ctermfg=88          ctermbg=250        cterm=None
+hi Constant	    ctermfg=208         ctermbg=None       cterm=None
+hi Todo         ctermfg=233         ctermbg=118        cterm=Bold
+hi Error	    ctermfg=233         ctermbg=124        cterm=Bold
+hi Special	    ctermfg=160         ctermbg=None       cterm=Bold
+hi Ignore       ctermfg=220         ctermbg=None       cterm=Bold
+hi Underline    ctermfg=244         ctermbg=None       cterm=None
+
+hi FoldColumn	ctermfg=247         ctermbg=None       cterm=Bold
+hi StatusLineNC ctermfg=247         ctermbg=234        cterm=None
+hi StatusLine   ctermfg=247         ctermbg=233        cterm=Bold
+hi VertSplit    ctermfg=247         ctermbg=234        cterm=Bold
+
+hi LineNr	    ctermfg=238         ctermbg=244        cterm=Bold
+hi LineNr	    ctermfg=247         ctermbg=235        cterm=Bold
+hi NonText	    ctermfg=87          ctermbg=None       cterm=Bold
+
+
+hi Pmenu        ctermfg=White       ctermbg=DarkGray    cterm=None
+hi PmenuSel     ctermfg=None        ctermbg=Gray        cterm=Bold
+hi PmenuSbar    ctermfg=DarkGray    ctermbg=DarkGray    cterm=None
+hi PmenuThumb   ctermfg=Gray        ctermbg=Gray        cterm=None
+
+"vim: sw=4
diff --git a/.vim/colors/; b/.vim/colors/;
new file mode 100644
index 0000000..576b1c9
--- /dev/null
+++ b/.vim/colors/;
@@ -0,0 +1,57 @@
+execute pathogen#infect()
+filetype indent plugin on
+syntax enable
+set t_Co=256
+color 256-grayvim
+hi Normal ctermbg=NONE
+
+set encoding=utf-8
+set history=1000
+set number
+set ruler
+set backspace=eol,start,indent
+set whichwrap+=<,>,h,l
+set incsearch
+set noerrorbells
+set novisualbell
+set nobackup
+set nowb
+set noswapfile
+set shiftwidth=2
+set tabstop=2
+set foldmethod=indent
+set foldnestmax=2
+set nofoldenable
+set cc=80
+set textwidth=79
+set list
+set listchars=tab:.\ ,eol:¬,trail:_,precedes:<,extends:>
+
+" Source the vimrc while editing
+autocmd! bufwritepost .vimrc source %
+
+" Tab Mappings
+map <TAB>l <C-W>l
+map <TAB>h <C-W>h
+map <TAB>j <C-W>j
+map <TAB>k <C-W>k
+
+" Search results stay in middle of screen
+nnoremap n nzzzv
+nnoremap N Nzzzv
+
+" Unmap the arrow keys!!!
+for prefix in ['i', 'n', 'v']
+	for key in ['<Up>', '<Down>', '<Left>', '<Right>']
+		exe prefix . "noremap " . key . " <Nop>"
+	endfor
+endfor
+
+" Load all the skeletons for newfiles
+for i in split(globpath('~/.vim/skel/', './*'), '\n')
+	let extension = split(i, "/")[-1]
+	exe "au BufNewFile *." . extension . " 0r ~/.vim/skel/" . extension
+endfor
+
+let mapleader="'"
+map <leader>n :NERDTreeToggle<CR>
diff --git a/.vim/ftplugin/Example-Exam_SE_2013.pdf b/.vim/ftplugin/Example-Exam_SE_2013.pdf
new file mode 100644
index 0000000..09791c3
Binary files /dev/null and b/.vim/ftplugin/Example-Exam_SE_2013.pdf differ
diff --git a/.vim/ftplugin/praat.vim b/.vim/ftplugin/praat.vim
new file mode 100644
index 0000000..f807feb
--- /dev/null
+++ b/.vim/ftplugin/praat.vim
@@ -0,0 +1,147 @@
+" Vim syntax file
+" Filename: praat.vim
+" Language: Praat - doing phonetics by computer (www.praat.org)
+" Maintainer: Pablo Arantes - parantes(at)fastmail(dot)fm
+" Last Change: 2006 Feb 17
+"
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+
+syntax clear
+syntax case match
+
+" Arguments to form (Manual, section 6.1)
+
+syntax keyword praatType boolean button choice comment integer
+syntax keyword praatType natural option optionmenu positive
+syntax keyword praattype real sentence word text
+
+" Loops and conditionals
+
+syntax keyword praatConditional if else elsif elif endif fi
+syntax keyword praatRepeat for from to endfor repeat until while endwhile
+
+" Statements
+
+syntax keyword praatStatement call clearinfo echo execute pause nowarn 
+syntax keyword praatStatement plus minus printline printtab Remove
+syntax keyword praatStatement select yes all filedelete fileappend
+
+" Compound statements (like Read from file...)
+
+syntax match praatDottedStat "[A-Z]\{1\}[A-Za-z \-]*\.\{3\}"
+syntax match praatCompStat "\W*\*s[A-Z]\{1\}[A-Za-z \-]*$"
+
+" Environments
+
+syntax keyword praatEnvironment editor endeditor procedure endproc
+syntax keyword praatEnvironment form endform 
+
+" Mathematical Functions (Praat Manual, Formulas, section 4)
+
+syntax keyword praatFunction abs arccos arcosh arcsin arcsinh arctan
+syntax keyword praatFunction arctan2 arctanh barkToHertz binomialP
+syntax keyword praatFunction ceiling chiSquareP chiSquareQ cos cosh
+syntax keyword praatFunction differenceLimensToPhon erb erbToHertz
+syntax keyword praatFunction erf erfc exp fisherP fisherQ floor
+syntax keyword praatFunction gaussP gaussQ hertzToBark hertzToErb
+syntax keyword praatFunction hertzToMel hertzToSemitones imax imin
+syntax keyword praatFunction invBinomialP invBinomialQ invChiSquareQ
+syntax keyword praatFunction invFisherQ invGaussQ invStudentQ ln
+syntax keyword praatFunction lnGamma log10 log2 max melToHertz min
+syntax keyword praatFunction phonToDifferenceLimens randomGauss
+syntax keyword praatFunction randomInteger randomPoisson randomUniform
+syntax keyword praatFunction round semitonesToHertz sigmoid sin sinh
+syntax keyword praatFunction sort sqrt stundentP studentQ tan tanh nSelected
+
+" Constants (Praat Manual, Formulas, section 3)
+
+syntax keyword praatConstant pi e undefined
+
+" String Functions (Praat Manual, Formulas, section 5)
+
+syntax keyword praatStrFunc contained left$ right$ mid$ 
+syntax keyword praatStrFunc contained fixed$ date$ tab$ 
+syntax keyword praatStrFunc contained extractWord$ newline$ 
+syntax keyword praatStrFunc contained extractLine$ percent$ 
+syntax keyword praatStrSpec colength index rindex startsWith
+syntax keyword praatStrSpec coendsWith extractNumber
+
+" Attributes of objects (Praat Manual, Formulas, section 7)
+
+syntax keyword praatAttribute xmin xmax ncol nrow nx dx ymin ymax ny dy
+
+" Types of objects (Praat Manual, Types of objects section)
+
+syntax keyword praatObject ArtWord BarkFilter CC Cepstrum Cochleagram
+syntax keyword praatObject DurationTier Excitation Formant FormantTier
+syntax keyword praatObject FormantFilter Harmonicity Intensity 
+syntax keyword praatObject IntensityTier LFCC LPC LongSound Ltas MFCC
+syntax keyword praatObject Manipulation Matrix MelFilter ParamCurve
+syntax keyword praatObject Pitch PitchTier PointProcess Polygon Sequence
+syntax keyword praatObject Sequence Sound Speaker Spectrogram Spectrum
+syntax keyword praatObject SpellingChecker Strings TableOfReal TextGrid
+syntax keyword praatObject TextTier Wavelet WordList Table
+
+" String variables
+
+syntax match praatStrVar "\l\w*\$" contains=praatStrFunc
+
+" String Assignment
+syntax region praatString start=+"+ skip=+\\+  end=+"+
+syntax region praatString start=+'+ skip=+\\+  end=+'+
+
+" Delimiters
+
+syntax match praatDelim "[{}()\\]"
+syntax match praatDelim "[][]"
+
+" Operators (Praat Manual, Formulas section 2)
+
+" syntax keyword praatOperator div mod not
+syntax keyword praatOperator = / * ^ > <
+
+" Numbers
+
+syntax match praatNumber "\d"
+
+" Comments
+syntax match praatComment "#.*$"
+syntax match praatComment "!.*$"
+syntax match praatComment ";.*$"
+
+" Define the default highlighting
+" For version 5.7 and earlier: only when not done already
+" For version 5.8 and later: only when an item doesn't have
+"  highlighting yet
+
+if version >= 508 || !exists("did_praat_syn_inits")
+	if version < 508
+		let did_praat_syn_inits = 1
+		command -nargs=+ HiLink hi link <args>
+	else
+		command -nargs=+ HiLink hi def <args>
+	endif
+
+highlight link praatType Type
+highlight link praatConditional Conditional
+highlight link praatRepeat Repeat
+highlight link praatStatement Statement
+highlight link praatEnvironment Repeat 
+highlight link praatFunction Function
+highlight link praatConstant Constant
+highlight link praatStrFunc Function
+highlight link praatStrSpec Function
+highlight link praatAttribute Statement
+highlight link praatObject Type
+highlight link praatString String
+highlight link praatStrVar Identifier
+highlight link praatDelim Delimiter
+highlight link praatComment Comment
+highlight link praatNumber Number
+highlight link praatDottedStat Statement
+highlight link praatCompStat Statement
+highlight link praatOperator Type
+	delcommand HiLink
+endif
+
+let b:current_syntax = "praat"
diff --git a/.vim/ftplugin/python.vim b/.vim/ftplugin/python.vim
new file mode 100644
index 0000000..0668ebe
--- /dev/null
+++ b/.vim/ftplugin/python.vim
@@ -0,0 +1,5 @@
+autocmd BufWritePost *.py call Flake8()
+set tabstop=8
+set expandtab
+set shiftwidth=4
+set softtabstop=4
diff --git a/.vim/skel/py b/.vim/skel/py
new file mode 100644
index 0000000..89f1db4
--- /dev/null
+++ b/.vim/skel/py
@@ -0,0 +1,2 @@
+#!/bin/env python
+# -*- coding: utf-8 -*-
diff --git a/.vim/skel/tex b/.vim/skel/tex
new file mode 100644
index 0000000..671c902
--- /dev/null
+++ b/.vim/skel/tex
@@ -0,0 +1,9 @@
+\documentclass{article}
+
+\author{Mart Lubbers}
+\title{
+\date{\today}
+
+\begin{document}
+
+\end{document}
diff --git a/.vim/snippets/java.snippets b/.vim/snippets/java.snippets
new file mode 100644
index 0000000..1a2c492
--- /dev/null
+++ b/.vim/snippets/java.snippets
@@ -0,0 +1,30 @@
+#Import etc
+snippet im
+	import
+
+#Modifiers
+snippet pu
+	public
+snippet po
+	protected
+snippet pr
+	private
+snippet st
+	static
+snippet fi
+	final
+snippet ab
+	abstract
+snippet sy
+	synchronized
+
+#Functions
+snippet main
+	public static void main (String [] args)
+	{
+		${1:/* code */}
+	}
+
+#Javadoc
+snippet syso
+	System.out.println(${1:text})
diff --git a/.vim/snippets/python.snippets b/.vim/snippets/python.snippets
new file mode 100644
index 0000000..c5b8ff4
--- /dev/null
+++ b/.vim/snippets/python.snippets
@@ -0,0 +1,6 @@
+snippet imp
+	import ${1:module}
+
+snippet ifmain
+	if __name__ == '__main__':
+		${1:main()}
diff --git a/.vim/snippets/snippet.snippets b/.vim/snippets/snippet.snippets
new file mode 100644
index 0000000..854c058
--- /dev/null
+++ b/.vim/snippets/snippet.snippets
@@ -0,0 +1,7 @@
+# snippets for making snippets :)
+snippet snip
+	snippet ${1:trigger}
+		${2}
+snippet msnip
+	snippet ${1:trigger} ${2:description}
+		${3}
diff --git a/.vim/snippets/tex.snippets b/.vim/snippets/tex.snippets
new file mode 100644
index 0000000..cbbba47
--- /dev/null
+++ b/.vim/snippets/tex.snippets
@@ -0,0 +1,16 @@
+snippet block
+	\begin{block}{${1}}
+		${2}
+	\end{block}
+
+snippet frame
+	\begin{frame}
+		\frametitle{${1}}
+		${2}
+	\end{frame}
+
+snippet fframe
+	\begin{frame}[fragile]
+		\frametitle{${1}}
+		${2}
+	\end{frame}
diff --git a/install.sh b/install.sh
index 691cfaa..479bf9a 100644
--- a/install.sh
+++ b/install.sh
@@ -1,6 +1,11 @@
 #!/bin/bash
 
 cp -v .Xresources .vimrc .bashrc .gitconfig ~/
-mkdir -p ~/.i3 ~/.mutt
+
+mkdir -p ~/.i3 ~/.mutt ~/.vim
+
 cp -v .i3/* ~/.i3/
+
 cp -v .mutt/* ~/.mutt/
+
+cp -vR .vim/* ~/.vim/