cloogleirc.icl

   1 module cloogleirc
   2
   3 import Cloogle
   4 import GenPrint
   5 import StdEnv
   6
   7 import Data.Functor
   8 import Data.Maybe
   9 import Data.Either
  10 from Data.Func import $, mapSt
  11 from Text import class Text(..), instance Text String, instance + String
  12
  13 import Internet.HTTP
  14
  15 import Text.JSON
  16
  17 import Text.URI
  18 import System.Time
  19
  20 import Control.Applicative
  21 import qualified Control.Monad as CM
  22 import qualified Data.Map as DM
  23 from Control.Monad import class Monad, instance Monad Maybe, >>=
  24 from Text.Encodings.UrlEncoding import urlEncode
  25 import System.CommandLine
  26 import Internet.HTTP
  27 import Data.Error
  28 import Data.List
  29 import Data.Functor
  30 import Data.Tuple
  31
  32 import TCPIP
  33 import IRC
  34 import IRCBot
  35
  36 import StdMisc, StdDebug
  37
  38 shorten :: String *World -> (String, *World)
  39 shorten s w
  40 # s = if (startsWith "http://" s) s (if (startsWith "https://" s) s ("http://" + s))
  41 # data = "type=regular&url="+urlEncode s+"&token=a"
  42 # (mer, w) = doHTTPRequest
  43                 { newHTTPRequest
  44                 & req_method = HTTP_POST
  45                 , req_path = "/"
  46                 , server_name = "cloo.gl"
  47                 , server_port = 80
  48                 , req_headers = 'DM'.fromList
  49                         [("Content-Type", "application/x-www-form-urlencoded")
  50                         ,("Content-Length", toString $ size data)
  51                         ,("Accept", "*/*")]
  52                 , req_data = data} 10000 w
  53 | isError mer = ("request failed: " + fromError mer, w)
  54 # resp = fromOk mer
  55 = (resp.rsp_data, w)
  56
  57 cloogle :: String *World -> (String, *World)
  58 cloogle data w
  59 # (mer, w) = doHTTPRequestFollowRedirects
  60                 { newHTTPRequest
  61                 & req_path = "/api.php"
  62                 , req_query = "?str=" + urlEncode data
  63                 , req_headers = 'DM'.fromList [("User-Agent", "cloogle-irc")]
  64                 , server_name = "cloogle.org"
  65                 , server_port = 80} 10000 10 w
  66 | isError mer = ("request failed: " + fromError mer, w)
  67 # resp = fromOk mer
  68 = case fromJSON $ fromString resp.HTTPResponse.rsp_data of
  69         Nothing = ("couldn't parse json", w)
  70         Just {return=127} = ("No results for " + data, w)
  71         Just clr = ("Results for " + data + " -- https://cloogle.org/#" +
  72                 replaceSubString "+" "%20" (urlEncode data) + "\n" +
  73                 processResults clr, w)
  74         where
  75                 processResults :: Response -> String
  76                 processResults resp
  77                 | resp.return > 127 = "Failed: return code: " + toString resp.return + ", " + resp.msg
  78                 = join "\n" $ map processResult $ take 3 resp.data
  79
  80                 processResult :: Result -> String
  81                 processResult (FunctionResult (br, {func}))
  82                         = "Function in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ func
  83                 processResult (TypeResult (br, {type}))
  84                         = "Type in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ limitResults type
  85                 processResult (ClassResult (br, {class_name,class_funs}))
  86                         = "Class in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ class_name +++ " with "
  87                                 +++ toString (length class_funs) +++ " class functions"
  88                 processResult (ModuleResult (br, _))
  89                         = "Module in " +++ br.library +++ ": " +++ br.modul
  90
  91                 limitResults :: String -> String
  92                 limitResults s
  93                 # lines = split "\n" s
  94                 | length lines > 4 = limitResults (join "\n" (take 3 lines) + "\n...")
  95                 = join "\n" (map maxWidth lines)
  96
  97                 maxWidth :: String -> String
  98                 maxWidth s = if (size s > 80) (subString 0 77 s + "...") s
  99
 100 :: BotSettings =
 101                 { bs_nick     :: String
 102                 , bs_nickserv :: Maybe String
 103                 , bs_autojoin :: [String]
 104                 , bs_port     :: Int
 105                 , bs_server   :: String
 106                 , bs_strftime :: String
 107                 }
 108
 109 Start :: *World -> (Maybe String, *World)
 110 Start w
 111 # ([cmd:args], w) = getCommandLine w
 112 # (io, w) = stdio w
 113 # bs = parseCLI cmd args
 114 | isError bs
 115         # io = io <<< fromError bs <<< "\n"
 116         = (Nothing, snd $ fclose io w)
 117 # (Ok bs) = bs
 118 # (merr, io, w) = bot (bs.bs_server, bs.bs_port) (startup bs) shutdown io (process bs.bs_strftime) w
 119 = (merr, snd $ fclose io w)
 120         where
 121                 parseCLI :: String [String] -> MaybeErrorString BotSettings
 122                 parseCLI _ [] = Ok
 123                         { bs_nick     = "clooglebot"
 124                         , bs_nickserv = Nothing
 125                         , bs_autojoin = []
 126                         , bs_port     = 6667
 127                         , bs_server   = "irc.freenode.net"
 128                         , bs_strftime = "%s"
 129                         }
 130                 parseCLI cmd [a:as]
 131                 | a == "-f" || a == "--strftime"
 132                         = arg1 "--strftime" as \a c->{c & bs_strftime=a}
 133                 | a == "-n" || a == "--nick"
 134                         = arg1 "--nick" as \a c->{c & bs_nick=a}
 135                 | a == "-ns" || a == "--nickserv"
 136                         = arg1 "--nickserv" as \a c->{c & bs_nickserv=Just a}
 137                 | a == "-a" || a == "--autojoin"
 138                         = arg1 "--autojoin" as \a c->{c & bs_autojoin=c.bs_autojoin ++ [a]}
 139                 | a == "-p" || a == "--port"
 140                         = arg1 "--port" as \a c->{c & bs_port=toInt a}
 141                 | a == "-s" || a == "--server"
 142                         = arg1 "--server" as \a c->{c & bs_server=a}
 143                 | a == "-h" || a == "--help" = Error $ join "\n" $
 144                         [ "Usage: " + cmd + " [OPTS]"
 145                         , "Options:"
 146                         , "\t--strftime/-f FORMAT   strftime format used in the output. default: %s\n"
 147                         , "\t--nick/-n NICKNAME     Use the given nickname instead of clooglebot"
 148                         , "\t--nickserv/-ns PW      Identify via the given password with NickServ"
 149                         , "\t--port/-p PORT         Use the given port instead of port 6667"
 150                         , "\t--server/-s SERVER     Use the given server instead of irc.freenode.net"
 151                         , "\t--autojoin/-a CHANNEL  Add CHANNEL to the autojoin list. This command "
 152                         , "\t                       can be called multiple times. Beware that #"
 153                         , "\t                       has to be escaped in most shells"
 154                         ]
 155                 = Error $ "Unknown option: " +++ a
 156                 where
 157                         arg1 name [] _ = Error $ name +++ " requires an argument"
 158                         arg1 name [a:as] f = parseCLI cmd as >>= Ok o f a
 159
 160                 nickserv pw = PRIVMSG (CSepList ["NickServ"]) $ "IDENTIFY " +++ pw
 161
 162                 toPrefix c = {irc_prefix=Nothing,irc_command=Right c}
 163
 164                 startup bs = map toPrefix $
 165                         [   NICK bs.bs_nick Nothing
 166                         ,   USER "cloogle" "cloogle" "cloogle" "Cloogle bot"
 167                         ]++ maybe [] (pure o nickserv) bs.bs_nickserv
 168                          ++ if (isEmpty bs.bs_autojoin) []
 169                                 [JOIN (CSepList bs.bs_autojoin) Nothing]
 170                 shutdown = map toPrefix [QUIT $ Just "Bye"]
 171
 172                 process :: String !IRCMessage *File !*World -> (Maybe [IRCMessage], *File, !*World)
 173                 process strf im io w
 174                 #! (io, w) = log strf " (r): " im (io, w)
 175                 = case im.irc_command of
 176                         Left numr = (Just [], io, w)
 177                         Right cmd = case process` im.irc_prefix cmd w of
 178                                 (Nothing, w) = (Nothing, io, w)
 179                                 (Just cs, w)
 180                                 # msgs = map toPrefix cs
 181                                 #! (io, w) = foldr (log strf " (s): ") (io, w) msgs
 182                                 = (Just msgs, io, w)
 183
 184                 log :: String String IRCMessage (!*File, !*World) -> (!*File, !*World)
 185                 log strf pref m (io, w)
 186                 #! (t, w) = localTime w
 187                 = (io <<< strfTime strf t <<< pref <<< toString m <<< "\n", w)
 188
 189                 process` :: (Maybe (Either IRCUser String)) IRCCommand *World -> (Maybe [IRCCommand], *World)
 190                 process` (Just (Left user)) (PRIVMSG t m) w
 191                         | m == "!restart" = (Nothing, w)
 192                         | m.[0] == '!'
 193                                 # (msgs, w) = realProcess (split " " $ m % (1, size m)) w
 194                                 = (Just $ map reply msgs, w)
 195                         | m % (0,4) == "\001PING" = (Just [reply m], w)
 196                         = (Just [], w)
 197                 where
 198                         reply = case (\(CSepList [t:_]) -> t.[0]) t of
 199                                 '#' -> PRIVMSG t
 200                                 _   -> NOTICE user.irc_nick
 201                 process` _ (PING t mt) w = (Just [PONG t mt], w)
 202                 process` _ _ w = (Just [], w)
 203
 204                 realProcess :: [String] *World -> ([String], *World)
 205                 realProcess ["help",x:xs] w = ((case x of
 206                         "help" =
 207                                 [ "Usage: !help [ARG]"
 208                                 , "Show this help, or the specific help of the argument"]
 209                         "ping" =
 210                                 [ "Usage: !ping [ARG [ARG ...]]"
 211                                 , "Ping the bot, it will pong the arguments back"]
 212                         "shorten" =
 213                                 [ "Usage: !shorten URL [URL [URL ...]]"
 214                                 , "Shorten the given urls with the cloo.gl url shortener"]
 215                         "query" =
 216                                 [ "Usage: !query QUERY"
 217                                 , "Query QUERY in cloogle and return the results"]
 218                         "restart" =
 219                                 [ "Usage: !restart"
 220                                 , "Restart the bot"]
 221                         x = ["Unknown command: " +++ x]
 222                         ), w)
 223                 realProcess ["help"] w = (
 224                         ["Type !help cmd for command specific help"
 225                         ,"available commands: help, ping, shorten, query, restart"], w)
 226                 realProcess ["ping":xs] w = (["pong " +++ join " " xs], w)
 227                 realProcess ["shorten":xs] w = case xs of
 228                         [] = (["shorten requires at least one argument"], w)
 229                         xs = mapSt shorten xs w
 230                 realProcess ["query":xs] w = case xs of
 231                         [] = (["query requires one or more arguments"], w)
 232                         xs = appFst (split "\n") $ cloogle (join " " xs) w
 233                 realProcess ["restart":_] w = (["restart takes no arguments"], w)
 234                 realProcess [c:_] w = ([join " " [
 235                         "Unknown cmd: ", c, ",  type !help to get help"]], w)