cloogleirc.icl

   1 module cloogleirc
   2
   3 import Cloogle
   4 import Text.GenPrint
   5 import StdEnv
   6
   7 import Data.Functor
   8 import Data.Maybe
   9 import Data.Either
  10 from Data.Func import $, mapSt
  11 from Text import class Text(..), instance Text String, instance + String
  12
  13 import Internet.HTTP
  14
  15 import Text.GenJSON
  16
  17 import Text.URI
  18 import System.Time
  19
  20 import Control.Applicative
  21 import qualified Control.Monad as CM
  22 import qualified Data.Map as DM
  23 from Control.Monad import class Monad(bind), >>=
  24 from Text.Encodings.UrlEncoding import urlEncode
  25 import System.CommandLine
  26 import Internet.HTTP
  27 import Data.Error
  28 import Data.List
  29 import Data.Functor
  30 import Data.Tuple
  31
  32 import TCPIP
  33 import IRC
  34 import IRCBot
  35
  36 import StdMisc, StdDebug
  37
  38 shorten :: String *World -> (String, *World)
  39 shorten s w
  40 # s = if (startsWith "http://" s) s (if (startsWith "https://" s) s ("http://" + s))
  41 # data = "type=regular&url="+urlEncode s+"&token=a"
  42 # (mer, w) = doHTTPRequest
  43                 { newHTTPRequest
  44                 & req_method = HTTP_POST
  45                 , req_path = "/"
  46                 , server_name = "cloo.gl"
  47                 , server_port = 80
  48                 , req_headers = 'DM'.fromList
  49                         [("Content-Type", "application/x-www-form-urlencoded")
  50                         ,("Content-Length", toString $ size data)
  51                         ,("Accept", "*/*")]
  52                 , req_data = data} 10000 w
  53 | isError mer = ("request failed: " + fromError mer, w)
  54 # resp = fromOk mer
  55 = (resp.rsp_data, w)
  56
  57 cloogle :: String *World -> (String, *World)
  58 cloogle data w
  59 # (mer, w) = doHTTPRequestFollowRedirects
  60                 { newHTTPRequest
  61                 & req_path = "/api.php"
  62                 , req_query = "?str=" + urlEncode data
  63                 , req_headers = 'DM'.fromList [("User-Agent", "cloogle-irc")]
  64                 , server_name = "cloogle.org"
  65                 , server_port = 80} 10000 10 w
  66 | isError mer = ("request failed: " + fromError mer, w)
  67 # resp = fromOk mer
  68 = case fromJSON $ fromString resp.HTTPResponse.rsp_data of
  69         Nothing = ("couldn't parse json", w)
  70         Just {return=127} = ("No results for " + data, w)
  71         Just clr = ("Results for " + data + " -- https://cloogle.org/#" +
  72                 replaceSubString "+" "%20" (urlEncode data) + "\n" +
  73                 processResults clr, w)
  74         where
  75                 processResults :: Response -> String
  76                 processResults resp
  77                 | resp.return > 127 = "Failed: return code: " + toString resp.return + ", " + resp.msg
  78                 = join "\n" $ map processResult $ take 3 resp.data
  79
  80                 processResult :: Result -> String
  81                 processResult (FunctionResult (br, {func}))
  82                         = "Function in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ func
  83                 processResult (TypeResult (br, {type}))
  84                         = "Type in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ limitResults type
  85                 processResult (ClassResult (br, {class_name,class_funs}))
  86                         = "Class in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ class_name +++ " with "
  87                                 +++ toString (length class_funs) +++ " class functions"
  88                 processResult (ModuleResult (br, _))
  89                         = "Module in " +++ br.library +++ ": " +++ br.modul
  90                 processResult (SyntaxResult (br, re))
  91                         = "Clean syntax: " +++ re.syntax_title +++ "\n"
  92                                 +++ concat (intersperse "; " re.syntax_code)
  93
  94                 limitResults :: String -> String
  95                 limitResults s
  96                 # lines = split "\n" s
  97                 | length lines > 4 = limitResults (join "\n" (take 3 lines) + "\n...")
  98                 = join "\n" (map maxWidth lines)
  99
 100                 maxWidth :: String -> String
 101                 maxWidth s = if (size s > 80) (subString 0 77 s + "...") s
 102
 103 :: BotSettings =
 104                 { bs_nick     :: String
 105                 , bs_nickserv :: Maybe String
 106                 , bs_autojoin :: [String]
 107                 , bs_port     :: Int
 108                 , bs_server   :: String
 109                 , bs_strftime :: String
 110                 }
 111
 112 Start :: *World -> (Maybe String, *World)
 113 Start w
 114 # ([cmd:args], w) = getCommandLine w
 115 # (io, w) = stdio w
 116 # bs = parseCLI cmd args
 117 | isError bs
 118         # io = io <<< fromError bs <<< "\n"
 119         = (Nothing, snd $ fclose io w)
 120 # (Ok bs) = bs
 121 # (_, w) = fclose io w
 122 # (merr, _, w) = bot (bs.bs_server, bs.bs_port) (startup bs) shutdown () (process bs.bs_strftime) w
 123 = (merr, w)
 124         where
 125                 parseCLI :: String [String] -> MaybeErrorString BotSettings
 126                 parseCLI _ [] = Ok
 127                         { bs_nick     = "clooglebot"
 128                         , bs_nickserv = Nothing
 129                         , bs_autojoin = []
 130                         , bs_port     = 6667
 131                         , bs_server   = "irc.freenode.net"
 132                         , bs_strftime = "%s"
 133                         }
 134                 parseCLI cmd [a:as]
 135                 | a == "-f" || a == "--strftime"
 136                         = arg1 "--strftime" as \a c->{c & bs_strftime=a}
 137                 | a == "-n" || a == "--nick"
 138                         = arg1 "--nick" as \a c->{c & bs_nick=a}
 139                 | a == "-ns" || a == "--nickserv"
 140                         = arg1 "--nickserv" as \a c->{c & bs_nickserv=Just a}
 141                 | a == "-a" || a == "--autojoin"
 142                         = arg1 "--autojoin" as \a c->{c & bs_autojoin=c.bs_autojoin ++ [a]}
 143                 | a == "-p" || a == "--port"
 144                         = arg1 "--port" as \a c->{c & bs_port=toInt a}
 145                 | a == "-s" || a == "--server"
 146                         = arg1 "--server" as \a c->{c & bs_server=a}
 147                 | a == "-h" || a == "--help" = Error $ join "\n" $
 148                         [ "Usage: " + cmd + " [OPTS]"
 149                         , "Options:"
 150                         , "\t--strftime/-f FORMAT   strftime format used in the output. default: %s\n"
 151                         , "\t--nick/-n NICKNAME     Use the given nickname instead of clooglebot"
 152                         , "\t--nickserv/-ns PW      Identify via the given password with NickServ"
 153                         , "\t--port/-p PORT         Use the given port instead of port 6667"
 154                         , "\t--server/-s SERVER     Use the given server instead of irc.freenode.net"
 155                         , "\t--autojoin/-a CHANNEL  Add CHANNEL to the autojoin list. This command "
 156                         , "\t                       can be called multiple times. Beware that #"
 157                         , "\t                       has to be escaped in most shells"
 158                         ]
 159                 = Error $ "Unknown option: " +++ a
 160                 where
 161                         arg1 name [] _ = Error $ name +++ " requires an argument"
 162                         arg1 name [a:as] f = parseCLI cmd as >>= Ok o f a
 163
 164                 nickserv pw = PRIVMSG (CSepList ["NickServ"]) $ "IDENTIFY " +++ pw
 165
 166                 toPrefix c = {irc_prefix=Nothing,irc_command=Right c}
 167
 168                 startup bs = map toPrefix $
 169                         [   NICK bs.bs_nick Nothing
 170                         ,   USER "cloogle" "cloogle" "cloogle" "Cloogle bot"
 171                         ]++ maybe [] (pure o nickserv) bs.bs_nickserv
 172                          ++ if (isEmpty bs.bs_autojoin) []
 173                                 [JOIN (CSepList bs.bs_autojoin) Nothing]
 174                 shutdown = map toPrefix [QUIT $ Just "Bye"]
 175
 176                 process :: String !IRCMessage () !*World -> (Maybe [IRCMessage], (), !*World)
 177                 process strf im _ w
 178                 # (io ,w) = stdio w
 179                 # (io, w) = log strf " (r): " im (io, w)
 180                 # (_, w) = fclose io w
 181                 = case im.irc_command of
 182                         Left numr = (Just [], (), w)
 183                         Right cmd = case process` im.irc_prefix cmd w of
 184                                 (Nothing, w) = (Nothing, (), w)
 185                                 (Just cs, w)
 186                                 # msgs = map toPrefix cs
 187                                 = (Just msgs, (), w)
 188
 189                 log :: String String IRCMessage (!*File, !*World) -> (!*File, !*World)
 190                 log strf pref m (io, w)
 191                 #! (t, w) = localTime w
 192                 = (io <<< strfTime strf t <<< pref <<< toString m <<< "\n", w)
 193
 194                 process` :: (Maybe (Either IRCUser String)) IRCCommand *World -> (Maybe [IRCCommand], *World)
 195                 process` (Just (Left user)) (PRIVMSG t m) w
 196                         | m == "!restart" = (Nothing, w)
 197                         | m.[0] == '!'
 198                                 # (msgs, w) = realProcess (split " " $ m % (1, size m)) w
 199                                 = (Just $ map reply msgs, w)
 200                         | m % (0,4) == "\001PING" = (Just [reply m], w)
 201                         = (Just [], w)
 202                 where
 203                         reply = case (\(CSepList [t:_]) -> t.[0]) t of
 204                                 '#' -> PRIVMSG t
 205                                 _   -> NOTICE user.irc_nick
 206                 process` _ (PING t mt) w = (Just [PONG t mt], w)
 207                 process` _ _ w = (Just [], w)
 208
 209                 realProcess :: [String] *World -> ([String], *World)
 210                 realProcess ["help",x:xs] w = ((case x of
 211                         "help" =
 212                                 [ "Usage: !help [ARG]"
 213                                 , "Show this help, or the specific help of the argument"]
 214                         "ping" =
 215                                 [ "Usage: !ping [ARG [ARG ...]]"
 216                                 , "Ping the bot, it will pong the arguments back"]
 217                         "shorten" =
 218                                 [ "Usage: !shorten URL [URL [URL ...]]"
 219                                 , "Shorten the given urls with the cloo.gl url shortener"]
 220                         "query" =
 221                                 [ "Usage: !query QUERY"
 222                                 , "Query QUERY in cloogle and return the results"]
 223                         "restart" =
 224                                 [ "Usage: !restart"
 225                                 , "Restart the bot"]
 226                         x = ["Unknown command: " +++ x]
 227                         ), w)
 228                 realProcess ["help"] w = (
 229                         ["Type !help cmd for command specific help"
 230                         ,"available commands: help, ping, shorten, query, restart"], w)
 231                 realProcess ["ping":xs] w = (["pong " +++ join " " xs], w)
 232                 realProcess ["shorten":xs] w = case xs of
 233                         [] = (["shorten requires at least one argument"], w)
 234                         xs = mapSt shorten xs w
 235                 realProcess ["query":xs] w = case xs of
 236                         [] = (["query requires one or more arguments"], w)
 237                         xs = appFst (split "\n") $ cloogle (join " " xs) w
 238                 realProcess ["restart":_] w = (["restart takes no arguments"], w)
 239                 realProcess [c:_] w = ([join " " [
 240                         "Unknown cmd: ", c, ",  type !help to get help"]], w)