dsl/xtend/src/robots/missions/generator/TaskDSLGenerator.xtend

   1 /*
   2  * generated by Xtext
   3  */
   4 package robots.missions.generator
   5
   6 import org.eclipse.emf.common.util.EList
   7 import org.eclipse.emf.ecore.resource.Resource
   8 import org.eclipse.xtext.generator.IFileSystemAccess
   9 import org.eclipse.xtext.generator.IGenerator
  10 import robots.missions.taskDSL.Behaviour
  11 import robots.missions.taskDSL.Mission
  12 import robots.missions.taskDSL.OperatorE
  13 import robots.missions.taskDSL.StoppingExpression
  14 import robots.missions.taskDSL.Robot
  15
  16 /**
  17  * Generates code from your model files on save.
  18  *
  19  * See https://www.eclipse.org/Xtext/documentation/303_runtime_concepts.html#code-generation
  20  */
  21 class TaskDSLGenerator implements IGenerator {
  22
  23         override void doGenerate(Resource resource, IFileSystemAccess fsa) {
  24                 var root = resource.allContents.head as Robot;
  25                 if(root != null){
  26                         fsa.generateFile("nl/ru/des/Constants.java", makeConstants(root));
  27                         for(Behaviour b : root.behaviour){
  28                                 fsa.generateFile("nl/ru/des/" + b.name + "Behaviour.java", makeBehaviour(b));
  29                         }
  30                         fsa.generateFile("nl/ru/des/Missions.java", makeMissions(root.mission));
  31                 }
  32         }
  33
  34         def CharSequence makeMissions(EList<Mission> mission)'''
  35 package nl.ru.des;
  36
  37 import java.util.LinkedList;
  38
  39 import lejos.robotics.subsumption.Behavior;
  40 import lejos.robotics.RegulatedMotor;
  41 import lejos.robotics.Color;
  42
  43 import nl.ru.des.sensors.SensorCollector;
  44
  45 public class Missions{
  46         public static LinkedList<Mission> getMissions(final SensorCollector sensors, RegulatedMotor rightMotor,
  47                         RegulatedMotor leftMotor, RegulatedMotor measMotor){
  48                 LinkedList<Mission> missions = new LinkedList<Mission>();
  49                 «FOR m : mission SEPARATOR "));" AFTER "));"»
  50                 missions.add(new Mission("«m.name»", new Behavior[]{
  51                         «FOR b : m.behaviours SEPARATOR "," AFTER ","»new «b.name»Behaviour(sensors, rightMotor, leftMotor, measMotor)
  52                         «ENDFOR»
  53                         new ShutdownBehaviour(){
  54                                 @Override public boolean takeControl(){
  55                                         return «printExpression(m.se)»;
  56                                 }
  57                         }}
  58                 «ENDFOR»
  59                 return missions;
  60         }
  61 }
  62 '''
  63
  64         def CharSequence makeBehaviour(Behaviour b)'''
  65 package nl.ru.des;
  66
  67 import lejos.robotics.RegulatedMotor;
  68 import lejos.robotics.Color;
  69 import nl.ru.des.sensors.SensorCollector;
  70
  71 public class «b.name»Behaviour extends BasicBehaviour {
  72         public «b.name»Behaviour(SensorCollector sensors, RegulatedMotor rightMotor,
  73                         RegulatedMotor leftMotor,  RegulatedMotor measMotor){
  74                 super(sensors, rightMotor, leftMotor, measMotor);
  75         }
  76         «IF b.tc != null»
  77         @Override public boolean takeControl(){
  78                 return «printExpression(b.tc)»;
  79         }
  80         «ENDIF»
  81
  82         @Override public void action(){
  83                 System.out.println("Start: «b.name»");
  84                 super.action();
  85                 «FOR a : b.actions»
  86                         «IF a.whichMotor != null»
  87                                 «IF a.acc > 0»
  88                                 «a.whichMotor.d.toString()»Motor.setAcceleration(«a.acc»);
  89                                 «a.whichMotor.d.toString()»Motor.setSpeed(«a.spd»);
  90                                 «ENDIF»
  91                                 «a.whichMotor.d.toString()»Motor.«a.moveDir.d.toString()»();
  92                         «ELSEIF a.time != null»
  93                         time = System.currentTimeMillis();
  94                         while(!suppressed«IF a.time.time > 0» && System.currentTimeMillis()-time<«a.time.time»«ENDIF»){
  95                                 Thread.yield();
  96                         }
  97                         «ELSEIF a.turnType != null»
  98                                 «IF a.acc > 0»
  99                                         leftMotor.setAcceleration(«a.acc»);
 100                                         leftMotor.setSpeed(«a.spd»);
 101                                         rightMotor.setAcceleration(«a.acc»);
 102                                         rightMotor.setSpeed(«a.spd»);
 103                                 «ENDIF»
 104                                 «IF a.turnType.turnDir != null»
 105                                         «a.turnType.turnDir.d.toString()»Turn(«a.turnType.degrees»);
 106                                 «ELSE»
 107                                         turnRandom(«a.turnType.start», «a.turnType.end»);
 108                                 «ENDIF»
 109                         «ELSEIF a.rl != null»
 110                         measure«a.rl.d.toString()»();
 111                         «ELSE»
 112                         if(!suppressed){
 113                                 sensors.saveVar("«a.varName.toString()»");
 114                         }
 115                         «ENDIF»
 116                 «ENDFOR»
 117                 System.out.print("Stop: «b.name»");
 118         }
 119 }
 120         '''
 121
 122         def CharSequence makeConstants(Robot robot)'''
 123 package nl.ru.des;
 124
 125 public class Constants{
 126         public final static int speed = «robot.spd»;
 127         public final static int acceleration = «robot.acc»;
 128 }'''
 129
 130         def CharSequence printExpression(StoppingExpression e)'''
 131         «IF e.scond != null»
 132                 «IF e.scond.varName != null»
 133                 sensors.collected("«e.scond.varName.toString()»")
 134                 «ELSEIF e.scond.touch != null»
 135                 sensors.«e.scond.touch.d.toString()»Touch()
 136                 «ELSEIF e.scond.light != null»
 137                 sensors.«e.scond.light.d.toString()»Light()
 138                 «ELSEIF e.scond.dist != null»
 139                 sensors.«e.scond.dist.d.toString()»Distance()
 140                 «ELSEIF e.scond.color != null»
 141                 sensors.color() == Color.«e.scond.color.d.getName()»
 142                 «ELSE»
 143                 false
 144                 «ENDIF»
 145         «ELSEIF e.negscond != null»
 146                 !(«printExpression(e.negscond)»)
 147         «ELSE»
 148                 «IF e.op.d.equals(OperatorE.AND)»
 149                         «FOR ex : e.s BEFORE "(" SEPARATOR "&&" AFTER ")"»«printExpression(ex)»«ENDFOR»
 150                 «ELSE»
 151                         «FOR ex : e.s BEFORE "(" SEPARATOR "||" AFTER ")"»«printExpression(ex)»«ENDFOR»
 152                 «ENDIF»
 153         «ENDIF»'''
 154 }