cloogleirc.icl

   1 module cloogleirc
   2
   3 import Cloogle
   4 import GenPrint
   5 import StdEnv
   6
   7 import Data.Functor
   8 import Data.Maybe
   9 import Data.Either
  10 from Data.Func import $, mapSt
  11 from Text import class Text(..), instance Text String, instance + String
  12
  13 import Internet.HTTP
  14
  15 import Text.JSON
  16
  17 import Text.URI
  18 import System.Time
  19
  20 import Control.Applicative
  21 import qualified Control.Monad as CM
  22 import qualified Data.Map as DM
  23 from Control.Monad import class Monad, instance Monad Maybe, >>=
  24 from Text.Encodings.UrlEncoding import urlEncode
  25 import System.CommandLine
  26 import Internet.HTTP
  27 import Data.Error
  28 import Data.List
  29 import Data.Functor
  30 import Data.Tuple
  31
  32 import TCPIP
  33 import IRC
  34 import IRCBot
  35
  36 import StdMisc, StdDebug
  37
  38 shorten :: String *World -> (String, *World)
  39 shorten s w
  40 # s = if (startsWith "http://" s) s (if (startsWith "https://" s) s ("http://" + s))
  41 # data = "type=regular&url="+urlEncode s+"&token=a"
  42 # (mer, w) = doHTTPRequest
  43                 { newHTTPRequest
  44                 & req_method = HTTP_POST
  45                 , req_path = "/"
  46                 , server_name = "cloo.gl"
  47                 , server_port = 80
  48                 , req_headers = 'DM'.fromList
  49                         [("Content-Type", "application/x-www-form-urlencoded")
  50                         ,("Content-Length", toString $ size data)
  51                         ,("Accept", "*/*")]
  52                 , req_data = data} 10000 w
  53 | isError mer = ("request failed: " + fromError mer, w)
  54 # resp = fromOk mer
  55 = (resp.rsp_data, w)
  56
  57 cloogle :: String *World -> (String, *World)
  58 cloogle data w
  59 # (mer, w) = doHTTPRequestFollowRedirects
  60                 { newHTTPRequest
  61                 & req_path = "/api.php"
  62                 , req_query = "?str=" + urlEncode data
  63                 , req_headers = 'DM'.fromList [("User-Agent", "cloogle-irc")]
  64                 , server_name = "cloogle.org"
  65                 , server_port = 80} 10000 10 w
  66 | isError mer = ("request failed: " + fromError mer, w)
  67 # resp = fromOk mer
  68 = case fromJSON $ fromString resp.HTTPResponse.rsp_data of
  69         Nothing = ("couldn't parse json", w)
  70         Just {return=127} = ("No results for " + data, w)
  71         Just clr = ("Results for " + data + " -- https://cloogle.org/#" +
  72                 replaceSubString "+" "%20" (urlEncode data) + "\n" +
  73                 processResults clr, w)
  74         where
  75                 processResults :: Response -> String
  76                 processResults resp
  77                 | resp.return > 127 = "Failed: return code: " + toString resp.return + ", " + resp.msg
  78                 = join "\n" $ map processResult $ take 3 resp.data
  79
  80                 processResult :: Result -> String
  81                 processResult (FunctionResult (br, {func}))
  82                         = "Function in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ func
  83                 processResult (TypeResult (br, {type}))
  84                         = "Type in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ limitResults type
  85                 processResult (ClassResult (br, {class_name,class_funs}))
  86                         = "Class in " +++ br.library +++ ": " +++ br.modul +++ "\n" +++ class_name +++ " with "
  87                                 +++ toString (length class_funs) +++ " class functions"
  88                 processResult (ModuleResult (br, _))
  89                         = "Module in " +++ br.library +++ ": " +++ br.modul
  90                 processResult (SyntaxResult (br, re))
  91                         = "Clean syntax: " +++ re.syntax_title +++ "\n"
  92                                 +++ concat (intersperse "; " re.syntax_code)
  93
  94                 limitResults :: String -> String
  95                 limitResults s
  96                 # lines = split "\n" s
  97                 | length lines > 4 = limitResults (join "\n" (take 3 lines) + "\n...")
  98                 = join "\n" (map maxWidth lines)
  99
 100                 maxWidth :: String -> String
 101                 maxWidth s = if (size s > 80) (subString 0 77 s + "...") s
 102
 103 :: BotSettings =
 104                 { bs_nick     :: String
 105                 , bs_nickserv :: Maybe String
 106                 , bs_autojoin :: [String]
 107                 , bs_port     :: Int
 108                 , bs_server   :: String
 109                 , bs_strftime :: String
 110                 }
 111
 112 Start :: *World -> (Maybe String, *World)
 113 Start w
 114 # ([cmd:args], w) = getCommandLine w
 115 # (io, w) = stdio w
 116 # bs = parseCLI cmd args
 117 | isError bs
 118         # io = io <<< fromError bs <<< "\n"
 119         = (Nothing, snd $ fclose io w)
 120 # (Ok bs) = bs
 121 # (merr, io, w) = bot (bs.bs_server, bs.bs_port) (startup bs) shutdown io (process bs.bs_strftime) w
 122 = (merr, snd $ fclose io w)
 123         where
 124                 parseCLI :: String [String] -> MaybeErrorString BotSettings
 125                 parseCLI _ [] = Ok
 126                         { bs_nick     = "clooglebot"
 127                         , bs_nickserv = Nothing
 128                         , bs_autojoin = []
 129                         , bs_port     = 6667
 130                         , bs_server   = "irc.freenode.net"
 131                         , bs_strftime = "%s"
 132                         }
 133                 parseCLI cmd [a:as]
 134                 | a == "-f" || a == "--strftime"
 135                         = arg1 "--strftime" as \a c->{c & bs_strftime=a}
 136                 | a == "-n" || a == "--nick"
 137                         = arg1 "--nick" as \a c->{c & bs_nick=a}
 138                 | a == "-ns" || a == "--nickserv"
 139                         = arg1 "--nickserv" as \a c->{c & bs_nickserv=Just a}
 140                 | a == "-a" || a == "--autojoin"
 141                         = arg1 "--autojoin" as \a c->{c & bs_autojoin=c.bs_autojoin ++ [a]}
 142                 | a == "-p" || a == "--port"
 143                         = arg1 "--port" as \a c->{c & bs_port=toInt a}
 144                 | a == "-s" || a == "--server"
 145                         = arg1 "--server" as \a c->{c & bs_server=a}
 146                 | a == "-h" || a == "--help" = Error $ join "\n" $
 147                         [ "Usage: " + cmd + " [OPTS]"
 148                         , "Options:"
 149                         , "\t--strftime/-f FORMAT   strftime format used in the output. default: %s\n"
 150                         , "\t--nick/-n NICKNAME     Use the given nickname instead of clooglebot"
 151                         , "\t--nickserv/-ns PW      Identify via the given password with NickServ"
 152                         , "\t--port/-p PORT         Use the given port instead of port 6667"
 153                         , "\t--server/-s SERVER     Use the given server instead of irc.freenode.net"
 154                         , "\t--autojoin/-a CHANNEL  Add CHANNEL to the autojoin list. This command "
 155                         , "\t                       can be called multiple times. Beware that #"
 156                         , "\t                       has to be escaped in most shells"
 157                         ]
 158                 = Error $ "Unknown option: " +++ a
 159                 where
 160                         arg1 name [] _ = Error $ name +++ " requires an argument"
 161                         arg1 name [a:as] f = parseCLI cmd as >>= Ok o f a
 162
 163                 nickserv pw = PRIVMSG (CSepList ["NickServ"]) $ "IDENTIFY " +++ pw
 164
 165                 toPrefix c = {irc_prefix=Nothing,irc_command=Right c}
 166
 167                 startup bs = map toPrefix $
 168                         [   NICK bs.bs_nick Nothing
 169                         ,   USER "cloogle" "cloogle" "cloogle" "Cloogle bot"
 170                         ]++ maybe [] (pure o nickserv) bs.bs_nickserv
 171                          ++ if (isEmpty bs.bs_autojoin) []
 172                                 [JOIN (CSepList bs.bs_autojoin) Nothing]
 173                 shutdown = map toPrefix [QUIT $ Just "Bye"]
 174
 175                 process :: String !IRCMessage *File !*World -> (Maybe [IRCMessage], *File, !*World)
 176                 process strf im io w
 177                 #! (io, w) = log strf " (r): " im (io, w)
 178                 = case im.irc_command of
 179                         Left numr = (Just [], io, w)
 180                         Right cmd = case process` im.irc_prefix cmd w of
 181                                 (Nothing, w) = (Nothing, io, w)
 182                                 (Just cs, w)
 183                                 # msgs = map toPrefix cs
 184                                 #! (io, w) = foldr (log strf " (s): ") (io, w) msgs
 185                                 = (Just msgs, io, w)
 186
 187                 log :: String String IRCMessage (!*File, !*World) -> (!*File, !*World)
 188                 log strf pref m (io, w)
 189                 #! (t, w) = localTime w
 190                 = (io <<< strfTime strf t <<< pref <<< toString m <<< "\n", w)
 191
 192                 process` :: (Maybe (Either IRCUser String)) IRCCommand *World -> (Maybe [IRCCommand], *World)
 193                 process` (Just (Left user)) (PRIVMSG t m) w
 194                         | m == "!restart" = (Nothing, w)
 195                         | m.[0] == '!'
 196                                 # (msgs, w) = realProcess (split " " $ m % (1, size m)) w
 197                                 = (Just $ map reply msgs, w)
 198                         | m % (0,4) == "\001PING" = (Just [reply m], w)
 199                         = (Just [], w)
 200                 where
 201                         reply = case (\(CSepList [t:_]) -> t.[0]) t of
 202                                 '#' -> PRIVMSG t
 203                                 _   -> NOTICE user.irc_nick
 204                 process` _ (PING t mt) w = (Just [PONG t mt], w)
 205                 process` _ _ w = (Just [], w)
 206
 207                 realProcess :: [String] *World -> ([String], *World)
 208                 realProcess ["help",x:xs] w = ((case x of
 209                         "help" =
 210                                 [ "Usage: !help [ARG]"
 211                                 , "Show this help, or the specific help of the argument"]
 212                         "ping" =
 213                                 [ "Usage: !ping [ARG [ARG ...]]"
 214                                 , "Ping the bot, it will pong the arguments back"]
 215                         "shorten" =
 216                                 [ "Usage: !shorten URL [URL [URL ...]]"
 217                                 , "Shorten the given urls with the cloo.gl url shortener"]
 218                         "query" =
 219                                 [ "Usage: !query QUERY"
 220                                 , "Query QUERY in cloogle and return the results"]
 221                         "restart" =
 222                                 [ "Usage: !restart"
 223                                 , "Restart the bot"]
 224                         x = ["Unknown command: " +++ x]
 225                         ), w)
 226                 realProcess ["help"] w = (
 227                         ["Type !help cmd for command specific help"
 228                         ,"available commands: help, ping, shorten, query, restart"], w)
 229                 realProcess ["ping":xs] w = (["pong " +++ join " " xs], w)
 230                 realProcess ["shorten":xs] w = case xs of
 231                         [] = (["shorten requires at least one argument"], w)
 232                         xs = mapSt shorten xs w
 233                 realProcess ["query":xs] w = case xs of
 234                         [] = (["query requires one or more arguments"], w)
 235                         xs = appFst (split "\n") $ cloogle (join " " xs) w
 236                 realProcess ["restart":_] w = (["restart takes no arguments"], w)
 237                 realProcess [c:_] w = ([join " " [
 238                         "Unknown cmd: ", c, ",  type !help to get help"]], w)